I_BILLINGDOCUMENTTYPE_2

CDS View

Billing Document Type

I_BILLINGDOCUMENTTYPE_2 is a CDS View in S/4HANA. Billing Document Type. It contains 3 fields. 4 CDS views read from this table.

Used by 4 CDS view(s) 3 fields

CDS Views using this table (4)

ViewTypeJoinVDMDescription
I_BillingDocumentTypeStdVH view_entity from COMPOSITE Billing Document Type
I_BillingDocumentTypeText_2 view_entity inner BASIC Billing Document Type - Text
R_BillingDocumentItemTextTP view_entity inner TRANSACTIONAL Billing Document Item Text - TP
R_BillingDocumentTextTP view_entity inner TRANSACTIONAL Billing Document - Text TP

Fields (3)

KeyField CDS FieldsUsed in Views
KEY BillingDocumentType BillingDocumentType 1
BillgDocItemTextDetnProcedure BillgDocItemTextDetnProcedure 1
BillgDocTextDetnProcedure BillgDocTextDetnProcedure 1 
@AbapCatalog.entityBuffer.definitionAllowed: true

@AccessControl.authorizationCheck: #NOT_REQUIRED

@Analytics.dataCategory: #DIMENSION
@Analytics.dataExtraction.enabled: true
@Analytics.internalName: #LOCAL

@Consumption.ranked: true

@EndUserText.label: 'Billing Document Type'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.representativeKey: 'BillingDocumentType'
@ObjectModel.sapObjectNodeType.name: 'BillingDocumentType'

@ObjectModel.supportedCapabilities: [ #ANALYTICAL_DIMENSION,
                                      #CDS_MODELING_DATA_SOURCE,
                                      #CDS_MODELING_ASSOCIATION_TARGET,
                                      #SQL_DATA_SOURCE,
                                      #SEARCHABLE_ENTITY,
                                      #EXTRACTION_DATA_SOURCE ]

@ObjectModel.usageType: { dataClass: #CUSTOMIZING, serviceQuality: #A, sizeCategory: #S }

@Search.searchable: true

@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC

define root view entity I_BillingDocumentType_2
  as select from I_BillingProcessDocumentType

  composition of exact one to many I_BillingDocumentTypeText_2 as _Text

{
      @ObjectModel.text.association: '_Text'
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
  key cast(BillingProcessDocumentType as billingdocumenttype preserving type)             as BillingDocumentType,

      @ObjectModel.foreignKey.association: '_SDDocumentCategory'
      SDDocumentCategory,

      IncrementItemNumber,

      @ObjectModel.foreignKey.association: '_BillingDocumentCategory'
      BillingDocumentCategory,

      @ObjectModel.foreignKey.association: '_BillgDocTextDetnProcedure'
      cast(BillgProcDocTxtDetnProcedure as billgdoctextdetnprocedure preserving type)     as BillgDocTextDetnProcedure,

      @ObjectModel.foreignKey.association: '_BillgDocItemTextDetnProcedure'
      cast(BillgProcDocItmTxtDetnProced as billgdocitemtextdetnprocedure preserving type) as BillgDocItemTextDetnProcedure,

      _Text,
      _SDDocumentCategory,
      _BillingDocumentCategory,
      _BillgProcDocTxtDetnProcedure                                                       as _BillgDocTextDetnProcedure,
      _BillgProcDocItmTxtDetnProced                                                       as _BillgDocItemTextDetnProcedure
}

where SDDocumentCategory = 'M' // Invoice

   or SDDocumentCategory = 'N' // Invoice Canceled

   or SDDocumentCategory = 'O' // Credit Memo

   or SDDocumentCategory = 'P' // Debit Memo

   or SDDocumentCategory = 'S' // Credit Memo Canceled

   or SDDocumentCategory = 'U' // Pro Forma Invoice

   or SDDocumentCategory = '5' // Intercompany Invoice

   or SDDocumentCategory = '6' // Intercompany Credit Memo

   or SDDocumentCategory = 'DPRQ' // Down Payment Request

   or SDDocumentCategory = 'DPCC' // Down Payment Cancellation

Learn More