R_REUsableObjectTP

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: ['_REUsableObjectChgDoc']
@EndUserText.label: 'Real Estate Usable Object TP'
@ObjectModel.usageType: {
        serviceQuality: #C,
        dataClass: #TRANSACTIONAL,
        sizeCategory: #XL
    }

@VDM: {
    viewType: #TRANSACTIONAL,
    lifecycle.contract.type: #SAP_INTERNAL_API,
    usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]
    }
@ObjectModel.sapObjectNodeType.name: 'RealEstateUsableObject'
@ObjectModel.objectIdentifier.oidElement: 'RealEstateUsableObjectOID'
@ObjectModel.alternativeKey: [{ element: [ 'RealEstateUsableObjectOID' ], id: 'OID', uniqueness: #UNIQUE_IF_NOT_INITIAL }]
define root view entity R_REUsableObjectTP
  as select from I_REUsableObject as _REUsableObject
  composition [1..*] of R_REUsblObjLdngAcctAssgmtObjTP as _REUsblObjLdngAcctAssgmtObj
  composition [1..*] of R_REUsblObjAddlAcctAssgmtObjTP as _REUsblObjAddlAcctAssgmtObj
  composition [0..*] of R_REUsableObjectMeasurementTP  as _REUsableObjectMeasurement
  composition [0..*] of R_REUsableObjectStatusObjectTP as _REUsableObjectStatusObject
  composition [0..*] of R_REUsblObjToContractAssgmtTP  as _REUsblObjToContractAssgmt
  composition [0..*] of R_REUsblObjArchtrUsageTP       as _REUsblObjArchitectureUsage
  composition [0..*] of R_REUsblObjToRntblObjAssgmtTP  as _REUsblObjToRntblObjAssgmt
  
  //  Change Documents

  association [0..*] to I_ChangeDocument_2             as _REUsableObjectChgDoc on _REUsableObjectChgDoc.ChangeDocObjectClass = 'REGO_REGO'
                                                                                and _REUsableObjectChgDoc.ChangeDocObject = $projection.ChangeDocObject
{
  key RealEstateUsableObjectUUID,
      REGenericRentalObjectType,
      InternalRealEstateNumber,
      REStatusObject,
      RealEstateUsableObjectOID,
      RealEstateUsableObjectNumber,
      @ObjectModel.editableFieldFor: 'RealEstateUsableObjectNumber'
      RealEstateUsableObjectNumber as REUsableObjectNumberForEdit,
      REGnrcRntlObjectAlternativeID,   
      REUsableObjectName,
      REIdentificationKey,
      CompanyCode,
      ValidityStartDate,
      ValidityEndDate,
      REAuthorizationGroup,
      REGnrcRentalObjUsageCategory,
      REGenericRentalObjectUsageType,
      REGnrcRentalObjPortfolioID,
      REGnrcRentalObjOwnershipID,
      REGenericRentalObjParentUUID,
      cast (_REArchitectureObject.REArchitectureObjectNumber as reobvdmobnrbuildingland preserving type ) as REArchtrObjectNumberBldngLand,
      _StatusObject.StatusProfile,
      CreationDateTime,
      LastChangeDateTime,
      LocalLastChangeDateTime,
      
      // convert the UUID into string to use in ON condition in association to change documents

      cast( bintohex( RealEstateUsableObjectUUID ) as cdobjectv ) as ChangeDocObject,

      /* Associations */
      _CompanyCode,
      _REAuthorizationGroup,
      _REGnrcRentalObjUsageCategory,
      _REGnrcRentalObjUsageType,
      _REGnrcRentalObjPortfolio,
      _REGnrcRentalObjOwnership,
      _REArchitectureObject,
      _StatusObject,
      _StatusObjectStatus,
      _REGenericRentalObjectType,

      /* Compositions */
      _REUsblObjLdngAcctAssgmtObj,
      _REUsblObjAddlAcctAssgmtObj,
      _REUsableObjectMeasurement,
      _REUsableObjectStatusObject,
      _REUsblObjToContractAssgmt,
      _REUsblObjArchitectureUsage,
      @Semantics.valueRange.maximum: '1'
      _REUsblObjToRntblObjAssgmt,
      _REUsableObjectChgDoc
}