@VDM: {
lifecycle.contract.type: #SAP_INTERNAL_API,
viewType: #TRANSACTIONAL
}
@AccessControl: {
authorizationCheck: #CHECK,
personalData.blocking: #('TRANSACTIONAL_DATA'),
privilegedAssociations: [ '_DfltAddrRprstn' ]
}
@ObjectModel: {
semanticKey: ['CustomerReturn', 'CustomerReturnItem', 'PartnerFunction'],
usageType: {
dataClass: #TRANSACTIONAL,
serviceQuality: #C,
sizeCategory: #L
}
}
@Consumption.dbHints: [ 'USE_HEX_PLAN', 'NO_SUBPLAN_SHARING' ]
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Returns Order Item Partner - TP'
define view entity R_CustomerReturnItemPartnerTP
as select from I_SalesDocItemCompletePartner as CustomerReturnItemPartner
inner join I_SalesDocumentBasic as CustomerReturn on CustomerReturn.SalesDocument = CustomerReturnItemPartner.SalesDocument
and CustomerReturn.SDDocumentCategory = 'H'
association to parent R_CustomerReturnItemTP as _Item on $projection.CustomerReturn = _Item.CustomerReturn
and $projection.CustomerReturnItem = _Item.CustomerReturnItem
association [1..1] to R_CustomerReturnTP as _CustomerReturn on $projection.CustomerReturn = _CustomerReturn.CustomerReturn
association [0..1] to I_PartnerFunction as _PartnerFunction on $projection.PartnerFunctionForEdit = _PartnerFunction.PartnerFunction
association [0..1] to I_FormOfAddress as _FormOfAddress on $projection.FormOfAddress = _FormOfAddress.FormOfAddress
association [0..1] to I_Language as _CorrespondenceLanguage on $projection.CorrespondenceLanguage = _CorrespondenceLanguage.Language
association [0..1] to I_TransportationZone as _TransportationZone on $projection.transportzone = _TransportationZone.TransportZone
and $projection.country = _TransportationZone.CountryCode
association [0..1] to I_AddrCurDfltLandlinePhoneNmbr as _CurrentDfltLandlinePhoneNmbr on $projection.AddressID = _CurrentDfltLandlinePhoneNmbr.AddressID
and $projection.AddressPersonID = _CurrentDfltLandlinePhoneNmbr.AddressPersonID
association [0..1] to I_AddrCurDfltMobilePhoneNumber as _CurrentDfltMobilePhoneNumber on $projection.AddressID = _CurrentDfltMobilePhoneNumber.AddressID
and $projection.AddressPersonID = _CurrentDfltMobilePhoneNumber.AddressPersonID
association [0..1] to I_AddrCurDefaultFaxNumber as _CurrentDfltFaxNumber on $projection.AddressID = _CurrentDfltFaxNumber.AddressID
and $projection.AddressPersonID = _CurrentDfltFaxNumber.AddressPersonID
association [1] to I_WorkplaceAddress as _WorkPlaceAddress on $projection.ReferenceBusinessPartner = _WorkPlaceAddress.BusinessPartner
{
key cast(CustomerReturnItemPartner.SalesDocument as vdm_customer_return preserving type) as CustomerReturn,
key cast(CustomerReturnItemPartner.SalesDocumentItem as vdm_customer_return_item preserving type) as CustomerReturnItem,
key cast(CustomerReturnItemPartner.PartnerFunction as parvw_unv preserving type) as PartnerFunction,
@ObjectModel.foreignKey.association: '_PartnerFunction'
cast(CustomerReturnItemPartner.PartnerFunction as parvw_unv preserving type ) as PartnerFunctionForEdit,
CustomerReturnItemPartner.Customer,
CustomerReturnItemPartner.Supplier,
CustomerReturnItemPartner.Personnel,
CustomerReturnItemPartner.ContactPerson,
@ObjectModel.text.element: ['FullName']
CustomerReturnItemPartner.Partner,
@ObjectModel.virtualElement: true
cast('' as ad_name1) as BusinessPartnerName1,
@ObjectModel.virtualElement: true
cast('' as ad_name2) as BusinessPartnerName2,
@ObjectModel.virtualElement: true
cast('' as ad_name3) as BusinessPartnerName3,
@ObjectModel.virtualElement: true
cast('' as ad_name4) as BusinessPartnerName4,
@Semantics.name.fullName: true
@Semantics.text: true
CustomerReturnItemPartner.FullName,
_PartnerFunction.SDDocumentPartnerType,
@ObjectModel.foreignKey.association: '_FormOfAddress'
@Semantics.name.jobTitle: true
CustomerReturnItemPartner.FormOfAddress,
@Semantics.address.street: true
CustomerReturnItemPartner._OrgNamePostalAddress.StreetName,
@Semantics.address.street: true
CustomerReturnItemPartner._OrgNamePostalAddress.StreetPrefixName1,
@Semantics.address.street: true
CustomerReturnItemPartner._OrgNamePostalAddress.StreetPrefixName2,
@Semantics.address.street: true
CustomerReturnItemPartner._OrgNamePostalAddress.StreetSuffixName1,
@Semantics.address.street: true
CustomerReturnItemPartner._OrgNamePostalAddress.StreetSuffixName2,
@Semantics.address.streetNoNumber: true
CustomerReturnItemPartner._OrgNamePostalAddress.HouseNumber,
@Semantics.address.zipCode:true
CustomerReturnItemPartner._OrgNamePostalAddress.PostalCode,
@Semantics.address.country:true
@ObjectModel.foreignKey.association: '_Country'
CustomerReturnItemPartner._OrgNamePostalAddress.Country,
@ObjectModel.foreignKey.association: '_Region'
@Semantics.address.region: true
CustomerReturnItemPartner._OrgNamePostalAddress.Region,
CustomerReturnItemPartner._OrgNamePostalAddress.DistrictName,
@Semantics.address.city:true
CustomerReturnItemPartner._OrgNamePostalAddress.CityName,
@Semantics.address.postBox: true
CustomerReturnItemPartner._OrgNamePostalAddress.POBox,
@Semantics.address.zipCode:true
CustomerReturnItemPartner._OrgNamePostalAddress.POBoxPostalCode,
@ObjectModel.foreignKey.association: '_CorrespondenceLanguage'
CustomerReturnItemPartner.CorrespondenceLanguage,
CustomerReturnItemPartner._OrgNamePostalAddress.TaxJurisdiction,
@ObjectModel.foreignKey.association: '_TransportationZone'
CustomerReturnItemPartner._OrgNamePostalAddress.TransportZone,
CustomerReturnItemPartner.PartnerIsSpecificForSDDocItem,
CustomerReturnItemPartner.ReferenceBusinessPartner,
CustomerReturnItemPartner.AddressID,
CustomerReturnItemPartner.AddressPersonID,
CustomerReturnItemPartner.AddressObjectType,
CustomerReturnItemPartner.SDDocPartnerAddrIsDocSpecific,
CustomerReturnItemPartner.VATRegistration,
@Semantics.text: true
CustomerReturnItemPartner.UnloadingPointName,
cast(
case
when CustomerReturnItemPartner.AddressID = ''
then
_WorkPlaceAddress.DestinationLocationCountry
else
_CurrentDfltLandlinePhoneNmbr.PhoneNumberCountry
end
as ad_comctry preserving type ) as PhoneNumberCountry,
cast(
case
when CustomerReturnItemPartner.AddressID = ''
then
_WorkPlaceAddress.PhoneNumber
else
_CurrentDfltLandlinePhoneNmbr.PhoneAreaCodeSubscriberNumber
end
as ad_tlnmbr preserving type ) as PhoneNumber,
cast(
case
when CustomerReturnItemPartner.AddressID = ''
then
_WorkPlaceAddress.PhoneNumberExtension
else
_CurrentDfltLandlinePhoneNmbr.PhoneExtensionNumber
end
as ad_tlxtns preserving type ) as PhoneNumberExtension,
cast(
case
when CustomerReturnItemPartner.AddressID = ''
then
_WorkPlaceAddress.MblPhoneDestinationLocCountry
else
_CurrentDfltMobilePhoneNumber.PhoneNumberCountry
end
as ad_comctry preserving type ) as MobilePhoneCountry,
cast(
case
when CustomerReturnItemPartner.AddressID = ''
then
_WorkPlaceAddress.MobilePhoneNumber
else
_CurrentDfltMobilePhoneNumber.PhoneAreaCodeSubscriberNumber
end
as ad_tlnmbr preserving type ) as MobilePhoneNumber,
cast(
case
when CustomerReturnItemPartner.AddressID = ''
then
_WorkPlaceAddress.FaxNumberCountry
else
_CurrentDfltFaxNumber.FaxNumberCountry
end
as ad_comctry preserving type ) as FaxNumberCountry,
cast(
case
when CustomerReturnItemPartner.AddressID = ''
then
_WorkPlaceAddress.FaxAreaCodeSubscriberNumber
else
_CurrentDfltFaxNumber.FaxAreaCodeSubscriberNumber
end
as ad_fxnmbr preserving type ) as FaxNumber,
cast(
case
when CustomerReturnItemPartner.AddressID = ''
then
_WorkPlaceAddress.FaxExtensionNumber
else
_CurrentDfltFaxNumber.FaxExtensionNumber
end
as ad_fxxtns preserving type ) as FaxNumberExtension,
@Semantics.telephone.type: [#WORK]
CustomerReturnItemPartner.InternationalPhoneNumber,
@Semantics.telephone.type: [#CELL]
CustomerReturnItemPartner.InternationalMobilePhoneNumber,
@Semantics.telephone.type: [#FAX]
CustomerReturnItemPartner.InternationalFaxNumber,
@Semantics.eMail.address: true
@Semantics.eMail.type: [#WORK]
CustomerReturnItemPartner.EmailAddress,
@Consumption.hidden: true
CustomerReturnItemPartner.SDDocPartnerAddressRefType,
@Consumption.hidden: true
CustomerReturnItemPartner.BPAddrDeterminationTransaction,
@Consumption.hidden: true
CustomerReturnItemPartner.BPRefAddressIDForDocSpcfcAddr,
@Consumption.hidden: true
_CustomerReturn.CustomerReturnType,
@Consumption.hidden: true
_CustomerReturn.SalesOrganization,
@Consumption.hidden: true
_CustomerReturn.DistributionChannel,
@Consumption.hidden: true
_CustomerReturn.OrganizationDivision,
//Associations
_Item,
_CustomerReturn,
_PartnerFunction,
_CorrespondenceLanguage,
_TransportationZone,
_FormOfAddress,
CustomerReturnItemPartner._ContactPerson,
CustomerReturnItemPartner._DfltAddrRprstn,
CustomerReturnItemPartner._BusinessPartnerAddress,
CustomerReturnItemPartner._BPRefAddressForDocSpcfcAddr,
CustomerReturnItemPartner._OrgNamePostalAddress._Country,
CustomerReturnItemPartner._OrgNamePostalAddress._Region
}