R_CustomerReturnItemTextTP

DDL: R_CUSTOMERRETURNITEMTEXTTP Type: view_entity TRANSACTIONAL Package: RAP_SD_SLS_RE

Returns Order Item - Text TP

R_CustomerReturnItemTextTP is a Transactional CDS View that provides data about "Returns Order Item - Text TP" in SAP S/4HANA. It reads from 3 data sources (P_SalesDocumentItemText, I_SalesDocumentItemBasic, I_SalesDocumentItemCategory) and exposes 17 fields with key fields CustomerReturn, CustomerReturnItem, Language, LongTextID. It has 4 associations to related views. Part of development package RAP_SD_SLS_RE.

3 data source(s) 17 fields

Data Sources (3)

SourceAliasJoin Type
P_SalesDocumentItemText P_SalesDocumentItemText from
I_SalesDocumentItemBasic SalesDocumentItemBasic inner
I_SalesDocumentItemCategory SalesDocumentItemCategory inner

Associations (4)

CardinalityTargetAliasCondition
[1..1] R_CustomerReturnTP _CustomerReturn $projection.CustomerReturn = _CustomerReturn.CustomerReturn
[0..1] I_Language _Language $projection.LanguageForEdit = _Language.Language
[0..1] I_SDDocumentItemLongTextID _LongTextID $projection.LongTextIDForEdit = _LongTextID.LongTextID
[0..*] I_TextDeterminationProcedItem _TextDeterminationProcedItem $projection.TextDeterminationProcedure = _TextDeterminationProcedItem.TextDeterminationProcedure and $projection.LongTextID = _TextDeterminationProcedItem.LongTextID and _TextDeterminationProcedItem.TextObjectCategory = 'VBBP'

Annotations (8)

NameValueLevelField
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
VDM.viewType #TRANSACTIONAL view
AccessControl.authorizationCheck #CHECK view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
Metadata.ignorePropagatedAnnotations true view
EndUserText.label Returns Order Item - Text TP view

Fields (17)

KeyFieldSource TableSource FieldDescription
KEY CustomerReturn
KEY CustomerReturnItem
KEY Language CustomerReturnItemText Language
KEY LongTextID CustomerReturnItemText LongTextID
LongTextIDForEdit CustomerReturnItemText LongTextID
LanguageForEdit CustomerReturnItemText Language
LongText CustomerReturnItemText LongText
TextDeterminationProcedure I_SalesDocumentItemCategory TextDeterminationProcedure
TextDeterminationProcedureItem _TextDeterminationProcedItem TextDeterminationProcedureItem
CustomerReturnType I_SalesDocumentItemBasic SalesDocumentType
OrganizationDivision I_SalesDocumentItemBasic OrganizationDivision
SalesOrganization I_SalesDocumentItemBasic SalesOrganization
DistributionChannel I_SalesDocumentItemBasic DistributionChannel
_Item _Item
_CustomerReturn _CustomerReturn
_Language _Language
_LongTextID _LongTextID 
@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
  semanticKey: ['CustomerReturn', 'CustomerReturnItem', 'Language', 'LongTextID'],
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory: #L
   }
}
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Returns Order Item - Text TP'

define view entity R_CustomerReturnItemTextTP
  as select from P_SalesDocumentItemText( P_SAPClient : $session.client ) as CustomerReturnItemText
    inner join   I_SalesDocumentItemBasic                                 as SalesDocumentItemBasic    on  SalesDocumentItemBasic.SalesDocument      = CustomerReturnItemText.SalesDocument
                                                                                                       and SalesDocumentItemBasic.SalesDocumentItem  = CustomerReturnItemText.SalesDocumentItem
                                                                                                       and SalesDocumentItemBasic.SDDocumentCategory = 'H'
    inner join   I_SalesDocumentItemCategory                              as SalesDocumentItemCategory on SalesDocumentItemCategory.SalesDocumentItemCategory = SalesDocumentItemBasic.SalesDocumentItemCategory


  association to parent R_CustomerReturnItemTP        as _Item                        on  $projection.CustomerReturn     = _Item.CustomerReturn
                                                                                      and $projection.CustomerReturnItem = _Item.CustomerReturnItem
                                                                                      
  association [1..1] to R_CustomerReturnTP            as _CustomerReturn              on  $projection.CustomerReturn = _CustomerReturn.CustomerReturn
  association [0..1] to I_Language                    as _Language                    on  $projection.LanguageForEdit = _Language.Language
  association [0..1] to I_SDDocumentItemLongTextID    as _LongTextID                  on  $projection.LongTextIDForEdit = _LongTextID.LongTextID
  
  association [0..*] to I_TextDeterminationProcedItem as _TextDeterminationProcedItem on  $projection.TextDeterminationProcedure          = _TextDeterminationProcedItem.TextDeterminationProcedure
                                                                                      and $projection.LongTextID                          = _TextDeterminationProcedItem.LongTextID
                                                                                      and _TextDeterminationProcedItem.TextObjectCategory = 'VBBP'

{
  key cast(CustomerReturnItemText.SalesDocument as vdm_customer_return preserving type)          as CustomerReturn,

  key cast(CustomerReturnItemText.SalesDocumentItem as vdm_customer_return_item preserving type) as CustomerReturnItem,

  key CustomerReturnItemText.Language,

  key CustomerReturnItemText.LongTextID,

      @ObjectModel.foreignKey.association: '_LongTextID'
      CustomerReturnItemText.LongTextID                                                          as LongTextIDForEdit,

      @ObjectModel.foreignKey.association: '_Language'
      CustomerReturnItemText.Language                                                            as LanguageForEdit,
      
      @ObjectModel.virtualElement: true
      CustomerReturnItemText.LongText,

      @Consumption.hidden: true
      SalesDocumentItemCategory.TextDeterminationProcedure,

      _TextDeterminationProcedItem.TextDeterminationProcedureItem                                as TextDeterminationProcedureItem,

      //For Access Control

      @Consumption.hidden: true
      SalesDocumentItemBasic.SalesDocumentType                                                   as CustomerReturnType,
      @Consumption.hidden: true
      SalesDocumentItemBasic.OrganizationDivision,
      @Consumption.hidden: true
      SalesDocumentItemBasic.SalesOrganization,
      @Consumption.hidden: true
      SalesDocumentItemBasic.DistributionChannel,

      //Associations

      _Item,
      _CustomerReturn,
      _Language,
      _LongTextID
}

Learn More