I_BILLINGDOCUMENTREQUEST

CDS View

Billing Document Request

I_BILLINGDOCUMENTREQUEST is a CDS View in S/4HANA. Billing Document Request. It contains 47 fields. 12 CDS views read from this table.

Used by 12 CDS view(s) 47 fields

CDS Views using this table (12)

ViewTypeJoinVDMDescription
A_BillingDocumentRequest view from COMPOSITE Billing Document Request Header
C_BillgDocReqWorklist view from CONSUMPTION Billing Document Request
C_BillingDocRequestObjPg view from CONSUMPTION Billing Document Request Object Page
C_BSOrdProcFlwBillgDocReq view from CONSUMPTION BDR Attrib for BSOrd Prgrs
C_DspDocFlwBillgDocRequest view_entity from CONSUMPTION Billing Document Request Attributes
C_DspDocFlwBillgDocRequestVH view_entity from CONSUMPTION Billing Document Request
ESH_N_BILLINGDOCUMENTREQUEST view from Anchor view -BILLINGDOCUMENTREQUEST
I_BillingDocumentRequestStdVH view from COMPOSITE Billing Document Request
P_ARProcessFlowBillgDocRequest view_entity from COMPOSITE Billing Document Request Attributes
R_BillgDocRequestItemTextTP view_entity inner TRANSACTIONAL Billing Document Request Item Text - TP
R_BillingDocumentRequestTextTP view_entity inner TRANSACTIONAL Billing Document Request Text - TP
R_BillingDocumentRequestTP view_entity from TRANSACTIONAL Billing Document Request - TP

Fields (47)

KeyField CDS FieldsUsed in Views
KEY BillingDocumentRequest BillingDocumentRequest,ReferenceSDDocument 4
_BillingDocumentRequestType _BillingDocumentRequestType 2
_BillingIssueType _BillingIssueType 2
_CompanyCode _CompanyCode 2
_Country _Country 1
_CustomerAccountAssgmtGroup _CustomerAccountAssgmtGroup 1
_CustomerPaymentTerms _CustomerPaymentTerms 2
_DunningBlockingReason _DunningBlockingReason 1
_DunningKey _DunningKey 1
_IncotermsClassification _IncotermsClassification 2
_IncotermsVersion _IncotermsVersion 2
_OvrlBillingDocReqStatus _OvrlBillingDocReqStatus 2
_ProposedBillingDocumentType _ProposedBillingDocumentType 2
_ReferenceDocSDDocCategory _ReferenceDocSDDocCategory 2
_SalesOrganization _SalesOrganization 2
_SDDocumentCategory _SDDocumentCategory 2
_SoldToParty _SoldToParty 1
_TransactionCurrency _TransactionCurrency 2
BillingDocumentDate BillingDocumentDate 5
BillingDocumentRequestType BillingDocumentRequestType 1
BillingIssueType BillingIssueType 2
CompanyCode CompanyCode 5
Country Country 1
CreatedByUser CreatedByUser 2
CreationDate CreationDate 1
CustomerAccountAssignmentGroup CustomerAccountAssignmentGroup 1
CustomerPaymentTerms CustomerPaymentTerms 3
CustomerTaxClassification1 CustomerTaxClassification1 1
DistributionChannel DistributionChannel 1
Division Division 1
DocumentReferenceID DocumentReferenceID 1
DunningArea DunningArea 1
DunningBlockingReason DunningBlockingReason 1
DunningKey DunningKey 1
IncotermsClassification IncotermsClassification 2
IncotermsLocation1 IncotermsLocation1 2
IncotermsLocation2 IncotermsLocation2 1
IncotermsVersion IncotermsVersion 2
OverallBillingDocReqStatus OverallBillingDocReqStatus 3
PayerParty PayerParty 4
PricingDocument SalesDocumentCondition 2
SalesOrganization SalesOrganization 4
SoldToParty SoldToParty 5
TotalNetAmount TotalNetAmount 4
TotalTaxAmount TotalTaxAmount 2
TransactionCurrency TransactionCurrency 4
VATRegistration VATRegistration 1 
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'ISDBILDOCREQ'

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@AccessControl.privilegedAssociations: [ '_CreatedByUser', '_CreditControlAreaText' ]

@Analytics.dataCategory: #DIMENSION

@Analytics.dataExtraction: { enabled: true,
                             delta.changeDataCapture.mapping: [ { table: 'vbrk',
                                                                  role: #MAIN,
                                                                  viewElement: [ 'BillingDocumentRequest' ],
                                                                  tableElement: [ 'vbeln' ] } ] }

@ClientHandling.algorithm: #SESSION_VARIABLE

@EndUserText.label: 'Billing Document Request'

@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.compositionRoot: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.representativeKey: 'BillingDocumentRequest'
@ObjectModel.sapObjectNodeType.name: 'BillingDocumentRequest'

@ObjectModel.supportedCapabilities: [ #ANALYTICAL_DIMENSION,
                                      #CDS_MODELING_DATA_SOURCE,
                                      #CDS_MODELING_ASSOCIATION_TARGET,
                                      #SQL_DATA_SOURCE,
                                      #EXTRACTION_DATA_SOURCE ]

@ObjectModel.usageType: { dataClass: #TRANSACTIONAL, serviceQuality: #A, sizeCategory: #L }

@VDM.viewType: #BASIC

define view I_BillingDocumentRequest
  as select from I_BillingDocumentBasic

  association [0..*] to I_BillingDocumentRequestItem as _Item           on $projection.BillingDocumentRequest = _Item.BillingDocumentRequest
  association [1..*] to I_BillingDocReqPartner       as _Partner        on $projection.BillingDocumentRequest = _Partner.BillingDocumentRequest
  association [0..*] to I_BillingDocReqPrcgElmnt     as _PricingElement on $projection.BillingDocumentRequest = _PricingElement.BillingDocumentRequest

  // Extensibility

  association [0..1] to E_BillingDocument            as _Extension      on $projection.BillingDocumentRequest = _Extension.BillingDocument

{
      // key

  key cast(BillingDocument as vbeln_bdr preserving type)                                  as BillingDocumentRequest,

      // category

      @ObjectModel.foreignKey.association: '_SDDocumentCategory'
      SDDocumentCategory,

      @ObjectModel.foreignKey.association: '_BillingDocumentRequestType'
      cast(BillingDocumentType as sdbil_odata_bdr_type preserving type)                   as BillingDocumentRequestType,

      @ObjectModel.foreignKey.association: '_ProposedBillingDocumentType'
      cast(ProposedBillingDocumentType as proposed_billing_document_type preserving type) as ProposedBillingDocumentType,

      // admin

      @Semantics.personalData.isPotentiallySensitive: true
      @Semantics.user.createdBy: true
      CreatedByUser,

      @Semantics.systemDate.createdAt: true
      CreationDate,

      @Semantics.systemTime.createdAt
      CreationTime,

      @Semantics.systemDate.lastChangedAt: true
      LastChangeDate,

      @Semantics.systemDateTime.lastChangedAt: true
      LastChangeDateTime,

      @ObjectModel.foreignKey.association: '_LogicalSystem'
      LogicalSystem,

      // org

      @ObjectModel.foreignKey.association: '_SalesOrganization'
      SalesOrganization,

      @ObjectModel.foreignKey.association: '_DistributionChannel'
      DistributionChannel,

      @ObjectModel.foreignKey.association: '_Division'
      Division,

      // billing

      BillingDocumentDate,
      cast(BillingDocCombinationCriteria as billg_doc_req_combn_criteria preserving type) as BillgDocReqCombinationCriteria,

      // pricing

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      TotalNetAmount,

      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      @Semantics.currencyCode: true
      TransactionCurrency,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      TotalTaxAmount,

      @ObjectModel.foreignKey.association: '_CustomerPriceGroup'
      CustomerPriceGroup,

      @ObjectModel.foreignKey.association: '_PriceListType'
      PriceListType,

      @ObjectModel.foreignKey.association: '_TaxDepartureCountry'
      TaxDepartureCountry,

      VATRegistration,

      @ObjectModel.foreignKey.association: '_VATRegistrationOrigin'
      VATRegistrationOrigin,

      @ObjectModel.foreignKey.association: '_VATRegistrationCountry'
      VATRegistrationCountry,

      CustomerTaxClassification1,
      CustomerTaxClassification2,
      CustomerTaxClassification3,
      CustomerTaxClassification4,
      CustomerTaxClassification5,
      CustomerTaxClassification6,
      CustomerTaxClassification7,
      CustomerTaxClassification8,
      CustomerTaxClassification9,

      @ObjectModel.foreignKey.association: '_SDPricingProcedure'
      SDPricingProcedure,

      // shipping

      @ObjectModel.foreignKey.association: '_IncotermsVersion'
      IncotermsVersion,

      @ObjectModel.foreignKey.association: '_IncotermsClassification'
      IncotermsClassification,

      IncotermsTransferLocation,
      IncotermsLocation1,
      IncotermsLocation2,

      // payment

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_Customer_VH', element: 'Customer' } } ]
      @ObjectModel.foreignKey.association: '_PayerParty'
      PayerParty,

      ContractAccount,

      @ObjectModel.foreignKey.association: '_CustomerPaymentTerms'
      CustomerPaymentTerms,

      @ObjectModel.foreignKey.association: '_PaymentMethod'
      PaymentMethod,

      FixedValueDate,
      AdditionalValueDays,
      SEPAMandate,

      // accounting

      DeviatingPostingDate,

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } } ]
      @ObjectModel.foreignKey.association: '_CompanyCode'
      CompanyCode,

      @ObjectModel.foreignKey.association: '_CustomerAccountAssgmtGroup'
      CustomerAccountAssignmentGroup,

      ExchangeRateDate,

      @ObjectModel.foreignKey.association: '_ExchangeRateType'
      ExchangeRateType,

      DocumentReferenceID,

      @ObjectModel.foreignKey.association: '_DunningArea'
      DunningArea,

      @ObjectModel.foreignKey.association: '_DunningBlockingReason'
      DunningBlockingReason,

      @ObjectModel.foreignKey.association: '_DunningKey'
      DunningKey,

      // reference

      cast(BillingDocRequestReference as sdbil_odata_source_document preserving type)     as ReferenceDocument,
      cast(BillgDocReqRefLgclSyst as sdbil_odata_source_system preserving type)           as ReferenceDocumentLogicalSystem,

      @ObjectModel.foreignKey.association: '_ReferenceDocSDDocCategory'
      cast(BillgDocReqRefSDDocCategory as sdbil_odata_src_doc_cat preserving type)        as ReferenceDocSDDocCategory,

      // sales

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_Customer_VH', element: 'Customer' } } ]
      @ObjectModel.foreignKey.association: '_SoldToParty'
      SoldToParty,

      PurchaseOrderByCustomer,

      @ObjectModel.foreignKey.association: '_CustomerGroup'
      CustomerGroup,

      @ObjectModel.foreignKey.association: '_Country'
      Country,

      @ObjectModel.foreignKey.association: '_CityCode'
      CityCode,

      @ObjectModel.foreignKey.association: '_SalesDistrict'
      SalesDistrict,

      @ObjectModel.foreignKey.association: '_Region'
      Region,

      @ObjectModel.foreignKey.association: '_County_2'
      County,

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CreditControlAreaStdVH', element: 'CreditControlArea' } } ]
      @ObjectModel.foreignKey.association: '_CreditControlArea'
      @ObjectModel.text.association: '_CreditControlAreaText'
      CreditControlArea,

      PricingDocument,

      // status 

      @ObjectModel.foreignKey.association: '_OvrlBillingDocReqStatus'
      OverallBillingDocReqStatus,

      @ObjectModel.foreignKey.association: '_BillingIssueType'
      BillingIssueType,

      @ObjectModel.foreignKey.association: '_OverallPricingIncompletionSts'
      OverallPricingIncompletionSts,

      // association

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _Item,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _Partner,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _PricingElement,

      _SDDocumentCategory,
      _BillgDocReqRefSDDocCategory                                                        as _ReferenceDocSDDocCategory,
      _BillingDocumentType                                                                as _BillingDocumentRequestType,

      _ProposedBillingDocumentType,
      _CreatedByUser,
      _LogicalSystem,
      _SalesOrganization,
      _DistributionChannel,
      _Division,
      _TransactionCurrency,
      _CustomerPriceGroup,
      _PriceListType,
      _TaxDepartureCountry,
      _VATRegistrationOrigin,
      _VATRegistrationCountry,
      _SDPricingProcedure,
      _IncotermsClassification,
      _IncotermsVersion,
      _PayerParty,
      _CustomerPaymentTerms,
      _PaymentMethod,
      _CompanyCode,
      _CustomerAccountAssgmtGroup,
      _ExchangeRateType,
      _DunningArea,
      _DunningBlockingReason,
      _DunningKey,
      _SoldToParty,
      _CustomerGroup,
      _Country,
      _CityCode,
      _SalesDistrict,
      _Region,

      @API.element: { releaseState: #DEPRECATED, successor: '_County_2' }
      _County,

      _County_2,
      _CreditControlArea,
      _OvrlBillingDocReqStatus,
      _BillingIssueType,
      _OverallPricingIncompletionSts,

      @Consumption.hidden: true
      _CreditControlAreaText
}

where SDDocumentCategory = 'EBDR';

Learn More