I_REUsableObject

DDL: I_REUSABLEOBJECT Type: view_entity COMPOSITE Package: VDM_RE_GO

Real Estate Usable Object

I_REUsableObject is a Composite CDS View (Dimension) that provides data about "Real Estate Usable Object" in SAP S/4HANA. It reads from 1 data source (I_REGenericRentalObject) and exposes 39 fields with key field RealEstateUsableObjectUUID. It has 7 associations to related views. Part of development package VDM_RE_GO.

1 data source(s) 39 fields

Data Sources (1)

SourceAliasJoin Type
I_REGenericRentalObject I_REGenericRentalObject from

Associations (7)

CardinalityTargetAliasCondition
[0..*] I_RERntblObjToUsblObjAssgmt _REUsblObjToRntblObjAssgmt $projection.RealEstateUsableObjectUUID = _REUsblObjToRntblObjAssgmt.RealEstateUsableObjectUUID
[0..*] I_REUsblObjToRntblObjAssgmt _RERntblObjToUsblObjAssgmt $projection.RealEstateUsableObjectUUID = _RERntblObjToUsblObjAssgmt.RealEstateUsableObjectUUID
[0..*] I_REUsableObjectMeasurement _REUsableObjectMeasurement $projection.RealEstateUsableObjectUUID = _REUsableObjectMeasurement.RealEstateUsableObjectUUID
[0..*] I_REUsblObjLdngAcctAssgmtObj _REUsblObjLdngAcctAssgmtObj $projection.RealEstateUsableObjectUUID = _REUsblObjLdngAcctAssgmtObj.RealEstateUsableObjectUUID
[0..*] I_REUsblObjAddlAcctAssgmtObj _REUsblObjAddlAcctAssgmtObj $projection.RealEstateUsableObjectUUID = _REUsblObjAddlAcctAssgmtObj.RealEstateUsableObjectUUID
[0..*] I_REUsblObjArchtrUsage _REUsblObjArchtrUsage $projection.RealEstateUsableObjectUUID = _REUsblObjArchtrUsage.RealEstateUsableObjectUUID
[0..*] I_REUsableObjectStatusObject _REUsableObjectStatusObject $projection.RealEstateUsableObjectUUID = _REUsableObjectStatusObject.RealEstateUsableObjectUUID

Annotations (16)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
EndUserText.label Real Estate Usable Object view
Analytics.dataCategory #DIMENSION view
Analytics.internalName #LOCAL view
Analytics.dataExtraction.enabled true view
ObjectModel.representativeKey RealEstateUsableObjectUUID view
ObjectModel.usageType.dataClass #MASTER view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.modelingPattern #ANALYTICAL_DIMENSION view
ObjectModel.objectIdentifier.oidElement RealEstateUsableObjectOID view
ObjectModel.sapObjectNodeType.name RealEstateUsableObject view
ODM.oid RealEstateUsableObjectOID view
Metadata.allowExtensions true view
Metadata.ignorePropagatedAnnotations true view
VDM.viewType #COMPOSITE view

Fields (39)

KeyFieldSource TableSource FieldDescription
KEY RealEstateUsableObjectUUID REGenericRentalObjectUUID
REGenericRentalObjectType REGenericRentalObjectType
InternalRealEstateNumber InternalRealEstateNumber
REStatusObject REStatusObject
RealEstateUsableObjectOID REGenericRentalObjectOID
REGnrcRntlObjectAlternativeID REGnrcRntlObjectAlternativeID
RealEstateUsableObjectNumber
REUsableObjectName
REIdentificationKey REIdentificationKey
CompanyCode CompanyCode
ValidityStartDate ValidityStartDate
ValidityEndDate ValidityEndDate
REAuthorizationGroup REAuthorizationGroup
REGnrcRentalObjUsageCategory REGnrcRentalObjUsageCategory
REGenericRentalObjectUsageType
REGenericRentalObjParentUUID REGenericRentalObjParentUUID
REGnrcRentalObjPortfolioID REGnrcRentalObjPortfolioID
REGnrcRentalObjOwnershipID REGnrcRentalObjOwnershipID
CreationDateTime CreationDateTime
LastChangeDateTime LastChangeDateTime
LocalLastChangeDateTime LocalLastChangeDateTime
_REKeyAssgmt _REKeyAssgmt
_CompanyCode _CompanyCode
_REAuthorizationGroup _REAuthorizationGroup
_REGnrcRentalObjUsageCategory _REGnrcRentalObjUsageCategory
_REGnrcRentalObjUsageType _REGnrcRentalObjUsageType
_REGnrcRentalObjOwnership _REGnrcRentalObjOwnership
_REGnrcRentalObjPortfolio _REGnrcRentalObjPortfolio
_REGenericRentalObjectType _REGenericRentalObjectType
_REArchitectureObject _REArchitectureObject
_StatusObject _StatusObject
_StatusObjectStatus _StatusObjectStatus
_REUsblObjToRntblObjAssgmt _REUsblObjToRntblObjAssgmt
_RERntblObjToUsblObjAssgmt _RERntblObjToUsblObjAssgmt
_REUsableObjectMeasurement _REUsableObjectMeasurement
_REUsblObjLdngAcctAssgmtObj _REUsblObjLdngAcctAssgmtObj
_REUsblObjAddlAcctAssgmtObj _REUsblObjAddlAcctAssgmtObj
_REUsblObjArchtrUsage _REUsblObjArchtrUsage
_REUsableObjectStatusObject _REUsableObjectStatusObject 
@AccessControl: {
  authorizationCheck: #MANDATORY,
  privilegedAssociations: ['_StatusObject', '_StatusObjectStatus']
}
@EndUserText.label: 'Real Estate Usable Object'
@Analytics: {
  dataCategory: #DIMENSION,
  internalName: #LOCAL,
  dataExtraction.enabled: true
}
@ObjectModel: {
  representativeKey: 'RealEstateUsableObjectUUID',
  semanticKey: ['RealEstateUsableObjectNumber'],
  usageType: {
    dataClass: #MASTER,
    serviceQuality: #C,
    sizeCategory: #L
  },
  modelingPattern: #ANALYTICAL_DIMENSION,
  supportedCapabilities: [
    #ANALYTICAL_DIMENSION, 
    #CDS_MODELING_ASSOCIATION_TARGET,
    #EXTRACTION_DATA_SOURCE
  ],
  objectIdentifier.oidElement: 'RealEstateUsableObjectOID',
  sapObjectNodeType.name: 'RealEstateUsableObject'
}
@ODM.oid: 'RealEstateUsableObjectOID'
@Metadata: {
  allowExtensions: true,
  ignorePropagatedAnnotations: true
}
@VDM.viewType: #COMPOSITE

define view entity I_REUsableObject
  as select from I_REGenericRentalObject

  association [0..*] to I_RERntblObjToUsblObjAssgmt as _REUsblObjToRntblObjAssgmt on $projection.RealEstateUsableObjectUUID = _REUsblObjToRntblObjAssgmt.RealEstateUsableObjectUUID
  association [0..*] to I_REUsblObjToRntblObjAssgmt as _RERntblObjToUsblObjAssgmt on $projection.RealEstateUsableObjectUUID = _RERntblObjToUsblObjAssgmt.RealEstateUsableObjectUUID

  association [0..*] to I_REUsableObjectMeasurement  as _REUsableObjectMeasurement  on $projection.RealEstateUsableObjectUUID = _REUsableObjectMeasurement.RealEstateUsableObjectUUID
  association [0..*] to I_REUsblObjLdngAcctAssgmtObj as _REUsblObjLdngAcctAssgmtObj on $projection.RealEstateUsableObjectUUID = _REUsblObjLdngAcctAssgmtObj.RealEstateUsableObjectUUID
  association [0..*] to I_REUsblObjAddlAcctAssgmtObj as _REUsblObjAddlAcctAssgmtObj on $projection.RealEstateUsableObjectUUID = _REUsblObjAddlAcctAssgmtObj.RealEstateUsableObjectUUID
  association [0..*] to I_REUsblObjArchtrUsage       as _REUsblObjArchtrUsage       on $projection.RealEstateUsableObjectUUID = _REUsblObjArchtrUsage.RealEstateUsableObjectUUID
  association [0..*] to I_REUsableObjectStatusObject as _REUsableObjectStatusObject on $projection.RealEstateUsableObjectUUID = _REUsableObjectStatusObject.RealEstateUsableObjectUUID

{
  key REGenericRentalObjectUUID                                                           as RealEstateUsableObjectUUID,
      @ObjectModel.foreignKey.association: '_REGenericRentalObjectType'
      REGenericRentalObjectType,
      InternalRealEstateNumber,
      @ObjectModel.foreignKey.association: '_StatusObject'
      REStatusObject,
      REGenericRentalObjectOID                                                            as RealEstateUsableObjectOID,
      REGnrcRntlObjectAlternativeID,
      cast( REGenericRentalObjectNumber as regogonrusable preserving type )               as RealEstateUsableObjectNumber,
      cast( REGenericRentalObjectName   as regovdmxusableobject preserving type )         as REUsableObjectName,
      REIdentificationKey,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      CompanyCode,
      ValidityStartDate,
      ValidityEndDate,
      @ObjectModel.foreignKey.association: '_REAuthorizationGroup'
      REAuthorizationGroup,
      @ObjectModel.foreignKey.association: '_REGnrcRentalObjUsageCategory'
      REGnrcRentalObjUsageCategory,
      @ObjectModel.foreignKey.association: '_REGnrcRentalObjUsageType'
      cast( REGenericRentalObjectUsageType as regovdmusableobjusagetype preserving type ) as REGenericRentalObjectUsageType,
      @ObjectModel.foreignKey.association: '_REArchitectureObject'
      REGenericRentalObjParentUUID,
      @ObjectModel.foreignKey.association: '_REGnrcRentalObjPortfolio'
      REGnrcRentalObjPortfolioID,
      @ObjectModel.foreignKey.association: '_REGnrcRentalObjOwnership'
      REGnrcRentalObjOwnershipID,

      @Semantics.systemDateTime.createdAt: true
      CreationDateTime,
      @Semantics.systemDateTime.lastChangedAt: true
      LastChangeDateTime,
      @Semantics.systemDateTime.localInstanceLastChangedAt: true
      LocalLastChangeDateTime,

      /* Associations */
      _REKeyAssgmt,
      _CompanyCode,
      _REAuthorizationGroup,
      _REGnrcRentalObjUsageCategory,
      _REGnrcRentalObjUsageType,
      _REGnrcRentalObjOwnership,
      _REGnrcRentalObjPortfolio,
//      _REParentGenericRentalObject,

      _REGenericRentalObjectType,
      _REArchitectureObject,
      _StatusObject,
      _StatusObjectStatus,
      _REUsblObjToRntblObjAssgmt,
      _RERntblObjToUsblObjAssgmt,
      _REUsableObjectMeasurement,
      _REUsblObjLdngAcctAssgmtObj,
      _REUsblObjAddlAcctAssgmtObj,
      _REUsblObjArchtrUsage,
      _REUsableObjectStatusObject
}
where
     REGenericRentalObjectType = 'U' //Usable Object

Learn More