R_BillingDocumentItemTextTP

DDL: R_BILLINGDOCUMENTITEMTEXTTP Type: view_entity TRANSACTIONAL Package: RAP_SD_BIL_BD

Billing Document Item Text - TP

R_BillingDocumentItemTextTP is a Transactional CDS View that provides data about "Billing Document Item Text - TP" in SAP S/4HANA. It reads from 3 data sources (I_BillingDocument, I_BillingDocumentType_2, P_BillingDocumentText) and exposes 13 fields with key fields BillingDocument, BillingDocumentItem, Language, LongTextID. It has 4 associations to related views. Part of development package RAP_SD_BIL_BD.

3 data source(s) 13 fields

Data Sources (3)

SourceAliasJoin Type
I_BillingDocument BillingDocument inner
I_BillingDocumentType_2 BillingDocumentType inner
P_BillingDocumentText P_BillingDocumentText from

Associations (4)

CardinalityTargetAliasCondition
[1..1] R_BillingDocumentTP _BillingDocument $projection.BillingDocument = _BillingDocument.BillingDocument
[0..1] I_Language _Language $projection.LanguageForEdit = _Language.Language
[0..1] I_SDDocumentItemLongTextID _LongTextID $projection.LongTextIDForEdit = _LongTextID.LongTextID
[0..1] I_TextDeterminationProcedItem _TextDeterminationProcedItem $projection.BillgDocItemTextDetnProcedure = _TextDeterminationProcedItem.TextDeterminationProcedure and $projection.LongTextID = _TextDeterminationProcedItem.LongTextID and _TextDeterminationProcedItem.TextObjectCategory = 'VBBP' and _TextDeterminationProcedItem.TextDeterminationProcedObject = 'F'

Annotations (8)

NameValueLevelField
EndUserText.label Billing Document Item Text - TP view
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
VDM.viewType #TRANSACTIONAL view
AccessControl.authorizationCheck #MANDATORY view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.dataCategory #TEXT view

Fields (13)

KeyFieldSource TableSource FieldDescription
KEY BillingDocument Text BillingDocument
KEY BillingDocumentItem Text BillingDocumentItem
KEY Language Text Language
KEY LongTextID Text LongTextID
LanguageForEdit Text Language
LongTextIDForEdit Text LongTextID
LongText Text LongText
BillgDocItemTextDetnProcedure I_BillingDocumentType_2 BillgDocItemTextDetnProcedure
TextDeterminationProcedureItem _TextDeterminationProcedItem TextDeterminationProcedureItem
_Item _Item
_BillingDocument _BillingDocument
_Language _Language
_LongTextID _LongTextID 
@EndUserText.label: 'Billing Document Item Text - TP'

@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}
@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory: #L
  },
  dataCategory: #TEXT,
  semanticKey: ['BillingDocument', 'BillingDocumentItem', 'Language', 'LongTextID']
}

define view entity R_BillingDocumentItemTextTP 
  as select from P_BillingDocumentText( P_SAPClient : $session.client,
                                        P_td_object : 'VBBP') as Text

    inner join   I_BillingDocument                           as BillingDocument on BillingDocument.BillingDocument = Text.BillingDocument
    inner join   I_BillingDocumentType_2                       as BillingDocumentType on BillingDocument.BillingDocumentType = BillingDocumentType.BillingDocumentType

  association        to parent R_BillingDocumentItemTP       as _Item                        on  $projection.BillingDocument     = _Item.BillingDocument
                                                                                             and $projection.BillingDocumentItem = _Item.BillingDocumentItem

  association [1..1] to R_BillingDocumentTP            as _BillingDocument       on  $projection.BillingDocument = _BillingDocument.BillingDocument

  association [0..1] to I_Language                           as _Language                    on  $projection.LanguageForEdit = _Language.Language

  association [0..1] to I_SDDocumentItemLongTextID           as _LongTextID                  on  $projection.LongTextIDForEdit = _LongTextID.LongTextID

  association [0..1] to I_TextDeterminationProcedItem        as _TextDeterminationProcedItem on  $projection.BillgDocItemTextDetnProcedure                  = _TextDeterminationProcedItem.TextDeterminationProcedure
                                                                                             and $projection.LongTextID                                     = _TextDeterminationProcedItem.LongTextID
                                                                                             and _TextDeterminationProcedItem.TextObjectCategory            = 'VBBP'
                                                                                             and _TextDeterminationProcedItem.TextDeterminationProcedObject = 'F'

{
  key Text.BillingDocument,

  key Text.BillingDocumentItem,

  @Semantics.language: true
  key Text.Language,

  key Text.LongTextID,

      @ObjectModel: {
        foreignKey.association: '_Language',
        editableFieldFor: 'Language'
      }
      Text.Language                                    as LanguageForEdit,

      @ObjectModel: {
        foreignKey.association: '_LongTextID',
        editableFieldFor: 'LongTextID'
      }
      Text.LongTextID                                  as LongTextIDForEdit,

      @ObjectModel.virtualElement: true
      Text.LongText,
      @Consumption.hidden: true
      BillingDocumentType.BillgDocItemTextDetnProcedure,

      _TextDeterminationProcedItem.TextDeterminationProcedureItem,

      _Item,
      _BillingDocument,
      _Language,
      _LongTextID

}
where BillingDocument.BillingDocumentIsTemporary = ' '

Learn More