I_BillingDocumentRequest

DDL: I_BILLINGDOCUMENTREQUEST SQL: ISDBILDOCREQ Type: view BASIC Package: VDM_SD_BIL_BDR

Billing Document Request

I_BillingDocumentRequest is a Basic CDS View (Dimension) that provides data about "Billing Document Request" in SAP S/4HANA. It reads from 1 data source (I_BillingDocumentBasic) and exposes 114 fields with key field BillingDocumentRequest. It has 4 associations to related views. Part of development package VDM_SD_BIL_BDR.

1 data source(s) 114 fields

Data Sources (1)

SourceAliasJoin Type
I_BillingDocumentBasic I_BillingDocumentBasic from

Associations (4)

CardinalityTargetAliasCondition
[0..*] I_BillingDocumentRequestItem _Item $projection.BillingDocumentRequest = _Item.BillingDocumentRequest
[1..*] I_BillingDocReqPartner _Partner $projection.BillingDocumentRequest = _Partner.BillingDocumentRequest
[0..*] I_BillingDocReqPrcgElmnt _PricingElement $projection.BillingDocumentRequest = _PricingElement.BillingDocumentRequest
[0..1] E_BillingDocument _Extension $projection.BillingDocumentRequest = _Extension.BillingDocument

Annotations (18)

NameValueLevelField
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AbapCatalog.sqlViewName ISDBILDOCREQ view
AccessControl.authorizationCheck #CHECK view
Analytics.dataCategory #DIMENSION view
Analytics.dataExtraction.enabled true view
ClientHandling.algorithm #SESSION_VARIABLE view
EndUserText.label Billing Document Request view
Metadata.allowExtensions true view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.compositionRoot true view
ObjectModel.modelingPattern #ANALYTICAL_DIMENSION view
ObjectModel.representativeKey BillingDocumentRequest view
ObjectModel.sapObjectNodeType.name BillingDocumentRequest view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #L view
VDM.viewType #BASIC view

Fields (114)

KeyFieldSource TableSource FieldDescription
KEY BillingDocumentRequest
SDDocumentCategory SDDocumentCategory
BillingDocumentRequestType
ProposedBillingDocumentType
CreatedByUser CreatedByUser
CreationDate CreationDate
CreationTime CreationTime
LastChangeDate LastChangeDate
LastChangeDateTime LastChangeDateTime
LogicalSystem LogicalSystem
SalesOrganization SalesOrganization
DistributionChannel DistributionChannel
Division Division
BillingDocumentDate BillingDocumentDate
BillgDocReqCombinationCriteria
TotalNetAmount TotalNetAmount
TransactionCurrency TransactionCurrency
TotalTaxAmount TotalTaxAmount
CustomerPriceGroup CustomerPriceGroup
PriceListType PriceListType
TaxDepartureCountry TaxDepartureCountry
VATRegistration VATRegistration
VATRegistrationOrigin VATRegistrationOrigin
VATRegistrationCountry VATRegistrationCountry
CustomerTaxClassification1 CustomerTaxClassification1
CustomerTaxClassification2 CustomerTaxClassification2
CustomerTaxClassification3 CustomerTaxClassification3
CustomerTaxClassification4 CustomerTaxClassification4
CustomerTaxClassification5 CustomerTaxClassification5
CustomerTaxClassification6 CustomerTaxClassification6
CustomerTaxClassification7 CustomerTaxClassification7
CustomerTaxClassification8 CustomerTaxClassification8
CustomerTaxClassification9 CustomerTaxClassification9
SDPricingProcedure SDPricingProcedure
IncotermsVersion IncotermsVersion
IncotermsClassification IncotermsClassification
IncotermsTransferLocation IncotermsTransferLocation
IncotermsLocation1 IncotermsLocation1
IncotermsLocation2 IncotermsLocation2
PayerParty PayerParty
ContractAccount ContractAccount
CustomerPaymentTerms CustomerPaymentTerms
PaymentMethod PaymentMethod
FixedValueDate FixedValueDate
AdditionalValueDays AdditionalValueDays
SEPAMandate SEPAMandate
DeviatingPostingDate DeviatingPostingDate
CompanyCode CompanyCode
CustomerAccountAssignmentGroup CustomerAccountAssignmentGroup
ExchangeRateDate ExchangeRateDate
ExchangeRateType ExchangeRateType
DocumentReferenceID DocumentReferenceID
DunningArea DunningArea
DunningBlockingReason DunningBlockingReason
DunningKey DunningKey
ReferenceDocument
ReferenceDocumentLogicalSystem
ReferenceDocSDDocCategory
SoldToParty SoldToParty
PurchaseOrderByCustomer PurchaseOrderByCustomer
CustomerGroup CustomerGroup
Country Country
CityCode CityCode
SalesDistrict SalesDistrict
Region Region
County County
CreditControlArea CreditControlArea
PricingDocument PricingDocument
OverallBillingDocReqStatus OverallBillingDocReqStatus
BillingIssueType BillingIssueType
OverallPricingIncompletionSts OverallPricingIncompletionSts
_Item _Item
_Partner _Partner
_PricingElement _PricingElement
_SDDocumentCategory _SDDocumentCategory
_ReferenceDocSDDocCategory _BillgDocReqRefSDDocCategory
_BillingDocumentRequestType _BillingDocumentType
_ProposedBillingDocumentType _ProposedBillingDocumentType
_CreatedByUser _CreatedByUser
_LogicalSystem _LogicalSystem
_SalesOrganization _SalesOrganization
_DistributionChannel _DistributionChannel
_Division _Division
_TransactionCurrency _TransactionCurrency
_CustomerPriceGroup _CustomerPriceGroup
_PriceListType _PriceListType
_TaxDepartureCountry _TaxDepartureCountry
_VATRegistrationOrigin _VATRegistrationOrigin
_VATRegistrationCountry _VATRegistrationCountry
_SDPricingProcedure _SDPricingProcedure
_IncotermsClassification _IncotermsClassification
_IncotermsVersion _IncotermsVersion
_PayerParty _PayerParty
_CustomerPaymentTerms _CustomerPaymentTerms
_PaymentMethod _PaymentMethod
_CompanyCode _CompanyCode
_CustomerAccountAssgmtGroup _CustomerAccountAssgmtGroup
_ExchangeRateType _ExchangeRateType
_DunningArea _DunningArea
_DunningBlockingReason _DunningBlockingReason
_DunningKey _DunningKey
_SoldToParty _SoldToParty
_CustomerGroup _CustomerGroup
_Country _Country
_CityCode _CityCode
_SalesDistrict _SalesDistrict
_Region _Region
_County _County
_County_2 _County_2
_CreditControlArea _CreditControlArea
_OvrlBillingDocReqStatus _OvrlBillingDocReqStatus
_BillingIssueType _BillingIssueType
_OverallPricingIncompletionSts _OverallPricingIncompletionSts
_CreditControlAreaText _CreditControlAreaText 
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'ISDBILDOCREQ'

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@AccessControl.privilegedAssociations: [ '_CreatedByUser', '_CreditControlAreaText' ]

@Analytics.dataCategory: #DIMENSION

@Analytics.dataExtraction: { enabled: true,
                             delta.changeDataCapture.mapping: [ { table: 'vbrk',
                                                                  role: #MAIN,
                                                                  viewElement: [ 'BillingDocumentRequest' ],
                                                                  tableElement: [ 'vbeln' ] } ] }

@ClientHandling.algorithm: #SESSION_VARIABLE

@EndUserText.label: 'Billing Document Request'

@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.compositionRoot: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.representativeKey: 'BillingDocumentRequest'
@ObjectModel.sapObjectNodeType.name: 'BillingDocumentRequest'

@ObjectModel.supportedCapabilities: [ #ANALYTICAL_DIMENSION,
                                      #CDS_MODELING_DATA_SOURCE,
                                      #CDS_MODELING_ASSOCIATION_TARGET,
                                      #SQL_DATA_SOURCE,
                                      #EXTRACTION_DATA_SOURCE ]

@ObjectModel.usageType: { dataClass: #TRANSACTIONAL, serviceQuality: #A, sizeCategory: #L }

@VDM.viewType: #BASIC

define view I_BillingDocumentRequest
  as select from I_BillingDocumentBasic

  association [0..*] to I_BillingDocumentRequestItem as _Item           on $projection.BillingDocumentRequest = _Item.BillingDocumentRequest
  association [1..*] to I_BillingDocReqPartner       as _Partner        on $projection.BillingDocumentRequest = _Partner.BillingDocumentRequest
  association [0..*] to I_BillingDocReqPrcgElmnt     as _PricingElement on $projection.BillingDocumentRequest = _PricingElement.BillingDocumentRequest

  // Extensibility

  association [0..1] to E_BillingDocument            as _Extension      on $projection.BillingDocumentRequest = _Extension.BillingDocument

{
      // key

  key cast(BillingDocument as vbeln_bdr preserving type)                                  as BillingDocumentRequest,

      // category

      @ObjectModel.foreignKey.association: '_SDDocumentCategory'
      SDDocumentCategory,

      @ObjectModel.foreignKey.association: '_BillingDocumentRequestType'
      cast(BillingDocumentType as sdbil_odata_bdr_type preserving type)                   as BillingDocumentRequestType,

      @ObjectModel.foreignKey.association: '_ProposedBillingDocumentType'
      cast(ProposedBillingDocumentType as proposed_billing_document_type preserving type) as ProposedBillingDocumentType,

      // admin

      @Semantics.personalData.isPotentiallySensitive: true
      @Semantics.user.createdBy: true
      CreatedByUser,

      @Semantics.systemDate.createdAt: true
      CreationDate,

      @Semantics.systemTime.createdAt
      CreationTime,

      @Semantics.systemDate.lastChangedAt: true
      LastChangeDate,

      @Semantics.systemDateTime.lastChangedAt: true
      LastChangeDateTime,

      @ObjectModel.foreignKey.association: '_LogicalSystem'
      LogicalSystem,

      // org

      @ObjectModel.foreignKey.association: '_SalesOrganization'
      SalesOrganization,

      @ObjectModel.foreignKey.association: '_DistributionChannel'
      DistributionChannel,

      @ObjectModel.foreignKey.association: '_Division'
      Division,

      // billing

      BillingDocumentDate,
      cast(BillingDocCombinationCriteria as billg_doc_req_combn_criteria preserving type) as BillgDocReqCombinationCriteria,

      // pricing

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      TotalNetAmount,

      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      @Semantics.currencyCode: true
      TransactionCurrency,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      TotalTaxAmount,

      @ObjectModel.foreignKey.association: '_CustomerPriceGroup'
      CustomerPriceGroup,

      @ObjectModel.foreignKey.association: '_PriceListType'
      PriceListType,

      @ObjectModel.foreignKey.association: '_TaxDepartureCountry'
      TaxDepartureCountry,

      VATRegistration,

      @ObjectModel.foreignKey.association: '_VATRegistrationOrigin'
      VATRegistrationOrigin,

      @ObjectModel.foreignKey.association: '_VATRegistrationCountry'
      VATRegistrationCountry,

      CustomerTaxClassification1,
      CustomerTaxClassification2,
      CustomerTaxClassification3,
      CustomerTaxClassification4,
      CustomerTaxClassification5,
      CustomerTaxClassification6,
      CustomerTaxClassification7,
      CustomerTaxClassification8,
      CustomerTaxClassification9,

      @ObjectModel.foreignKey.association: '_SDPricingProcedure'
      SDPricingProcedure,

      // shipping

      @ObjectModel.foreignKey.association: '_IncotermsVersion'
      IncotermsVersion,

      @ObjectModel.foreignKey.association: '_IncotermsClassification'
      IncotermsClassification,

      IncotermsTransferLocation,
      IncotermsLocation1,
      IncotermsLocation2,

      // payment

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_Customer_VH', element: 'Customer' } } ]
      @ObjectModel.foreignKey.association: '_PayerParty'
      PayerParty,

      ContractAccount,

      @ObjectModel.foreignKey.association: '_CustomerPaymentTerms'
      CustomerPaymentTerms,

      @ObjectModel.foreignKey.association: '_PaymentMethod'
      PaymentMethod,

      FixedValueDate,
      AdditionalValueDays,
      SEPAMandate,

      // accounting

      DeviatingPostingDate,

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } } ]
      @ObjectModel.foreignKey.association: '_CompanyCode'
      CompanyCode,

      @ObjectModel.foreignKey.association: '_CustomerAccountAssgmtGroup'
      CustomerAccountAssignmentGroup,

      ExchangeRateDate,

      @ObjectModel.foreignKey.association: '_ExchangeRateType'
      ExchangeRateType,

      DocumentReferenceID,

      @ObjectModel.foreignKey.association: '_DunningArea'
      DunningArea,

      @ObjectModel.foreignKey.association: '_DunningBlockingReason'
      DunningBlockingReason,

      @ObjectModel.foreignKey.association: '_DunningKey'
      DunningKey,

      // reference

      cast(BillingDocRequestReference as sdbil_odata_source_document preserving type)     as ReferenceDocument,
      cast(BillgDocReqRefLgclSyst as sdbil_odata_source_system preserving type)           as ReferenceDocumentLogicalSystem,

      @ObjectModel.foreignKey.association: '_ReferenceDocSDDocCategory'
      cast(BillgDocReqRefSDDocCategory as sdbil_odata_src_doc_cat preserving type)        as ReferenceDocSDDocCategory,

      // sales

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_Customer_VH', element: 'Customer' } } ]
      @ObjectModel.foreignKey.association: '_SoldToParty'
      SoldToParty,

      PurchaseOrderByCustomer,

      @ObjectModel.foreignKey.association: '_CustomerGroup'
      CustomerGroup,

      @ObjectModel.foreignKey.association: '_Country'
      Country,

      @ObjectModel.foreignKey.association: '_CityCode'
      CityCode,

      @ObjectModel.foreignKey.association: '_SalesDistrict'
      SalesDistrict,

      @ObjectModel.foreignKey.association: '_Region'
      Region,

      @ObjectModel.foreignKey.association: '_County_2'
      County,

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CreditControlAreaStdVH', element: 'CreditControlArea' } } ]
      @ObjectModel.foreignKey.association: '_CreditControlArea'
      @ObjectModel.text.association: '_CreditControlAreaText'
      CreditControlArea,

      PricingDocument,

      // status 

      @ObjectModel.foreignKey.association: '_OvrlBillingDocReqStatus'
      OverallBillingDocReqStatus,

      @ObjectModel.foreignKey.association: '_BillingIssueType'
      BillingIssueType,

      @ObjectModel.foreignKey.association: '_OverallPricingIncompletionSts'
      OverallPricingIncompletionSts,

      // association

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _Item,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _Partner,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _PricingElement,

      _SDDocumentCategory,
      _BillgDocReqRefSDDocCategory                                                        as _ReferenceDocSDDocCategory,
      _BillingDocumentType                                                                as _BillingDocumentRequestType,

      _ProposedBillingDocumentType,
      _CreatedByUser,
      _LogicalSystem,
      _SalesOrganization,
      _DistributionChannel,
      _Division,
      _TransactionCurrency,
      _CustomerPriceGroup,
      _PriceListType,
      _TaxDepartureCountry,
      _VATRegistrationOrigin,
      _VATRegistrationCountry,
      _SDPricingProcedure,
      _IncotermsClassification,
      _IncotermsVersion,
      _PayerParty,
      _CustomerPaymentTerms,
      _PaymentMethod,
      _CompanyCode,
      _CustomerAccountAssgmtGroup,
      _ExchangeRateType,
      _DunningArea,
      _DunningBlockingReason,
      _DunningKey,
      _SoldToParty,
      _CustomerGroup,
      _Country,
      _CityCode,
      _SalesDistrict,
      _Region,

      @API.element: { releaseState: #DEPRECATED, successor: '_County_2' }
      _County,

      _County_2,
      _CreditControlArea,
      _OvrlBillingDocReqStatus,
      _BillingIssueType,
      _OverallPricingIncompletionSts,

      @Consumption.hidden: true
      _CreditControlAreaText
}

where SDDocumentCategory = 'EBDR';

Learn More