I_ExternalStoreListingTP

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Product Assignment to Store by External Source'
@VDM: {
  viewType: #TRANSACTIONAL,

  lifecycle: {
    contract: {
      type: #SAP_INTERNAL_API
    }
  }
}
@ObjectModel: {
    usageType: {
        serviceQuality: #C,
        sizeCategory: #XL,
        dataClass: #MASTER
   },
   sapObjectNodeType.name: 'ListingCondition'
}
define root view entity I_ExternalStoreListingTP
  as select from I_ProductToAssortmentModule as product
    inner join   I_AsstmtMdlUsrToAsstmtMdl_2 as user       on product.AssortmentModuleUUID = user.AssortmentModuleObjectUUID
    inner join   I_ExternalAssortmentModule  as ext_module on ext_module.AssortmentModuleUUID = product.AssortmentModuleUUID
    inner join   I_Site                      as site       on site.SiteCustomer = user.AssortmentModuleUser
{
  key user.AssortmentModuleUser as AssortmentModuleUser,
  key product.Product           as Product,
  key product.ValidityStartDate as ValidityStartDate,
  key product.ValidityEndDate   as ValidityEndDate,
      ext_module.LastChangeDate,
      ext_module.LastChangeDateTime,
      site.Site                 as Site,
      site.SalesOrganization    as SalesOrganization,
      site.DistributionChannel  as DistributionChannel
}