I_Site

@EndUserText: {label: 'Retail Site'}
@AbapCatalog: {
    sqlViewName: 'ISITE',
    compiler: {
        compareFilter: true
    }
} 

@AccessControl: {
    authorizationCheck: #CHECK,
    personalData.blocking: #NOT_REQUIRED
}

@AbapCatalog.preserveKey:true

@Metadata.ignorePropagatedAnnotations: true

@ClientHandling: {algorithm: #SESSION_VARIABLE}
@VDM: {viewType: #BASIC}

@ObjectModel: {
    compositionRoot: true,
    semanticKey: 'Site',
    representativeKey: 'Site',
    supportedCapabilities: [ #SQL_DATA_SOURCE,
                             #CDS_MODELING_DATA_SOURCE,
                             #CDS_MODELING_ASSOCIATION_TARGET ],
    usageType: {
        serviceQuality: #A,
        sizeCategory: #M,
        dataClass: #MASTER
   }
}

define view I_Site
  as select from I_Plant
  association [0..1] to I_SiteOpeningHours       as _SiteOpeningHours              on  $projection.SiteCustomer = _SiteOpeningHours.SiteCustomer
  association [0..1] to I_SitePointOfSale        as _SitePointOfSale               on  $projection.SiteCustomer = _SitePointOfSale.SiteCustomer
  association [0..1] to I_SiteBlocking           as _SiteBlocking                  on  $projection.SiteCustomer = _SiteBlocking.SiteCustomer
  association [1..1] to I_SalesOrganization      as _SalesOrganization             on  $projection.SalesOrganization = _SalesOrganization.SalesOrganization
  association [1..1] to I_DistributionChannel    as _DistributionChannel           on  $projection.DistributionChannel = _DistributionChannel.DistributionChannel
  /*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
  association [1..1] to I_PurchasingOrganization as _DefaultPurchasingOrganization on  $projection.DefaultPurchasingOrganization = _DefaultPurchasingOrganization.PurchasingOrganization
  association [0..1] to I_FactoryCalendar        as _FactoryCalendar               on  $projection.FactoryCalendar = _FactoryCalendar.FactoryCalendar
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
  association [0..1] to I_AddressEmailAddress    as _AddressEmailAddress           on  $projection.AddressID                      = _AddressEmailAddress.AddressID
                                                                                   and _AddressEmailAddress.Person                = ' '
                                                                                   and _AddressEmailAddress.IsDefaultEmailAddress = 'X'
  association [0..*] to I_SiteProductGroup       as _SiteProductGroup              on  $projection.SiteCustomer = _SiteProductGroup.SiteCustomer
  association [0..*] to I_SiteSupplyingSite      as _SiteSupplyingSite             on  $projection.SiteCustomer = _SiteSupplyingSite.SiteCustomer
  association [0..*] to I_AssortmentUser         as _AssortmentUser                on  $projection.SiteCustomer = _AssortmentUser.SiteCustomer
  association [1..1] to I_SiteReferenceSite      as _SiteReferenceSite             on  $projection.Site = _SiteReferenceSite.Site
  /*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
  association [1..1] to I_SiteCategory           as _SiteCategory                  on  $projection.SiteCategory = _SiteCategory.SiteCategory
  association [0..1] to I_SiteMasterAdministrativeData as _SiteMasterAdminFields   on  $projection.SiteCustomer = _SiteMasterAdminFields.SiteCustomer
  association [0..1] to I_SiteValnAndInvtryManagement  as _SiteInventory           on  $projection.SiteCustomer = _SiteInventory.SiteCustomer  
 
{
      @ObjectModel: {text: {element: 'SiteName'}}
  key Plant                                                           as Site,
      @Semantics.text:true
      cast(PlantName as sitename preserving type)                     as SiteName,
      PlantCustomer                                                   as SiteCustomer,
      PlantSupplier                                                   as SiteSupplier,
      AddressID,
      cast(PlantCategory as sitecategory preserving type)             as SiteCategory,
      @ObjectModel: {foreignKey: {association: '_SalesOrganization'}}
      cast(SalesOrganization as w_vkorg_header preserving type)       as SalesOrganization,
      @ObjectModel: {foreignKey: {association: '_DistributionChannel'}}
      cast(DistributionChannel as w_vtweg_header preserving type)     as DistributionChannel,
      @ObjectModel: {foreignKey: {association: '_DefaultPurchasingOrganization'}}
      cast(DefaultPurchasingOrganization as ekorg_ll preserving type) as DefaultPurchasingOrganization,
      @EndUserText: {quickInfo: 'Calendar', label: 'Calendar'}
      @ObjectModel: {foreignKey: {association: '_FactoryCalendar'}}
      FactoryCalendar,
      ValuationArea,
      IsMarkedForArchiving,
      Division,
      @ObjectModel: {association: {type: [#TO_COMPOSITION_CHILD]}}
      _SiteOpeningHours,
      @ObjectModel: {association: {type: [#TO_COMPOSITION_CHILD]}}
      _SitePointOfSale,
      @ObjectModel: {association: {type: [#TO_COMPOSITION_CHILD]}}
      _SiteBlocking,
      _Address,
      _OrganizationAddress,
      _Customer,
      _Supplier,
      /*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
      _PlantCategoryText                                              as _SiteCategoryText,

      _SalesOrganization,
      _DistributionChannel,
      _DefaultPurchasingOrganization,
      _FactoryCalendar,
      _AddressEmailAddress,
      @ObjectModel: {association: {type: [#TO_COMPOSITION_CHILD]}}
      _SiteProductGroup,
      @ObjectModel: {association: {type: [#TO_COMPOSITION_CHILD]}}
      _SiteSupplyingSite,
      _AssortmentUser,
      @ObjectModel: {association: {type: [#TO_COMPOSITION_CHILD]}}
      _SiteReferenceSite,
      @ObjectModel: {foreignKey: {association: '_SiteCategory'}}
      _SiteCategory,
      _SiteMasterAdminFields,
      _SiteInventory
      
}
where
     PlantCategory = 'A'
  or PlantCategory = 'B'