R_ChangeRecordTP

@AbapCatalog.viewEnhancementCategory: [#NONE]
@ObjectModel.sapObjectNodeType.name: 'ChangeRecord'
@Metadata.ignorePropagatedAnnotations: true
@AccessControl.authorizationCheck:#MANDATORY
@EndUserText.label: 'Change Record Root - TP'
@VDM: {
lifecycle.contract.type: #SAP_INTERNAL_API,
viewType: #TRANSACTIONAL
}
@ObjectModel.usageType:{
    serviceQuality: #D,
    sizeCategory: #XL,
    dataClass: #MIXED
}


@Consumption.dbHints: [ 'USE_HEX_PLAN' ]

define root view entity R_ChangeRecordTP
  as select from R_ChangeRecordHeader as Header
  composition [0..*] of R_ChgRecdRefMatTP              as _ReferenceMaterial
  composition [0..*] of R_ChgRecdRefBOMTP              as _ReferenceBOM
  composition [0..*] of R_ChgRecdRefDocTP              as _ReferenceDocument
  composition [0..*] of R_ChgRecdRefClassTP            as _ReferenceClass
  composition [0..*] of R_ChgRecdRefOrdBOMTP           as _ReferenceOrdBOM
  composition [0..*] of R_ChgRecdRefCharcTP            as _ReferenceCharc
  composition [0..*] of R_ChgRecdRefProdnRoutingTP     as _ReferenceProdnRouting
  association [0..1] to I_ChangeRecordItemVisibility   as _ChgRecdRefObjVisibility   on _ChgRecdRefObjVisibility.ChangeRecordType = Header.ChangeRecordType
  association [0..1] to I_ChangeRecordItemVisibility_2 as _ChgRecdRefObjVisibility_2 on _ChgRecdRefObjVisibility_2.ChangeRecordType = Header.ChangeRecordType
  association [0..1] to I_ChangeRecordPartner          as _ChangeRecordContactPerson on  _ChangeRecordContactPerson.Partner = Header.Partner    
 //                                                      or _ChangeRecordContactPerson.Partner = Header.ChangeRecordPartner )

  association [0..1] to I_ChgRecordMergeSplitStatusTP  as _ChgRecordChildIsMerge     on _ChgRecordChildIsMerge.ChangeRecordUUID = $projection.ChangeRecordUUID
  association [0..1] to I_UserContactCard              as _CreatedByUser             on $projection.CreatedByUser = _CreatedByUser.ContactCardID
  association [0..1] to I_UserContactCard              as _ChangedByUser             on $projection.LastChangedByUser = _ChangedByUser.ContactCardID
  association [0..1] to I_ChangeMasterVH               as _ChangeMasterVH            on $projection.ChangeNumber = _ChangeMasterVH.ChangeNumber

{
  key Header.ChangeRecordUUID,
      Header.ChangeRecord,
      Header.ChangeRecordType,
      Header.ParentChangeRecordUUID,
      Header.RootChangeRecordUUID,
      Header.ChangeRecordStatus,
      Header.ChangeNumber,
      Header.ChangeRecordCategory,
      Header.ChgRecordApplication,
      @Semantics.user.createdBy: true
      Header.CreatedByUser,
      @Semantics.systemDateTime.createdAt: true
      Header.CreationDateTime,
      @Semantics.user.localInstanceLastChangedBy: true
      Header.LastChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      Header.LastChangeDateTime,
      Header.ChangeRecordLifecycleStatus,
      Header.ChangeRecordUserStatusProfile,
      Header.ChgRecdAuthGroup,
      Header.ExtensionChangeRecordUUID,
      Header.ChgRecdReasonForChange,
      Header.ChgRecdExpectedCompletionDate,
      Header.ChgRecdPrflIdn,
      Header.ChangeRecordDetailDescription,
//      Header.ChgRecdHdrExtnUUID,

      Header.ChgRecdEngEffectiveDate,
      Header.ChgRecdMfgEffectiveDate,
      Header.ResponsibleChangeRecordUUID,
      Header.Partner,
//      Header.ChangeRecordPartner,

      Header.ChangeRecordItemEditMode,
      _ChangeRecordContactPerson.PersonFullName,
      Header.ChangeRecordReferenceTextUUID,
      Header.ChangeRecordReferenceUUID,
      Header.ChgRecordDescriptionText,
      Header.ChangeRecordTypeDesc,
      Header.ChangeRecordStatusDescription,
      Header.ChangeRecdLifecycleStatusDesc,
      @Semantics.booleanIndicator: true
      Header.ChgRecdItemProcgStatusIsEnbld       as ChgRecdItemProcgStatusIsEnbld,
      @Semantics.booleanIndicator: true
      Header.ChgRecItemProcStatusIsDisabled      as ChgRecItemProcStatusIsDisabled,
      cast(' ' as cv_orig preserving type )      as IsAttachmentsEnabled,
      _ChgRecordChildIsMerge.ChangeRecordIsMerge as ChangeRecordIsMerge,
      _CreatedByUser.FullName                    as CreatedByUserFullName,
      _ChangedByUser.FullName                    as LastChangedByUserName,
      Header.ChangeRecdLifecycleStatusDesc       as ChangeRecordLifecycleStatusTxt,
      _ChangeMasterVH.ChangeNumberDescription,
      Header.ChangeRecordScenarioID,
      cast( case when $projection.changerecordlifecyclestatus = '09' then 'X' else ' ' end as boolean preserving type ) as UpdateIsHidden,
      @ObjectModel: { virtualElement: true, virtualElementCalculatedBy: 'ABAP:/PLMI/CL_CR_AUTH_FOR_CHG_STAT' }
      cast( '' as boolean preserving type )    as ChgRecdIsStatusUpdateEnabled,
      @ObjectModel: { virtualElement: true, virtualElementCalculatedBy: 'ABAP:CL_PLMI_CR_ACTION_CONTROL' }
      cast( '' as boolean preserving type )     as AuthorizationFieldName,
      @Semantics.booleanIndicator: true
      coalesce(  _ChgRecdRefObjVisibility_2.ChangeRecordDocumentIsHidden, _ChgRecdRefObjVisibility.ChangeRecordDocumentIsHidden)  as ChangeRecordDocumentIsHidden,
      @Semantics.booleanIndicator: true
      coalesce( _ChgRecdRefObjVisibility_2.ChangeRecordMaterialIsHidden, _ChgRecdRefObjVisibility.ChangeRecordMaterialIsHidden) as ChangeRecordMaterialIsHidden,
      @Semantics.booleanIndicator: true
      coalesce( _ChgRecdRefObjVisibility_2.ChgRecdBillOfMatlIsHidn, _ChgRecdRefObjVisibility.ChgRecdBillOfMatlIsHidn) as ChgRecdBillOfMatlIsHidn,
      @Semantics.booleanIndicator: true
      coalesce( _ChgRecdRefObjVisibility_2.ChangeRecordOrderBOMIsHidden, _ChgRecdRefObjVisibility.ChangeRecordOrderBOMIsHidden) as ChangeRecordOrderBOMIsHidden,
      @Semantics.booleanIndicator: true
      coalesce( _ChgRecdRefObjVisibility_2.ChangeRecordProdnRtgIsHidden, _ChgRecdRefObjVisibility.ChangeRecordProdnRtgIsHidden) as ChangeRecordProdnRtgIsHidden,
      @Semantics.booleanIndicator: true
      coalesce( _ChgRecdRefObjVisibility_2.ChangeRecordCharIsHidden, _ChgRecdRefObjVisibility.ChangeRecordCharIsHidden) as ChangeRecordCharIsHidden,
      @Semantics.booleanIndicator: true
      coalesce( _ChgRecdRefObjVisibility_2.ChangeRecordClassIsHidden, _ChgRecdRefObjVisibility.ChangeRecordClassIsHidden) as ChangeRecordClassIsHidden,
     
      _ChgRecdRefObjVisibility.ChgRecdBillOfMatlItmIsHidn,
      _ChgRecdRefObjVisibility.ChangeRecordFuncLocBOMIsHidden,
      _ChgRecdRefObjVisibility.ChgRecdEquipBillOfMatlIsHidn,   
      _ChgRecdRefObjVisibility.ChgRecdMaintTskListIsHidn,
      _ChgRecdRefObjVisibility.ChgRecdEquipTskListIsHidn,
      _ChgRecdRefObjVisibility.ChgRecdFuncLocTaskListIsHidden,
      _ChgRecdRefObjVisibility.ChangeRecordRateRtgIsHidden,
      _ChgRecdRefObjVisibility.ChgRecdPurOrdIsHidn,
      _ChgRecdRefObjVisibility.ChangeRecordMasterRcpIsHidden,
      _ChgRecdRefObjVisibility.ChgRecdInPlnIsHidn,      
      _ChangeRecordContactPerson,
      _CreatedByUser,
      _ChangedByUser,
//      _ChangeRecordType,

      _ReferenceMaterial,
      _ReferenceBOM,
      _ReferenceDocument,
      _ReferenceClass,
      _ReferenceOrdBOM,
      _ReferenceCharc,
      _ReferenceProdnRouting

}