C_AURSStore

@EndUserText.label: 'Store'

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED

@VDM.viewType: #CONSUMPTION
@VDM.usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]
@Metadata.allowExtensions: true
@ObjectModel: {
    representativeKey: 'Store',
    semanticKey: ['Store'],
    usageType.serviceQuality: #C,
    usageType.sizeCategory: #M,
    usageType.dataClass: #MASTER
}
define root view entity C_AURSStore
  as select from I_Site

  composition [0..*] of C_AURSStoreUser               as _AssignedUser
  association [0..1] to I_RetailStoreUserAssignment   as _RetailStoreUserAssignment   on  _RetailStoreUserAssignment.Store        = $projection.Store
                                                                                      and _RetailStoreUserAssignment.AssignedUser = $session.user
  association [0..*] to I_RetailStoreApplicationStore as _RetailStoreApplicationStore on  _RetailStoreApplicationStore.Store                          = $projection.Store
                                                                                      and _RetailStoreApplicationStore.RetailStoreApplicationCategory = '2'
  composition [0..*] of C_AURSAssignableUser          as _AssignableUser

{
      @Consumption.semanticObject: 'Site'
      @ObjectModel.text.element: ['StoreName']
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_SiteStdVH',
                     element: 'Site' }
        }]
  key cast(Site as store preserving type)         as Store,

      @Semantics.text: true
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_SiteStdVH',
                     element: 'SiteName' }
        }]
      cast(SiteName as storename preserving type) as StoreName,

      AddressID                                   as AddressID,

      @ObjectModel.virtualElement:true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_RETAIL_ST_ADDRESS_FORMAT'
      cast('' as char200)                         as FormattedAddress,

      @Semantics.booleanIndicator: true
      case when _RetailStoreUserAssignment.Store is not null then 'X'
           else ''
      end                                         as RetailStoreIsAssignedToUser,

      @ObjectModel.virtualElement:true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_RTST_AU_SADL_CALC_EXIT'
      cast('' as boolean)                         as UserHasStoreUserAssignAuthzn,

      @ObjectModel.virtualElement:true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_RTST_AU_SADL_CALC_EXIT'
      cast('' as boolean)                         as UserHasStoreUserUnassignAuthzn,

      @Consumption.valueHelpDefinition: [
              { entity:  { name:    'I_SiteStdVH',
                           element: 'PostalCode' }
              }]
      _Address.PostalCode                         as PostalCode,

      @Semantics.text: true
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_SiteStdVH',
                     element: 'CityName' }
        }]
      _Address.CityName                           as CityName,

      @Consumption.valueHelpDefinition: [
              { entity:  { name:    'I_SiteStdVH',
                           element: 'StreetName' }
              }]
      _Address.StreetName                         as StreetName,

      _RetailStoreApplicationStore,

      _AssignedUser,
      _AssignableUser
}
where
  SiteCategory = 'A'