I_WorkPermitOrder

DDL: I_WORKPERMITORDER Type: view_entity BASIC Package: VDM_EAM_WCM_PERMIT_TO_WORK

Work Permit Assigned Orders

I_WorkPermitOrder is a Basic CDS View that provides data about "Work Permit Assigned Orders" in SAP S/4HANA. It reads from 2 data sources (I_WorkPermitBasic, I_WorkPermitOrderBasic) and exposes 17 fields with key fields MaintenanceOrderInternalID, WorkPermitInternalID. It has 3 associations to related views. Part of development package VDM_EAM_WCM_PERMIT_TO_WORK.

2 data source(s) 17 fields

Data Sources (2)

SourceAliasJoin Type
I_WorkPermitBasic _WorkPermitBasic inner
I_WorkPermitOrderBasic _WorkPermitOrderBasic from

Associations (3)

CardinalityTargetAliasCondition
[1..1] I_MaintenanceOrder _MaintenanceOrder $projection.MaintenanceOrderInternalID = _MaintenanceOrder.MaintenanceOrderInternalID
[0..1] I_MaintenancePlanPlant _MaintenancePlanPlant $projection.maintenanceplanningplant = _MaintenancePlanPlant.MaintenancePlanningPlant
[1..1] I_OrderType _MaintenanceOrderType $projection.maintenanceordertype = _MaintenanceOrderType.OrderType

Annotations (7)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
AccessControl.personalData.blocking #NOT_REQUIRED view
EndUserText.label Work Permit Assigned Orders view
VDM.viewType #BASIC view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view

Fields (17)

KeyFieldSource TableSource FieldDescription
KEY MaintenanceOrderInternalID I_WorkPermitOrderBasic MaintenanceOrderInternalID
KEY WorkPermitInternalID I_WorkPermitOrderBasic WorkPermitInternalID
WorkPermit I_WorkPermitBasic WorkPermit
WrkPermitDesc I_WorkPermitBasic WrkPermitDesc
MaintenanceOrder _MaintenanceOrder MaintenanceOrder
MaintenanceOrderDesc _MaintenanceOrder MaintenanceOrderDesc
MaintenancePlanningPlant _MaintenanceOrder MaintenancePlanningPlant
MaintenanceOrderType _MaintenanceOrder MaintenanceOrderType
MaintOrderRoutingNumber _MaintenanceOrder MaintOrderRoutingNumber
WorkPermitOrderObjectType I_WorkPermitOrderBasic WorkPermitOrderObjectType
WorkPermitObjectType I_WorkPermitOrderBasic WorkPermitObjectType
WrkPmtProcessingContext I_WorkPermitOrderBasic WrkPmtProcessingContext
IsReferenceDocument I_WorkPermitOrderBasic IsReferenceDocument
MaintOrdCnctntdActvSystSts
_MaintenanceOrder _MaintenanceOrder
_MaintenancePlanPlant _MaintenancePlanPlant
_MaintenanceOrderType _MaintenanceOrderType 
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Work Permit Assigned Orders'
@VDM.viewType: #BASIC
@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C, //#B,

     sizeCategory:   #L
   }
}

define view entity I_WorkPermitOrder
  as select from I_WorkPermitOrderBasic as _WorkPermitOrderBasic
    inner join   I_WorkPermitBasic      as _WorkPermitBasic on _WorkPermitBasic.WorkPermitInternalID = _WorkPermitOrderBasic.WorkPermitInternalID
  association [1..1] to I_MaintenanceOrder         as _MaintenanceOrder     on $projection.MaintenanceOrderInternalID = _MaintenanceOrder.MaintenanceOrderInternalID
  association [0..1] to I_MaintenancePlanPlant        as _MaintenancePlanPlant       on  $projection.maintenanceplanningplant = _MaintenancePlanPlant.MaintenancePlanningPlant
  association [1..1] to I_OrderType                   as _MaintenanceOrderType       on  $projection.maintenanceordertype = _MaintenanceOrderType.OrderType    
{
  key _WorkPermitOrderBasic.MaintenanceOrderInternalID,
  key _WorkPermitOrderBasic.WorkPermitInternalID,
      _WorkPermitBasic.WorkPermit,
      _WorkPermitBasic.WrkPermitDesc,
      _MaintenanceOrder.MaintenanceOrder,
      _MaintenanceOrder.MaintenanceOrderDesc,
      @ObjectModel.foreignKey.association: '_MaintenancePlanPlant'
      _MaintenanceOrder.MaintenancePlanningPlant,
      @ObjectModel.foreignKey.association: '_MaintenanceOrderType'
      _MaintenanceOrder.MaintenanceOrderType,
      _MaintenanceOrder.MaintOrderRoutingNumber,
      _WorkPermitOrderBasic.WorkPermitOrderObjectType,
      _WorkPermitOrderBasic.WorkPermitObjectType,
      _WorkPermitOrderBasic.WrkPmtProcessingContext,  
      _WorkPermitOrderBasic.IsReferenceDocument,         
      cast ('' as vdm_j_system_status_concat_t) as MaintOrdCnctntdActvSystSts,
      
      case 
        when _MaintenanceOrder.Equipment is not null and _MaintenanceOrder.Equipment <> ''         
          then cast( _MaintenanceOrder.Equipment as eams_tec_obj )
        when _MaintenanceOrder._LocationAccountAssignment.FunctionalLocation is not null and _MaintenanceOrder._LocationAccountAssignment.FunctionalLocation <> ''
          then cast( _MaintenanceOrder._LocationAccountAssignment.FunctionalLocation as eams_tec_obj )
          else
           ''
      end as TechnicalObject,
      
      case 
        when _MaintenanceOrder.Equipment is not null and _MaintenanceOrder.Equipment <> ''         
          then cast( _MaintenanceOrder._Equipment._EquipmentText[1: Language = $session.system_language].EquipmentName as eams_tec_obj_des )
        when _MaintenanceOrder._LocationAccountAssignment.FunctionalLocation is not null and _MaintenanceOrder._LocationAccountAssignment.FunctionalLocation <> ''
//          then cast( _LocationAccountAssignment._FunctionalLocation._FunctionalLocationText.FunctionalLocationName as eams_tec_obj_des )

          then cast( _MaintenanceOrder._LocationAccountAssignment._FunctionalLocation._FunctionalLocationText[1: Language = $session.system_language].FunctionalLocationName as eams_tec_obj_des )          
          else
           ''
      end as TechnicalObjectDescription, 
      _MaintenanceOrder  ,
      _MaintenancePlanPlant,
      _MaintenanceOrderType      
}

Learn More