I_ChangeRecordType

@AbapCatalog.sqlViewName: 'ICHGRCDTYP'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'ChangeRecordType'
//@Analytics: {dataCategory: #DIMENSION, dataExtraction.enabled: true}

@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Change Record Type'
@VDM.viewType:#BASIC

@ObjectModel.usageType: {serviceQuality: #B,
                         dataClass: #MIXED,
                         sizeCategory: #L}
@AbapCatalog.preserveKey:true

define view I_ChangeRecordType
  as select from /iam/c_issuetyp as Issue_type
    inner join   /plmi/cr_type   as CR_type on Issue_type.issue_type = CR_type.cr_type
  association [0..*] to I_ChangeRecordTypeText as _Text on $projection.ChangeRecordType = _Text.ChangeRecordType

{
      @ObjectModel.text.association: '_Text'
      @ObjectModel.text.element: ['ChangeRecordTypeDesc']

  key cast(Issue_type.issue_type as /plmb/cr_type preserving type)      as ChangeRecordType,
      Issue_type.party_role_code                                        as ChangeResponsible,
      Issue_type.status_profile                                         as ChangeRecordStatusProfile,
      Issue_type.nrange_interval                                        as ChangeRecordNumberRangeIntID,
      Issue_type.wfd_id                                                 as ChangeRecordScenarioID,
      CR_type.cr_category                                               as ChangeRecordCategory,
      CR_type.process_route                                             as ChgRecordIsUsingProcessRoute,
      CR_type.collaboration                                             as ChgRecordIsUsingCollaboration,
      case CR_type.collaboration
            when '' then 'X'
            else ''
      end                                                               as ChgRecdCollaborationIsHidden,
      CR_type.enable_item_proc_status                                   as ChgRecdItemProcgStatusIsEnbld,
      case CR_type.enable_item_proc_status
      when 'X' then ' '
      else 'X' 
      end                                                               as ChgRecItemProcStatusIsDisabled,
      CR_type.peo_relevant                                              as ChgRecdIsProdnEngOpsRlvt,
      _Text[1:Language = $session.system_language].ChangeRecordTypeDesc as ChangeRecordTypeDesc,
      CR_type.purpose                                                   as ChangeRecordPurposeType,
      Issue_type.inactive                                               as ChangeRecordTypeIsInactive  ,        
      _Text
                                               
}
where
  Issue_type.application = 'CR'