R_BillingDocumentRequestTextTP

DDL: R_BILLINGDOCUMENTREQUESTTEXTTP Type: view_entity TRANSACTIONAL Package: RAP_SD_BIL_BDR

Billing Document Request Text - TP

R_BillingDocumentRequestTextTP is a Transactional CDS View that provides data about "Billing Document Request Text - TP" in SAP S/4HANA. It reads from 3 data sources (I_BillingDocumentRequest, I_BillingDocumentRequestType, P_BillingDocumentText) and exposes 7 fields with key fields BillingDocumentRequest, Language, LongTextID. Part of development package RAP_SD_BIL_BDR.

3 data source(s) 7 fields

Data Sources (3)

SourceAliasJoin Type
I_BillingDocumentRequest BillingDocumentRequest inner
I_BillingDocumentRequestType BillingDocumentRequestType inner
P_BillingDocumentText P_BillingDocumentText from

Annotations (8)

NameValueLevelField
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
VDM.viewType #TRANSACTIONAL view
AccessControl.authorizationCheck #MANDATORY view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.dataCategory #TEXT view
EndUserText.label Billing Document Request Text - TP view

Fields (7)

KeyFieldSource TableSource FieldDescription
KEY BillingDocumentRequest Text BillingDocument
KEY Language Text Language
KEY LongTextID Text LongTextID
LongText Text LongText
BillgDocReqTxtDetnProcedure I_BillingDocumentRequestType BillgDocReqTxtDetnProcedure
TextDeterminationProcedureItem _TextDeterminationProcedItem TextDeterminationProcedureItem
_BillingDocumentRequest _BillingDocumentRequest 
@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}
@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory: #L
  },
  dataCategory: #TEXT,
  semanticKey: ['BillingDocumentRequest', 'Language', 'LongTextID']
}

@EndUserText.label: 'Billing Document Request Text - TP'
define view entity R_BillingDocumentRequestTextTP 
    as select from P_BillingDocumentText( P_SAPClient : $session.client,
                                            P_td_object : 'VBBK') as Text
      inner join   I_BillingDocumentRequest                   as BillingDocumentRequest       on BillingDocumentRequest.BillingDocumentRequest = Text.BillingDocument
      inner join   I_BillingDocumentRequestType               as BillingDocumentRequestType   on BillingDocumentRequest.BillingDocumentRequestType = BillingDocumentRequestType.BillingDocumentRequestType
    
    association        to parent R_BillingDocumentRequestTP as _BillingDocumentRequest       on  $projection.BillingDocumentRequest = _BillingDocumentRequest.BillingDocumentRequest
    association of many to one I_TextDeterminationProcedItem     as _TextDeterminationProcedItem  on  $projection.BillgDocReqTxtDetnProcedure                     = _TextDeterminationProcedItem.TextDeterminationProcedure
                                                                                             and $projection.LongTextID                                     = _TextDeterminationProcedItem.LongTextID
                                                                                             and _TextDeterminationProcedItem.TextObjectCategory            = 'VBBK'
                                                                                             and _TextDeterminationProcedItem.TextDeterminationProcedObject = 'C'
  {
    key Text.BillingDocument as BillingDocumentRequest,
    @Semantics.language:true
    key Text.Language,
    key Text.LongTextID,
    
    @ObjectModel.virtualElement:true
    Text.LongText,
    @Consumption.hidden: true
    BillingDocumentRequestType.BillgDocReqTxtDetnProcedure,
    _TextDeterminationProcedItem.TextDeterminationProcedureItem,
    
    _BillingDocumentRequest    
}

Learn More