R_CustomerReturnItemTP

@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}
@ObjectModel: {
  sapObjectNodeType:{
        name: 'CustomerReturnItem'
  },
  semanticKey: ['CustomerReturn', 'CustomerReturnItem'],
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory: #L
  }
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@AbapCatalog.extensibility: {
  extensible: true,
  dataSources: ['_Extension'],
  elementSuffix: 'SDI',
  quota: {
    maximumFields: 204, 
    maximumBytes: 6800  
  }
}
@EndUserText.label: 'Returns Order Item - TP'
@Metadata.ignorePropagatedAnnotations: true

define view entity R_CustomerReturnItemTP
  as select from I_CustomerReturnItemEnhanced          as CustomerReturnItem

  composition [0..*] of R_CustomerReturnItemPartnerTP  as _ItemPartner
  composition [0..*] of R_CustomerReturnItemTextTP     as _ItemText
  composition [0..*] of R_CustRetItemPricingElementTP  as _ItemPricingElement
  composition [0..*] of R_CustReturnItemSerialNumberTP as _ItemSerialNumber

  association [0..1] to R_VariantConfigurationTP      as _VariantConfiguration         on  $projection.VarConfigurationBusObjectType = _VariantConfiguration.VarConfigurationBusObjectType
                                                                                       and $projection.VarConfigurationBusObjectKey  = _VariantConfiguration.VarConfigurationBusObjectKey                                                                                  
  association [0..*] to I_CustomerReturnProcessStep    as _ReturnProcessStep           on  $projection.RetsMgmtProcessItem = CustomerReturnItem.CustomerReturnItem
                                                                                       and $projection.RetsMgmtProcess     = CustomerReturnItem.RetsMgmtProcess
  association [0..1] to I_SalesDocumentItemCategory    as _HigherLevelItemCategory     on  $projection.HigherLevelItemCategory = _HigherLevelItemCategory.SalesDocumentItemCategory
  association [0..1] to I_SlsDocItemEnhancedFields     as _ItemEnhancedFields          on  $projection.CustomerReturn       = _ItemEnhancedFields.SalesDocument
                                                                                       and $projection.CustomerReturnItem   = _ItemEnhancedFields.SalesDocumentItem
  association [0..1] to I_WBSElementByExternalID          as _WBSElementExternalID        on  $projection.WBSElementExternalID = _WBSElementExternalID.WBSElementExternalID
  //association [0..1] to P_CustReturnSubsqntProcg       as _CustReturnSubsqntProcg      on  $projection.CustomerReturn      = _CustReturnSubsqntProcg.CustomerReturn

  //                                                                                     and $projection.CustomerReturnItem  = _CustReturnSubsqntProcg.CustomerReturnItem


  association to parent R_CustomerReturnTP             as _CustomerReturn              on $projection.CustomerReturn       = _CustomerReturn.CustomerReturn
  //Extension Association

  association [1]    to E_SalesDocumentItemBasic       as _Extension                   on  $projection.CustomerReturn      = _Extension.SalesDocument
                                                                                       and $projection.CustomerReturnItem  = _Extension.SalesDocumentItem
{
  key CustomerReturnItem.CustomerReturn,
  key CustomerReturnItem.CustomerReturnItem,

      CustomerReturnItem.HigherLevelItem,

      @ObjectModel.foreignKey.association: '_ItemCategory'
      CustomerReturnItem.CustomerReturnItemCategory,
      @ObjectModel.foreignKey.association: '_ItemCategoryGroup'
      _ItemEnhancedFields.ItemCategoryGroup,
      @ObjectModel.foreignKey.association: '_SDDocumentItemUsage'
      _ItemEnhancedFields.SDDocumentItemUsage,
      @ObjectModel.foreignKey.association: '_HigherLevelItemCategory'
      CustomerReturnItem._HigherLevelItem.CustomerReturnItemCategory              as HigherLevelItemCategory,

      @Semantics.text: true
      CustomerReturnItem.CustomerReturnItemText,

      CustomerReturnItem.PurchaseOrderByCustomer,
      CustomerReturnItem.PurchaseOrderByShipToParty,
      CustomerReturnItem.CorrespncExternalReference,
      CustomerReturnItem.CorrespncExtRefByShipToParty,
      CustomerReturnItem.UnderlyingPurchaseOrderItem,
      CustomerReturnItem.UndrlgPurOrdItmByShipToParty,
      CustomerReturnItem.Product,
      CustomerReturnItem.Material,
      CustomerReturnItem.OriginallyRequestedMaterial,
      CustomerReturnItem.MaterialByCustomer,
      CustomerReturnItem.InternationalArticleNumber,    
      CustomerReturnItem.ProductConfiguration,  
      @ObjectModel.foreignKey.association: '_CustomerPurchaseOrderType'
      CustomerReturnItem.CustomerPurchaseOrderType, 
      @ObjectModel.foreignKey.association: '_CustPurOrdTypeByShipToParty'
      CustomerReturnItem.CustPurOrdTypeByShipToParty,

      case when CustomerReturnItem.ProductConfiguration is not initial
        then
          cast ('CustomerReturnItem' as sbo_node_type)
        else
          null
      end                                                                 as VarConfigurationBusObjectType,     
                
      case when CustomerReturnItem.ProductConfiguration is not initial
        then
          cast ( concat(CustomerReturnItem.CustomerReturn, CustomerReturnItem.CustomerReturnItem) as ibobjkey )
        else
          null          
      end                                                                 as VarConfigurationBusObjectKey,

      @ObjectModel.foreignKey.association: '_ProductGroup'
      CustomerReturnItem.ProductGroup,
      CustomerReturnItem.Batch,

      @Semantics.quantity.unitOfMeasure: 'RequestedQuantityUnit'
      CustomerReturnItem.RequestedQuantity,
      CustomerReturnItem.RequestedQuantityUnit,

      @Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
      CustomerReturnItem.ItemGrossWeight,
      @Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
      CustomerReturnItem.ItemNetWeight,
      CustomerReturnItem.ItemWeightUnit,

      @Semantics.quantity.unitOfMeasure: 'ItemVolumeUnit'
      CustomerReturnItem.ItemVolume,
      CustomerReturnItem.ItemVolumeUnit,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CustomerReturnItem.NetAmount,
      CustomerReturnItem.TransactionCurrency,
      CustomerReturnItem.PricingDate,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CustomerReturnItem.TaxAmount,
      @ObjectModel.foreignKey.association: '_MatlAccountAssignmentGroup'
      CustomerReturnItem.MatlAccountAssignmentGroup,
      @ObjectModel.foreignKey.association: '_ControllingArea'
      CustomerReturnItem.ControllingArea,

      @ObjectModel.foreignKey.association: '_SDPricingProcedure'
      _CustomerReturn.SDPricingProcedure,

      CustomerReturnItem.ServicesRenderedDate,
      CustomerReturnItem.BillingDocumentDate,
      CustomerReturnItem.FixedValueDate,
            
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: 'Plant'
      CustomerReturnItem.Plant as ProductionPlant,
      CustomerReturnItem.Plant,
      CustomerReturnItem.StorageLocation,
      CustomerReturnItem.ShippingPoint,
      CustomerReturnItem.DeliveryPriority,
      CustomerReturnItem.ShippingType,
      CustomerReturnItem.CustomerGroup,
      
      @ObjectModel.foreignKey.association: '_SalesDocumentRjcnReason'
      CustomerReturnItem.SalesDocumentRjcnReason,
      CustomerReturnItem.ItemBillingBlockReason,

      CustomerReturnItem.IncotermsClassification,
      CustomerReturnItem.IncotermsTransferLocation,
      CustomerReturnItem.IncotermsLocation1,
      CustomerReturnItem.IncotermsLocation2,
      CustomerReturnItem.IncotermsVersion,      
      CustomerReturnItem.CustomerPaymentTerms,
      CustomerReturnItem.CustomerPriceGroup,
      cast(CustomerReturnItem.MaterialPricingGroup as productpricinggroup preserving type) as MaterialPricingGroup,      
                 
      //Accounting

      CustomerReturnItem.BusinessArea,      
      @ObjectModel.foreignKey.association: '_ProfitCenter'
      CustomerReturnItem.ProfitCenter,
      CustomerReturnItem.WBSElementInternalID,
      @ObjectModel.foreignKey.association: '_WBSElementExternalID'
      CustomerReturnItem._WBSElementBasicData_2.WBSElementExternalID as WBSElementExternalID,
      

      //ARM Fields

      CustomerReturnItem.RetsMgmtProcess,
      CustomerReturnItem.RetsMgmtProcessItem,
      CustomerReturnItem.ReturnReason,
      CustomerReturnItem.RetsMgmtProcessingBlock,
      CustomerReturnItem.CustRetItmFollowUpActivity,
      @Semantics.booleanIndicator:true
      CustomerReturnItem.ReturnsMaterialHasBeenReceived,
      @ObjectModel.virtualElement: true
      cast ( '' as msr_cust_insp_comment )                          as CustRetItmCustomerText,
      @ObjectModel.virtualElement: true
      cast ( '' as msr_insp_comment )                               as CustRetItmInspectionText,
      CustomerReturnItem.ReturnsRefundType,
//      CustomerReturnItem.ReturnsRefundProcgMode,

      cast(CustomerReturnItem.ReturnsRefundProcgMode as msr_refund_control preserving type) as ReturnsRefundProcgMode,
      @Semantics.booleanIndicator:true
      CustomerReturnItem.RetsProdValnIsSuspended,
      @Semantics.booleanIndicator:true
      CustomerReturnItem.RetsInspIsCrtedAutomly,
      @Semantics.booleanIndicator:true
      CustomerReturnItem.RetsProdIsVltdWithRef,
      CustomerReturnItem.ReturnsRefundExtent,
      @Semantics.booleanIndicator:true
      CustomerReturnItem.PrelimRefundIsDetermined,
      CustomerReturnItem.ReturnsRefundRjcnReason,

      cast(CustomerReturnItem.ReplacementMaterial as return_replace_product preserving type) as ReplacementMaterial,
      @Semantics.quantity.unitOfMeasure: 'ReplacementMaterialQtyUnit'
      CustomerReturnItem.ReplacementMaterialQuantity,
      CustomerReturnItem.ReplacementMaterialQtyUnit,
      @Semantics.booleanIndicator:true
      CustomerReturnItem.ReplacementMaterialIsRequested,
      CustomerReturnItem.ReplacementMatlSupplyingPlant,

      CustomerReturnItem.NextPlantForFollowUpActivity,
      CustomerReturnItem.ReturnsTransshipmentPlant,
      
      CustomerReturnItem.Supplier,
      @Semantics.text:true
      CustomerReturnItem._Supplier.SupplierName,
      CustomerReturnItem.SupplierRetMatlAuthzn,
      CustomerReturnItem.AddressID as ReturnToAddressID,
      @Semantics.booleanIndicator:true
      CustomerReturnItem.SuplrRetMatlAuthznIsRequired,
      CustomerReturnItem.CustomerRetMatlInspResultCode,
      CustomerReturnItem.NextFllwUpActivityForMatlInsp,
      CustomerReturnItem.RetMatlInspResultCode,
      @Semantics.booleanIndicator:true
      CustomerReturnItem.ProductIsInspectedAtCustSite,
      CustomerReturnItem.CustRetMatlAuthzn,
      CustomerReturnItem._SalesDocumentRjcnReason,

      CustomerReturnItem.CRMLogicalSystem,
      @Semantics.uuid
      CustomerReturnItem.CRMObjectUUID,
      CustomerReturnItem.CRMObjectID,
      CustomerReturnItem.CRMObjectType,

      CustomerReturnItem.RetsMgmtItmLogProcgStatus,
      CustomerReturnItem.RetsMgmtItmCompnProcgStatus,
      CustomerReturnItem.RetsMgmtItmProcgStatus,
      CustomerReturnItem.ReturnsDocumentStatus,
      CustomerReturnItem.ReturnsDocumentApprovalStatus,

      //Reference

      CustomerReturnItem.ReferenceSDDocument,
      CustomerReturnItem.ReferenceSDDocumentItem,
      CustomerReturnItem.ReferenceSDDocumentCategory,
      CustomerReturnItem.BusinessSolutionOrderItem,
      CustomerReturnItem.BusSolnOrdItemBundleItem,
      
      //Status

      CustomerReturnItem.SDProcessStatus,
      CustomerReturnItem.SDDocumentRejectionStatus,
      CustomerReturnItem.CustRetReleaseStatus,
      CustomerReturnItem.ItemGeneralIncompletionStatus,

      //Tax Classfication

      CustomerReturnItem.ProductTaxClassification1,
      CustomerReturnItem.ProductTaxClassification2,
      CustomerReturnItem.ProductTaxClassification3,
      CustomerReturnItem.ProductTaxClassification4,
      CustomerReturnItem.ProductTaxClassification5,
      CustomerReturnItem.ProductTaxClassification6,
      CustomerReturnItem.ProductTaxClassification7,
      CustomerReturnItem.ProductTaxClassification8,
      CustomerReturnItem.ProductTaxClassification9,

      CustomerReturnItem.AdditionalMaterialGroup1,
      CustomerReturnItem.AdditionalMaterialGroup2,
      CustomerReturnItem.AdditionalMaterialGroup3,
      CustomerReturnItem.AdditionalMaterialGroup4,
      CustomerReturnItem.AdditionalMaterialGroup5,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CustomerReturnItem.Subtotal1Amount,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CustomerReturnItem.Subtotal2Amount,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CustomerReturnItem.Subtotal3Amount,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CustomerReturnItem.Subtotal4Amount,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CustomerReturnItem.Subtotal5Amount,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CustomerReturnItem.Subtotal6Amount,


      // For Access control

      @Consumption.hidden: true
      _CustomerReturn.CustomerReturnType,
      @Consumption.hidden: true
      _CustomerReturn.OrganizationDivision,
      @Consumption.hidden: true
      _CustomerReturn.SalesOrganization,
      @Consumption.hidden: true
      _CustomerReturn.DistributionChannel,

      //Compositions

      _ItemPartner,
      _ItemText,
      _ItemPricingElement,
      _ItemSerialNumber,
      _ReturnProcessStep,

      //Association

      _CustomerReturn._SDPricingProcedure,
      _CustomerReturn,
      CustomerReturnItem._ItemCategory,
      CustomerReturnItem._HigherLevelItem,
      CustomerReturnItem._ProductGroup,     
      CustomerReturnItem._WBSElementBasicData_2,
      CustomerReturnItem._MatlAccountAssignmentGroup,
      CustomerReturnItem._ProfitCenter,
      CustomerReturnItem._ControllingArea,
      CustomerReturnItem._RequestedQuantityUnit,
      CustomerReturnItem._ItemWeightUnit,
      CustomerReturnItem._ItemVolumeUnit,
      CustomerReturnItem._ReferenceSDDocumentCategory,
      CustomerReturnItem._CustomerPurchaseOrderType,
      CustomerReturnItem._CustPurOrdTypeByShipToParty, 
      CustomerReturnItem._ReplacementMaterialQtyUnit as _RplcmtProdQuantityUnit,
      _HigherLevelItemCategory,
      _WBSElementExternalID,
      _ItemEnhancedFields._ItemCategoryGroup,
      _ItemEnhancedFields._SDDocumentItemUsage,
      _VariantConfiguration
}