I_WorkPermitTemplate

@AbapCatalog.sqlViewName: 'IWRKPMTTEMPLATE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Work Permit Template'
@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@ObjectModel.usageType: { serviceQuality: #C, sizeCategory:#L , dataClass:#TRANSACTIONAL }
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'WorkPermit'
@ObjectModel.semanticKey: ['WorkPermit']
define view I_WorkPermitTemplate
  as select from I_WorkPermitBasic as _PermitBasic

  association [1..1] to I_WorkPermitTemplateType     as _WorkPermitType             on  $projection.WorkPermitType           = _WorkPermitType.WorkPermitType
                                                                                    and $projection.MaintenancePlanningPlant = _WorkPermitType.MaintenancePlanningPlant
  association [0..1] to I_Plant                      as _PermitPlanningPlant        on  $projection.MaintenancePlanningPlant = _PermitPlanningPlant.Plant
  association [1..1] to I_MaintenancePlannerGroup    as _MaintenancePlannerGroup    on  $projection.MaintenancePlannerGroup  = _MaintenancePlannerGroup.MaintenancePlannerGroup
                                                                                    and $projection.MaintenancePlanningPlant = _MaintenancePlannerGroup.MaintenancePlanningPlant
  association [0..1] to I_WorkCenter                 as _MainWorkCenter             on  $projection.OperationWorkCenterInternalID = _MainWorkCenter.WorkCenterInternalID
                                                                                    and $projection.ObjectTypeCode                = _MainWorkCenter.WorkCenterTypeCode
  association [1..1] to I_PermitToWorkProfile        as _PermitToWorkProfile        on  $projection.MaintenancePlanningPlant = _PermitToWorkProfile.MaintenancePlanningPlant
  association [0..1] to I_User                       as _CreatedByUser              on  _CreatedByUser.UserID = $projection.CreatedByUser
  association [0..1] to I_User                       as _LastChangedByUser          on  _LastChangedByUser.UserID = $projection.LastChangedByUser
  association [1..1] to I_WrkPmtProcessingStatusText as _WrkPmtProcessingStatusText on  _WrkPmtProcessingStatusText.WorkPermitProcessingStatus = $projection.WorkPermitProcessingStatus
                                                                                    and _WrkPmtProcessingStatusText.Language                   = $session.system_language
                                                                                    and _WrkPmtProcessingStatusText.Name                       = 'PTWDWORKPERMITPROCESSINGSTATUS'
  association [0..1] to I_WorkPermitStatus           as _WorkPermitStatus           on  _WorkPermitStatus.WorkPermit           = $projection.WorkPermit
                                                                                    and _WorkPermitStatus.WorkPermitInternalID = $projection.WorkPermitInternalID
                                                                                    and _WorkPermitStatus.StatusCode           = 'I0175'
  association [0..1] to I_Plant                      as _WorkCenterPlant            on  $projection.WorkCenterPlant = _WorkCenterPlant.Plant
{
  key _PermitBasic.WorkPermit,
      _PermitBasic.WorkPermitInternalID,
      _PermitBasic.WrkPmtMgmtObjSubType,
      @ObjectModel.foreignKey.association: '_WorkPermitType'
      _PermitBasic.WorkPermitType,
      @Semantics.text :true
      _PermitBasic.WrkPermitDesc,
      _PermitBasic.WorkPermitHasLongText,
      _PermitBasic.WorkPermitTmplID,
      _PermitBasic.WrkPermitIsDeleted,
      _PermitBasic.MaintenancePlannerGroup,
      _PermitBasic.MaintenancePlanningPlant,
      _PermitBasic.ObjectTypeCode,
      _PermitBasic.OperationWorkCenterInternalID,
      _PermitBasic.TechObjAuthorizationGroup,
      _PermitBasic.WrkPermitValidFrmDate,
      _PermitBasic.WrkPermitValidFrmTime,
      _PermitBasic.WrkPermitValidToDate,
      $session. system_date                              as CurrentDate,
      cast ( tstmp_current_utctimestamp() as tzntstmps ) as CurrentDateTime,
      _PermitBasic.WrkPermitValidToTime,
      _PermitBasic.WrkPmtMgmtPriority,
      _PermitBasic.FunctionalLocation,
      _PermitBasic.Equipment,
      _PermitBasic.WrkPermitHasObjectList,
      _CreatedByUser.UserDescription                     as CreatedByUserName,
      _LastChangedByUser.UserDescription,
      @Semantics.user.createdBy: true
      _PermitBasic.CreatedByUser,
      _PermitBasic.CreationDate,
      _PermitBasic.CreationTime,
      @Semantics.systemDateTime.createdAt: true
      _PermitBasic.CreationDateTime,
      @Semantics.user.lastChangedBy: true
      _PermitBasic.LastChangedByUser,
      _PermitBasic.LastChangeDate,
      _PermitBasic.LastChangeTime,
      @Semantics.systemDateTime.lastChangedAt: true
      _PermitBasic.LastChangeDateTime,
      _PermitBasic.ValidFromDateTime,
      _PermitBasic.ValidToDateTime,
      _PermitBasic.WrkPermitIsLinkdToDoc,
      _PermitBasic.StatusProfile,
      _PermitBasic.WrkPermitHasMaintRemark,
      _PermitBasic.WrkPermitHasOpRemark,
      _PermitBasic.WorkPermitOperationLongTextKey,
      _PermitBasic.WrkPmtMaintenanceLongTextKey,
      _PermitBasic.LongTextKey,
      cast (case
       when _WorkPermitStatus.StatusCode is not initial
       then 'X'
       else '' end as  xfeld )                           as IsApproved,
      _MainWorkCenter.WorkCenter,
      _MainWorkCenter._Text[1: Language = $session.system_language ].WorkCenterText,
      _MainWorkCenter.Plant                              as WorkCenterPlant,
      _MaintenancePlannerGroup,
      _PermitPlanningPlant,
      _PermitToWorkProfile,
      _MainWorkCenter,
      _WorkPermitType,
      _LastChangedByUser,
      _CreatedByUser,
      cast ('' as vdm_j_system_status_concat_t)          as WrkPmtCnctntdActvSystStsTxt,
      cast( '' as abap.char( 1333 ) )                    as WrkPmtChgStsActnEnbldVal,
      _PermitBasic.WorkPermitProcessingStatus,
      _WrkPmtProcessingStatusText.WorkPermitProcessingStatusText,
      _WrkPmtProcessingStatusText,
      _WorkCenterPlant
}
where
  (
    WrkPmtMgmtObjSubType = 'M'
  );