R_BillingDocumentTextTP

DDL: R_BILLINGDOCUMENTTEXTTP Type: view_entity TRANSACTIONAL Package: RAP_SD_BIL_BD

Billing Document - Text TP

R_BillingDocumentTextTP is a Transactional CDS View that provides data about "Billing Document - Text TP" in SAP S/4HANA. It reads from 3 data sources (I_BillingDocument, I_BillingDocumentType_2, P_BillingDocumentText) and exposes 11 fields with key fields BillingDocument, Language, LongTextID. It has 3 associations to related views. Part of development package RAP_SD_BIL_BD.

3 data source(s) 11 fields

Data Sources (3)

SourceAliasJoin Type
I_BillingDocument BillingDocument inner
I_BillingDocumentType_2 BillingDocumentType inner
P_BillingDocumentText P_BillingDocumentText from

Associations (3)

CardinalityTargetAliasCondition
[0..1] I_Language _Language $projection.LanguageForEdit = _Language.Language
[0..1] I_SDDocumentLongTextID _LongTextID $projection.LongTextIDForEdit = _LongTextID.LongTextID
[0..1] I_TextDeterminationProcedItem _TextDeterminationProcedItem $projection.BillgDocTextDetnProcedure = _TextDeterminationProcedItem.TextDeterminationProcedure and $projection.LongTextID = _TextDeterminationProcedItem.LongTextID and _TextDeterminationProcedItem.TextObjectCategory = 'VBBK' and _TextDeterminationProcedItem.TextDeterminationProcedObject = 'C'

Annotations (8)

NameValueLevelField
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
VDM.viewType #TRANSACTIONAL view
AccessControl.authorizationCheck #MANDATORY view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.dataCategory #TEXT view
EndUserText.label Billing Document - Text TP view

Fields (11)

KeyFieldSource TableSource FieldDescription
KEY BillingDocument Text BillingDocument
KEY Language Text Language
KEY LongTextID Text LongTextID
LanguageForEdit Text Language
LongTextIDForEdit Text LongTextID
LongText Text LongText
BillgDocTextDetnProcedure I_BillingDocumentType_2 BillgDocTextDetnProcedure
TextDeterminationProcedureItem _TextDeterminationProcedItem TextDeterminationProcedureItem
_BillingDocument _BillingDocument
_Language _Language
_LongTextID _LongTextID 
@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}
@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory: #L
  },
  dataCategory: #TEXT,
  semanticKey: ['BillingDocument', 'Language', 'LongTextID']
}

@EndUserText.label: 'Billing Document - Text TP'
define view entity R_BillingDocumentTextTP 
    as select from P_BillingDocumentText( P_SAPClient : $session.client,
                                            P_td_object : 'VBBK') as Text
        inner join   I_BillingDocument                        as BillingDocument       on BillingDocument.BillingDocument = Text.BillingDocument
        inner join   I_BillingDocumentType_2                  as BillingDocumentType   on BillingDocument.BillingDocumentType = BillingDocumentType.BillingDocumentType
    
      association        to parent R_BillingDocumentTP as _BillingDocument       on  $projection.BillingDocument = _BillingDocument.BillingDocument
    
      association [0..1] to I_Language                       as _Language                    on  $projection.LanguageForEdit = _Language.Language
    
      association [0..1] to I_SDDocumentLongTextID           as _LongTextID                  on  $projection.LongTextIDForEdit = _LongTextID.LongTextID
    
      association [0..1] to I_TextDeterminationProcedItem    as _TextDeterminationProcedItem on  $projection.BillgDocTextDetnProcedure                      = _TextDeterminationProcedItem.TextDeterminationProcedure
                                                                                             and $projection.LongTextID                                     = _TextDeterminationProcedItem.LongTextID
                                                                                             and _TextDeterminationProcedItem.TextObjectCategory            = 'VBBK'
                                                                                             and _TextDeterminationProcedItem.TextDeterminationProcedObject = 'C'
  {
    key Text.BillingDocument as BillingDocument,

    @Semantics.language:true
    key Text.Language,
    
    key Text.LongTextID,
    
    @ObjectModel:{
    foreignKey.association:'_Language',
    editableFieldFor:'Language'
    }
    Text.Language as LanguageForEdit,
    
    @ObjectModel:{
    foreignKey.association:'_LongTextID',
    editableFieldFor:'LongTextID'
    }
    Text.LongTextID as LongTextIDForEdit,
    
    @ObjectModel.virtualElement:true
    Text.LongText,
    @Consumption.hidden: true
    BillingDocumentType.BillgDocTextDetnProcedure,
    
    _TextDeterminationProcedItem.TextDeterminationProcedureItem,
    
    _BillingDocument,
    _Language,
    _LongTextID
    
}
where BillingDocument.BillingDocumentIsTemporary = ' '

Learn More