I_REGENERICRENTALOBJECT

CDS View

Real Estate Generic Rental Object

I_REGENERICRENTALOBJECT is a CDS View in S/4HANA. Real Estate Generic Rental Object. It contains 3 fields. 4 CDS views read from this table.

Used by 4 CDS view(s) 3 fields

CDS Views using this table (4)

ViewTypeJoinVDMDescription
C_REGenericRentalObjectDEX view_entity from CONSUMPTION Extraction RE Generic Rental Object
I_REGenericRentalObjStatusObj view_entity from COMPOSITE RE Generic Rental Object Status Object
I_RERentableObject view_entity from COMPOSITE Real Estate Rentable Object
I_REUsableObject view_entity from COMPOSITE Real Estate Usable Object

Fields (3)

KeyField CDS FieldsUsed in Views
KEY REGenericRentalObjectUUID REGenericRentalObjectUUID 1
KEY REStatusObject REStatusObject 1
REGenericRentalObjectType REGenericRentalObjectType 1 
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: [ '_StatusObject', '_StatusObjectStatus' ]
@EndUserText.label: 'Real Estate Generic Rental Object'

@ObjectModel.semanticKey: ['REGenericRentalObjectNumber']
@ObjectModel.representativeKey: 'REGenericRentalObjectUUID'
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.objectIdentifier.oidElement: 'REGenericRentalObjectOID'
@ODM.oid: 'REGenericRentalObjectOID'

@Metadata.allowExtensions: true
@VDM.viewType: #BASIC

@Analytics.internalName:#LOCAL
@Analytics:{
    dataCategory: #DIMENSION,
    dataExtraction: {
        enabled: true
//        delta.changeDataCapture: {

//        automatic: true

//        }

    }
}

define view entity I_REGenericRentalObject
  as select from vigobd
  association [1..1] to I_REKeyAssgmt                  as _REKeyAssgmt                  on  $projection.InternalRealEstateNumber = _REKeyAssgmt.InternalRealEstateNumber
  association [0..1] to I_CompanyCode                  as _CompanyCode                  on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_REAuthorizationGroup         as _REAuthorizationGroup         on  $projection.REAuthorizationGroup           = _REAuthorizationGroup.REAuthorizationGroup
                                                                                        and _REAuthorizationGroup.RealEstateObjectType = 'J7'
  association [1..1] to I_REGenericRentalObjectType    as _REGenericRentalObjectType    on  $projection.REGenericRentalObjectType = _REGenericRentalObjectType.REGenericRentalObjectType
  association [1..1] to I_REGnrcRentalObjUsageCategory as _REGnrcRentalObjUsageCategory on  $projection.REGnrcRentalObjUsageCategory = _REGnrcRentalObjUsageCategory.REGnrcRentalObjUsageCategory
  association [1..1] to I_REGnrcRentalObjUsageType     as _REGnrcRentalObjUsageType     on  $projection.REGenericRentalObjectUsageType = _REGnrcRentalObjUsageType.REGenericRentalObjectUsageType
//  association [0..1] to I_REGenericRentalObject        as _REParentGenericRentalObject  on  $projection.REGenericRentalObjParentUUID = _REParentGenericRentalObject.REGenericRentalObjectUUID

  association [0..1] to I_REGnrcRentalObjPortfolio     as _REGnrcRentalObjPortfolio     on  $projection.REGnrcRentalObjPortfolioID = _REGnrcRentalObjPortfolio.REGnrcRentalObjPortfolioID
  association [0..1] to I_REGnrcRentalObjOwnership     as _REGnrcRentalObjOwnership     on  $projection.REGnrcRentalObjOwnershipID = _REGnrcRentalObjOwnership.REGnrcRentalObjOwnershipID
  association [0..1] to I_RERentableObjectCategory     as _RERentableObjectCategory     on  $projection.RERentableObjectCategory = _RERentableObjectCategory.RERentableObjectCategory

//Parent Architecture Object

  association [0..1] to I_REArchitectureObject         as _REArchitectureObject         on  $projection.REGenericRentalObjParentUUID = _REArchitectureObject.REArchitectureObjectUUID

  association [0..1] to I_StatusObject                 as _StatusObject                 on  $projection.REStatusObject = _StatusObject.StatusObject
  association [1..*] to I_StatusObjectStatus           as _StatusObjectStatus           on  $projection.REStatusObject = _StatusObjectStatus.StatusObject

{
  key objectuuid                       as REGenericRentalObjectUUID,
      @ObjectModel.foreignKey.association: '_REGenericRentalObjectType'
      objtype                          as REGenericRentalObjectType,
      intreno                          as InternalRealEstateNumber,
      @ObjectModel.foreignKey.association: '_StatusObject'
      objnr                            as REStatusObject,
      oid                              as REGenericRentalObjectOID,
      gonr                             as REGenericRentalObjectNumber,
      alternativeid                    as REGnrcRntlObjectAlternativeID,
      description                      as REGenericRentalObjectName,
      _REKeyAssgmt.REIdentificationKey as REIdentificationKey,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      companycode                      as CompanyCode,
      validfrom                        as ValidityStartDate,
      validto                          as ValidityEndDate,
      @ObjectModel.foreignKey.association: '_REAuthorizationGroup'
      authgrp                          as REAuthorizationGroup,
      @ObjectModel.foreignKey.association: '_REGnrcRentalObjUsageCategory'
      usagecategory                    as REGnrcRentalObjUsageCategory,
      @ObjectModel.foreignKey.association: '_REGnrcRentalObjUsageType'
      usagetype                        as REGenericRentalObjectUsageType,
      @ObjectModel.foreignKey.association: '_REArchitectureObject'
      parentobjectuuid                 as REGenericRentalObjParentUUID,
      @ObjectModel.foreignKey.association: '_REGnrcRentalObjPortfolio'
      portfolioid                      as REGnrcRentalObjPortfolioID,
      @ObjectModel.foreignKey.association: '_REGnrcRentalObjOwnership'
      ownershipid                      as REGnrcRentalObjOwnershipID,
      @ObjectModel.foreignKey.association: '_RERentableObjectCategory'
      rentablecategory                 as RERentableObjectCategory,

      @Semantics.systemDateTime.createdAt: true
      creationdatetime                 as CreationDateTime,
      @Semantics.systemDateTime.lastChangedAt: true
      lastchangedatetime               as LastChangeDateTime,
      @Semantics.systemDateTime.localInstanceLastChangedAt: true
      locallastchangedatetime          as LocalLastChangeDateTime,

      /* Associations */
      _REKeyAssgmt,
      _CompanyCode,
      _REAuthorizationGroup,
      _REGenericRentalObjectType,
      _REGnrcRentalObjUsageCategory,
      _REGnrcRentalObjUsageType,
//      _REParentGenericRentalObject,

      _REGnrcRentalObjPortfolio,
      _REGnrcRentalObjOwnership,
      _RERentableObjectCategory,
      _REArchitectureObject,
      _StatusObject,
      _StatusObjectStatus
}

Learn More