C_BillingDocumentTextManage

DDL: C_BILLINGDOCUMENTTEXTMANAGE Type: view_entity CONSUMPTION Package: ODATA_SD_BIL_BD_UI

Billing Document - Text

C_BillingDocumentTextManage is a Consumption CDS View that provides data about "Billing Document - Text" in SAP S/4HANA. It reads from 1 data source (R_BillingDocumentTextTP) and exposes 9 fields with key fields BillingDocument, Language, LongTextID. It is exposed through 1 OData service (UI_BILLINGDOCUMENT_MANAGE). Part of development package ODATA_SD_BIL_BD_UI.

1 data source(s) Exposed by 1 service(s) 9 fields

Data Sources (1)

SourceAliasJoin Type
R_BillingDocumentTextTP R_BillingDocumentTextTP projection

Annotations (10)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
EndUserText.label Billing Document - Text view
Metadata.allowExtensions true view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.modelingPattern #TRANSACTIONAL_QUERY view
ObjectModel.query.implementedBy ABAP:CL_S4RAP_STICKY_QRY view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
VDM.viewType #CONSUMPTION view

OData Services (1)

ServiceBindingVersionContractRelease
UI_BILLINGDOCUMENT_MANAGE UI_BILLINGDOCUMENT_MANAGE V4 C1 NOT_RELEASED

Fields (9)

KeyFieldSource TableSource FieldDescription
KEY BillingDocument BillingDocument
KEY Language Language
KEY LongTextID LongTextID
LanguageForEdit LanguageForEdit
LongTextIDForEdit LongTextIDForEdit
string
TextDeterminationProcedureItem TextDeterminationProcedureItem
_Language _Language
_LongTextID _LongTextID 
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')

@Consumption.dbHints: [ 'USE_HEX_PLAN' ]

@EndUserText.label: 'Billing Document - Text'

@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true

//@ObjectModel.dataCategory: #TEXT    //todo_phantha: maybe incorect annotation. 

@ObjectModel.modelingPattern: #TRANSACTIONAL_QUERY
@ObjectModel.query.implementedBy: 'ABAP:CL_S4RAP_STICKY_QRY'
@ObjectModel.semanticKey: [ 'BillingDocument',
                            'Language',
                            'LongTextID' ]
@ObjectModel.supportedCapabilities: [ #TRANSACTIONAL_PROVIDER ]
@ObjectModel.usageType: { serviceQuality: #C,
                          sizeCategory:   #L,
                          dataClass:      #TRANSACTIONAL }

@VDM.usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]
@VDM.viewType: #CONSUMPTION

define view entity C_BillingDocumentTextManage
  as projection on R_BillingDocumentTextTP
{
  key     BillingDocument,

          @Semantics.language: true
  key     Language,

  key     LongTextID,

          @ObjectModel.editableFieldFor: 'Language'
          @ObjectModel.foreignKey.association: '_Language'
          LanguageForEdit,

          @ObjectModel.editableFieldFor: 'LongTextID'
          @ObjectModel.foreignKey.association: '_LongTextID'
          LongTextIDForEdit,
          
          @ObjectModel.virtualElement: true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SDBIL_CALC_EXIT_TEXT'
          @Semantics.text: true
  virtual LongText : abap.string,

          TextDeterminationProcedureItem,

          @ObjectModel.filter.enabled: false
          @ObjectModel.sort.enabled: false
          _Language,

          @ObjectModel.filter.enabled: false
          @ObjectModel.sort.enabled: false
          _LongTextID,
          
          /* Associations */
          @ObjectModel.filter.enabled: false
          @ObjectModel.sort.enabled: false
          _BillingDocument : redirected to parent C_BillingDocumentManage
  
}

Learn More