R_ChangeRecordHeader

@AbapCatalog.viewEnhancementCategory: [#NONE]
@ObjectModel.sapObjectNodeType.name: 'ChangeRecord'
@Metadata.ignorePropagatedAnnotations: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Change Record Header'
@VDM: {
lifecycle.contract.type: #SAP_INTERNAL_API,
viewType: #TRANSACTIONAL
}
@ObjectModel.usageType:{
    serviceQuality: #C,
    sizeCategory: #L,
    dataClass: #MIXED
}

define view entity R_ChangeRecordHeader
  as select from R_ChangeRecordHeader_2 as _Header
  association [0..1] to I_ChangeRecordTypeText         as _ChangeRecordTypeText         on  _ChangeRecordTypeText.ChangeRecordType = _Header.ChangeRecordType
                                                                                        and _ChangeRecordTypeText.Language         = $session.system_language
  association [0..1] to I_ChangeRecordType             as _ChangeRecordType             on  _ChangeRecordType.ChangeRecordType = _Header.ChangeRecordType
  association [0..1] to I_ChgRecordUserStatusText      as _ChangeRecordUserStatusText   on  $projection.ChangeRecordStatus       = _ChangeRecordUserStatusText.ChangeRecordStatus
                                                                                        and _ChangeRecordUserStatusText.Language = $session.system_language
  association [0..1] to I_ChgRecdLifecycleStatusTxt    as _ChangeRecordLcycleStsText    on  $projection.ChangeRecordLifecycleStatus = _ChangeRecordLcycleStsText.ChangeRecordLifecycleStatus
                                                                                        and _ChangeRecordLcycleStsText.Language     = $session.system_language
  association [0..1] to I_ChangeRecordTypeText_2       as _ChangeRecordTypeText_2       on  _ChangeRecordTypeText_2.ChangeRecordType = _Header.ChangeRecordType
                                                                                        and _ChangeRecordTypeText_2.Language         = $session.system_language
  association [0..1] to I_ChangeRecordType_2           as _ChangeRecordType_2           on  _ChangeRecordType_2.ChangeRecordType = _Header.ChangeRecordType
  association [0..1] to I_ChangeRecordUserStatusText_2 as _ChangeRecordUserStatusText_2 on  $projection.ChangeRecordStatus         = _ChangeRecordUserStatusText_2.ChangeRecordUserStatus
                                                                                        and $projection.ChangeRecordUserStatusProfile = _ChangeRecordUserStatusText_2.ChangeRecordStatusProfile
                                                                                        and _ChangeRecordUserStatusText_2.Language = $session.system_language
  association [0..1] to I_ChangeRecordLifeCycleStsTxt  as _ChangeRecordLcycleStsText_2  on  $projection.ChangeRecordLifecycleStatus = _ChangeRecordLcycleStsText_2.ChangeRecordLifeStatus
                                                                                        and _ChangeRecordLcycleStsText_2.Language   = $session.system_language
  association [0..1] to I_ChgRecdTypeWorkFlowScenario  as _WFScenario                   on  _Header.ChangeRecordType             = _WFScenario.ChangeRecordType
                                                                                        and _WFScenario.WorkflowScenarioIsActive = 'X'
{
  key _Header.ChangeRecordUUID,
      _Header.ChangeRecord,
      _Header.ChangeRecordType,
      _Header.ParentChangeRecordUUID,
      _Header.RootChangeRecordUUID,
      _Header.ChangeRecordStatus,
      _Header.ChangeRecordCategory,
      _Header.ChgRecordApplication,
      _Header.ChangeNumber,
      _Header.CreatedByUser,
      _Header.CreationDateTime,
      _Header.LastChangedByUser,
      _Header.LastChangeDateTime,
      _Header.ChangeRecordLifecycleStatus,
      _Header.ChangeRecordUserStatusProfile,
      _Header.ChgRecdAuthGroup,
      _Header.ExtensionChangeRecordUUID,
//      _Header.ChgRecdHdrExtnUUID,

      _Header.ChgRecdReasonForChange,
      _Header.ChgRecdExpectedCompletionDate,
      _Header.ChgRecdPrflIdn,
      _Header.ChangeRecordDetailDescription,
      _Header.ChgRecdEngEffectiveDate,
      _Header.ChgRecdMfgEffectiveDate,
      _Header.ChangeRecordItemEditMode,
      _Header.ChgRecdSilentDataMigrtnStatus,
      _Header.Partner,
//      _Header.ChangeRecordPartner,

      _Header.ResponsibleChangeRecordUUID                           as ResponsibleChangeRecordUUID,
      _Header.ChangeRecordReferenceTextUUID,  
      _Header.ChangeRecordReferenceUUID,
      _Header.ChgRecordDescriptionText,
//      _ChangeRecordTypeText.ChangeRecordTypeDesc  as ChangeRecordTypeDesc,

       coalesce(_ChangeRecordTypeText_2.ChangeRecordTypeDesc, _ChangeRecordTypeText.ChangeRecordTypeDesc )                              as ChangeRecordTypeDesc,
//      _ChangeRecordUserStatusText.ChangeRecordStatusDescription as ChangeRecordStatusDescription,

      coalesce( _ChangeRecordUserStatusText_2.ChangeRecordStatusDescription,_ChangeRecordUserStatusText.ChangeRecordStatusDescription  ) as ChangeRecordStatusDescription,
      coalesce( _ChangeRecordLcycleStsText_2.ChangeRecordStatusDescription,_ChangeRecordLcycleStsText.ChangeRecordLifecycleStatusTxt ) as ChangeRecdLifecycleStatusDesc,
//      _ChangeRecordLcycleStsText.ChangeRecordLifecycleStatusTxt as  ChangeRecdLifecycleStatusDesc,         

      coalesce(_WFScenario.ChangeRecordScenarioID ,_ChangeRecordType.ChangeRecordScenarioID ) as ChangeRecordScenarioID,
      @Semantics.booleanIndicator:true
      coalesce(_ChangeRecordType_2.ChgRecdItemProcgStatusIsEnbld,_ChangeRecordType.ChgRecdItemProcgStatusIsEnbld) as ChgRecdItemProcgStatusIsEnbld,                                                                                                                            
      @Semantics.booleanIndicator:true
      coalesce(_ChangeRecordType_2.ChgRecItemProcStatusIsDisabled,_ChangeRecordType.ChgRecItemProcStatusIsDisabled) as ChgRecItemProcStatusIsDisabled  

}