R_BillingDocumentTP

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@AccessControl.privilegedAssociations: [ '_CreatedByUser', '_PricingDocument' ]

@EndUserText.label: 'Billing Document - TP'

@ObjectModel.sapObjectNodeType.name: 'BillingDocument'
@ObjectModel.usageType: { dataClass: #TRANSACTIONAL, serviceQuality: #C, sizeCategory: #L }

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL

define root view entity R_BillingDocumentTP
  as select from           I_BillingDocument as BillingDocument

    left outer to one join I_OutputRequest   as OutputRequest
      on  OutputRequest.OutputControlApplicationObject = BillingDocument.BillingDocument
      and OutputRequest.OutputControlApplObjectType    = 'BILLING_DOCUMENT'

  composition [0..*] of           R_BillingDocumentItemTP    as _Item
  composition [0..*] of           R_BillingDocumentPartnerTP as _Partner
  composition [0..*] of           R_BillingDocumentTextTP    as _Text

  association of exact one to one R_PricingDocumentTP        as _PricingDocument
    on  $projection.PricingDocument              = _PricingDocument.PricingDocument
    and $projection.SAPObjectTypeInUppercase     = _PricingDocument.HostObjectNodeSONTInUppercase
    and $projection.PrcgDocumentHostObjectNodeID = _PricingDocument.HostObjectNodeID

  // Extensibility

  association [0..1]       to     E_BillingDocument          as _Extension
    on $projection.BillingDocument = _Extension.BillingDocument

{
  key BillingDocument.BillingDocument,

      BillingDocument.SDDocumentCategory,
      BillingDocument.BillingDocumentCategory,
      BillingDocument.BillingDocumentType,
      BillingDocument.CreatedByUser,
      BillingDocument.CreationDate,
      BillingDocument.CreationTime,
      BillingDocument.LastChangeDate,

      case tstmp_is_valid(cast(BillingDocument.LastChangeDateTime as abap.dec(15,0)))
        when 0 then cast(dats_tims_to_tstmp(BillingDocument.CreationDate, BillingDocument.CreationTime, 'UTC', $session.client, 'NULL') as timestampl)
        else BillingDocument.LastChangeDateTime
      end                                                                                                            as LastChangeDateTime,

      BillingDocument.LogicalSystem,
      BillingDocument.SalesOrganization,
      BillingDocument.DistributionChannel,
      BillingDocument.Division,
      BillingDocument.BillingDocumentDate,
      BillingDocument.BillingDocumentIsCancelled,
      BillingDocument.CancelledBillingDocument,
      BillingDocument.BillingDocCombinationCriteria,
      BillingDocument.ManualInvoiceMaintIsRelevant,
      BillingDocument.NmbrOfPages,
      BillingDocument.IsIntrastatReportingRelevant,
      BillingDocument.IsIntrastatReportingExcluded,
      BillingDocument.BillingDocumentIsTemporary,
      BillingDocument.TotalNetAmount,
      BillingDocument.TransactionCurrency,
      BillingDocument.StatisticsCurrency,
      BillingDocument.TotalTaxAmount,
      BillingDocument._EnhancedFields.TotalGrossAmount,
      BillingDocument.CustomerPriceGroup,
      BillingDocument.PriceListType,
      BillingDocument.TaxDepartureCountry,
      BillingDocument.VATRegistration,
      BillingDocument.VATRegistrationOrigin,
      BillingDocument.VATRegistrationCountry,
      BillingDocument.HierarchyTypePricing,
      BillingDocument.CustomerTaxClassification1,
      BillingDocument.CustomerTaxClassification2,
      BillingDocument.CustomerTaxClassification3,
      BillingDocument.CustomerTaxClassification4,
      BillingDocument.CustomerTaxClassification5,
      BillingDocument.CustomerTaxClassification6,
      BillingDocument.CustomerTaxClassification7,
      BillingDocument.CustomerTaxClassification8,
      BillingDocument.CustomerTaxClassification9,
      BillingDocument.IsEUTriangularDeal,
      BillingDocument.SDPricingProcedure,
      BillingDocument.ShippingCondition,
      BillingDocument.IncotermsVersion,
      BillingDocument.IncotermsClassification,
      BillingDocument.IncotermsTransferLocation,
      BillingDocument.IncotermsLocation1,
      BillingDocument.IncotermsLocation2,
      BillingDocument.PayerParty,
      BillingDocument.ContractAccount,
      BillingDocument.CustomerPaymentTerms,

      // Wrong foreign key association is used in the basic interface view

      @ObjectModel.foreignKey.association: null
      BillingDocument.PaymentMethod,

      BillingDocument.PaymentReference,
      BillingDocument.FixedValueDate,
      BillingDocument.AdditionalValueDays,
      BillingDocument.SEPAMandate,
      BillingDocument.DeviatingPostingDate,
      BillingDocument.CompanyCode,
      BillingDocument.FiscalYear,
      BillingDocument.AccountingDocument,
      BillingDocument.FiscalPeriod,
      BillingDocument.CustomerAccountAssignmentGroup,
      BillingDocument.AccountingExchangeRateIsSet,
      cast(abs(BillingDocument.AccountingExchangeRate) as kurrf_abs)                                                 as AbsltAccountingExchangeRate, // new

      cast(case when BillingDocument.AccountingExchangeRate < 0 then 'X' else ' ' end  as kurrf_quotatn_is_indirect) as AcctgExchangeRateIsIndrctQtan, // new

      BillingDocument.AccountingExchangeRate, // TBD: Which rate? AccountingExchangeRate or AbsltAccountingExchangeRate & AcctgExchangeRateIsIndrctQtan

      BillingDocument.ExchangeRateDate,
      BillingDocument.ExchangeRateType,
      BillingDocument.DocumentReferenceID,
      BillingDocument.AssignmentReference,
      BillingDocument.ReversalReason,
      BillingDocument.DunningArea,
      BillingDocument.DunningBlockingReason,
      BillingDocument.DunningKey,
      BillingDocument.InternalFinancialDocument,
      BillingDocument.IsRelevantForAccrual,
      BillingDocument.SoldToParty,
      BillingDocument.PartnerCompany,
      BillingDocument.PurchaseOrderByCustomer,
      BillingDocument.CustomerGroup,
      BillingDocument.Country,
      BillingDocument.CityCode,
      BillingDocument.SalesDistrict,
      BillingDocument.Region,

      @ObjectModel.foreignKey.association: '_County'
      BillingDocument.County,

      BillingDocument.CreditControlArea,
      BillingDocument.CustomerRebateAgreement,
      BillingDocument.PricingDocument,
      cast('BILLINGDOCUMENT' as sap_object_type)                                                                     as SAPObjectTypeInUppercase,
      cast(BillingDocument.BillingDocument as pricingdochostobjectnodeid)                                            as PrcgDocumentHostObjectNodeID,

      BillingDocument.OverallSDProcessStatus,
      BillingDocument.OverallBillingStatus,
      BillingDocument.AccountingPostingStatus,
      BillingDocument.AccountingTransferStatus,
      BillingDocument.BillingIssueType,
      BillingDocument.InvoiceListStatus,
      BillingDocument.OvrlItmGeneralIncompletionSts,
      BillingDocument.OverallPricingIncompletionSts,
      BillingDocument.InvoiceClearingStatus,
      BillingDocument.InvoiceListType,
      BillingDocument.InvoiceListBillingDate,
      OutputRequest.OutputRequestUUID                                                                                as OutputRequestUUID,
      /* Associations */
      BillingDocument._AccountingDocument,
      BillingDocument._AccountingPostingStatus,
      BillingDocument._AccountingTransferStatus,
      BillingDocument._BillingDocumentCategory,
      BillingDocument._BillingDocumentType,
      BillingDocument._BillingIssueType,
      BillingDocument._CancelledBillingDocument,
      BillingDocument._CityCode,
      BillingDocument._CompanyCode,
      BillingDocument._Country,
      BillingDocument._County_2                                                                                      as _County,
      BillingDocument._CreatedByUser,
      BillingDocument._CreditControlArea,
      BillingDocument._CustomerAccountAssgmtGroup,
      BillingDocument._CustomerGroup,
      BillingDocument._CustomerPaymentTerms,
      BillingDocument._CustomerPriceGroup,
      BillingDocument._DistributionChannel,
      BillingDocument._Division,
      BillingDocument._DunningArea,
      BillingDocument._DunningBlockingReason,
      BillingDocument._DunningKey,
      BillingDocument._ExchangeRateType,
      BillingDocument._FiscalYear,
      BillingDocument._IncotermsClassification,
      BillingDocument._IncotermsVersion,
      BillingDocument._InvoiceClearingStatus,
      BillingDocument._InvoiceListStatus,
      BillingDocument._InvoiceListType,

      _Item,
      _Partner,
      _Text,
      _PricingDocument,

      BillingDocument._LogicalSystem,
      BillingDocument._OverallBillingStatus,
      BillingDocument._OverallPricingIncompletionSts,
      BillingDocument._OverallSDProcessStatus,
      BillingDocument._OvrlItmGeneralIncompletionSts,
      BillingDocument._PayerParty,
      BillingDocument._PriceListType,
      BillingDocument._Region,
      BillingDocument._ReversalReason,
      BillingDocument._SalesDistrict,
      BillingDocument._SalesOrganization,
      BillingDocument._SDDocumentCategory,
      BillingDocument._SDPricingProcedure,
      BillingDocument._ShippingCondition,
      BillingDocument._SoldToParty,
      BillingDocument._StatisticsCurrency,
      BillingDocument._TaxDepartureCountry,
      BillingDocument._TransactionCurrency,
      BillingDocument._VATRegistrationCountry,
      BillingDocument._VATRegistrationOrigin
}

where BillingDocument.BillingDocumentIsTemporary = ' '