I_WorkPermitBasic

@AbapCatalog.sqlViewName: 'IWRKPMTBASIC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #MANDATORY
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@ObjectModel.usageType: { serviceQuality: #C, sizeCategory:#L , dataClass:#TRANSACTIONAL }
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'WorkPermit'
@ObjectModel.semanticKey: ['WorkPermit']
@EndUserText.label: 'Work Permit'

define view I_WorkPermitBasic
  as select from wcaap
{
  key wapinr                                             as WorkPermit,
      objnr                                              as WorkPermitInternalID,
      wapityp                                            as WrkPmtMgmtObjSubType,
      wapiuse                                            as WorkPermitType,
      @Semantics.text :true
      stxt                                               as WrkPermitDesc,
      lflg                                               as WorkPermitHasLongText,
      delflg                                             as WrkPermitIsDeleted,
      ingrp                                              as MaintenancePlannerGroup,
      iwerk                                              as MaintenancePlanningPlant,
      wkcrtyp                                            as ObjectTypeCode,
      wkcrid                                             as OperationWorkCenterInternalID,
      begru                                              as TechObjAuthorizationGroup,
      datefr                                             as WrkPermitValidFrmDate,
      timefr                                             as WrkPermitValidFrmTime,
      dateto                                             as WrkPermitValidToDate,
      timeto                                             as WrkPermitValidToTime,
      priok                                              as WrkPmtMgmtPriority,
      cast ( tplnr as eams_ui_oid_name preserving type ) as FunctionalLocation,
      equnr                                              as Equipment,
      lnkflg                                             as WrkPermitHasObjectList,
      @Semantics.user.createdBy: true
      crname                                             as CreatedByUser,
      crdate                                             as CreationDate,
      crtime                                             as CreationTime,
      @Semantics.systemDateTime.createdAt: true
      cast( dats_tims_to_tstmp( wcaap.crdate,
                        wcaap.crtime,
                        abap_system_timezone( $session.client,'NULL' ),
                        $session.client,
                       'NULL' ) as timestamp )           as CreationDateTime,
      @Semantics.user.lastChangedBy: true
      chname                                             as LastChangedByUser,
      chname                                             as VersionLastChangedByUser,
      chdate                                             as LastChangeDate,
      chtime                                             as LastChangeTime,
      @Semantics.systemDateTime.lastChangedAt: true
      cast( dats_tims_to_tstmp( wcaap.chdate,
                       wcaap.chtime,
                       abap_system_timezone( $session.client,'NULL' ),
                       $session.client,
                      'NULL' ) as timestamp )            as LastChangeDateTime,
      cast( dats_tims_to_tstmp( wcaap.datefr,
                   wcaap.timefr,
                   abap_system_timezone( $session.client,'NULL' ),
                   $session.client,
                  'NULL' ) as timestamp )                as ValidFromDateTime,
      cast($session.user_timezone as tznzone)            as PlantTimeZone,
      cast( dats_tims_to_tstmp( wcaap.dateto,
                          wcaap.timeto,
                          abap_system_timezone( $session.client,'NULL' ),
                          $session.client,
                         'NULL' ) as timestamp )         as ValidToDateTime,
      docflg                                             as WrkPermitIsLinkdToDoc,
      wapistsma                                          as StatusProfile,
      refobj                                             as WorkPermitTmplID,

      remarkflg1                                         as WrkPermitHasMaintRemark,
      remarkflg2                                         as WrkPermitHasOpRemark,
      case wcaap.remarkflg2
             when 'X' then cast(concat(wcaap.objnr, 'REM2') as tdobname)
             else '' end                                 as WorkPermitOperationLongTextKey,

      case wcaap.remarkflg1
        when 'X' then cast( concat( wcaap.objnr,'REM1') as tdobname)
        else '' end                                      as WrkPmtMaintenanceLongTextKey,

      case wcaap.lflg
       when 'X' then cast(concat(wcaap.objnr, 'LTXT' ) as tdobname)
       else '' end                                       as LongTextKey,
      workpermitprocessingstatus                         as WorkPermitProcessingStatus
}
where
     wapityp = 'P'
  or wapityp = 'M'