R_ChemicalComplianceInfoTP

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: [ '_CreatedByUser', '_LastChangedByUser' ]

@EndUserText.label: 'Chemical Compliance Info - TP'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.sapObjectNodeType.name: 'ChemicalComplianceInfo'
@ObjectModel.usageType: { dataClass: #MIXED, sizeCategory: #L, serviceQuality: #C }

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL

define root view entity R_ChemicalComplianceInfoTP
  as select from I_ChmlCmplncInfo

  composition [0..*] of R_ChmlCmplncMatlAssgmtTP      as _MaterialAssgmt
  composition [0..*] of R_ChmlCmplncPrpsAssgmtTP      as _PurposeAssgmt
  composition [0..*] of R_ChmlCmplncSuplrMatlAssgmtTP as _SupplierAssgmt
  composition [0..*] of R_ChmlCmplncInfoPckgdProdTP   as _ToPackagedProductAssgmt
  composition [0..*] of R_ChmlCmplncBrnddProdNameTP   as _BrandedProductName
  composition [0..1] of R_ChmlCmplncInfoUnpckgdProdTP as _ToUnpackagedProductAssgmt

  -- Material Data for Primary Material
  association [0..1] to C_ChmlCmplncPrimMatl          as _MaterialDataPrimary         on  _MaterialDataPrimary.ChmlCmplncInfoUUID = $projection.ChmlCmplncInfoUUID

  association [0..*] to I_ResponsibleUnitDngrsGdsText as _ResponsibleUnitDngrsGdsText on  _ResponsibleUnitDngrsGdsText.ResponsibleUnit = $projection.DngrsGdsRespUnit

  association [0..*] to I_ResponsibleUnitText         as _ResponsibleUnitText         on  _ResponsibleUnitText.ResponsibleUnit = $projection.ProdStewardshipRespUnit

  -- Phrase ID
  association [1..1] to I_ProdCmplncPhrs              as _ProdCmplncPhrs              on  $projection.ChmlCmplncProdCatztnPhrsUUID = _ProdCmplncPhrs.ProdCmplncPhrsUUID

  -- UP
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_ChmlCmplncProdAssgmt        as _UnpackagedProductAssgmt     on  _UnpackagedProductAssgmt.ChmlCmplncInfoUUID = $projection.ChmlCmplncInfoUUID  
                                                                                      and _UnpackagedProductAssgmt.ChmlCmplncInfoType = 'BU'

  association [0..1] to I_ChmlComposition             as _MultiComponentComposition   on  _MultiComponentComposition.ChmlCmplncInfoUUID    = $projection.ChmlCmplncInfoUUID
                                                                                      and _MultiComponentComposition.ChmlCompositionType   = 'MCPC'
                                                                                      and _MultiComponentComposition.ChmlCompositionStatus = 'RE'
{
  key ChmlCmplncInfoUUID,

      CreationUTCDateTime,
      CreatedByUser,
      LastChangeUTCDateTime,
      LastChangedByUser,
      // Responsible Unit

      ProdStewardshipRespUnit,
      // Responsible Unit for Dangerous Goods

      DngrsGdsRespUnit,
      ChmlCmplncInfoType,
      // Internal Name

      ChmlCmplncInternalName,
      MaterialIsBaseProduct,
      MaterialIsSold,
      MaterialIsTransported,
      MaterialIsSourced,
      MaterialIsProduced,
      MaterialIsDisposed,
      MaterialIsEmissionRelevant,
      // Internal Number

      cast(Specification as ehfnd_internal_nr preserving type)                             as ChemicalComplianceInfo,

      SpecificationInternalID,
      ChmlCmplncProdIsResearched,
      MatlIsNotDngrsGdsRlvt,
      MatlIsNotProdMarketabilityRlvt,
      MatlIsNotProdSafetyRlvt                                                              as SftyDataShtIsNotRequired,
      MatlIsNotSupplierRlvt,

      --- Product Categorization
      cast(ChmlCmplncProdCatztnPhrsUUID as ehfnd_chm_prod_catztnphrs_uuid preserving type) as ChmlCmplncProdCatztnPhrsUUID,
      _ProdCmplncPhrs.ProdCmplncPhrs,

      --- Multi-Component Product
      MatlIsMultiComponentProduct,

      /* Associations */
      _CreatedByUser,
      _LastChangedByUser,
      _MaterialAssgmt,
      _PurposeAssgmt,
      _SupplierAssgmt,
      _ToPackagedProductAssgmt,
      _ToUnpackagedProductAssgmt,
      _MaterialDataPrimary,
      _ResponsibleUnitText,
      _ResponsibleUnitDngrsGdsText,
      _UnpackagedProductAssgmt,
      _ProdCmplncPhrs,
      _MultiComponentComposition,
      _BrandedProductName
}