I_ProductProjectStockValuation

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Product Project Stock Valuation'
@VDM.viewType: #BASIC
@ObjectModel: {
   usageType: {
     dataClass:      #MIXED,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}
@Metadata.ignorePropagatedAnnotations:true

define view entity I_ProductProjectStockValuation
  as select from qbew as ProjectStockValuation
    inner join   t001k on ProjectStockValuation.bwkey = t001k.bwkey
    inner join   t001  on t001.bukrs = t001k.bukrs

  association [0..1] to I_InventoryValuationType   as _InventoryValuationType     on $projection.ValuationType = _InventoryValuationType.InventoryValuationType
  association [0..1] to I_ProdValnPriceControl     as _InventoryValnProcedure     on $projection.InventoryValuationProcedure = _InventoryValnProcedure.InventoryValuationProcedure
  association [0..*] to I_ProdValnPriceControlText as _InventoryValnProcedureText on $projection.InventoryValuationProcedure = _InventoryValnProcedureText.InventoryValuationProcedure
  association [0..1] to I_Prodvaluationclass       as _ValuationClass             on $projection.ValuationClass = _ValuationClass.ValuationClass
  association [0..*] to I_Prodvaluationclasstxt    as _ValuationClassText         on $projection.ValuationClass = _ValuationClassText.ValuationClass
  association [1..1] to I_Product                  as _Product                    on $projection.Product = _Product.Product
  association [1..1] to I_UnitOfMeasure            as _BaseUnitOfMeasure          on $projection.baseunit = _BaseUnitOfMeasure.UnitOfMeasure

{
  key  ProjectStockValuation.matnr                                                           as Product,
  key  ProjectStockValuation.bwkey                                                           as ValuationArea,
       @ObjectModel.foreignKey.association: '_InventoryValuationType'
  key  ProjectStockValuation.bwtar                                                           as ValuationType,
  key  ProjectStockValuation.sobkz                                                           as InventorySpecialStockType,
  key  cast( ProjectStockValuation.pspnr as ps_s4_pspnr preserving type  )                   as WBSElementInternalID,
       @ObjectModel.foreignKey.association: '_InventoryValnProcedure'
       @ObjectModel.text.association:'_InventoryValnProcedureText'
       ProjectStockValuation.vprsv                                                           as InventoryValuationProcedure,

       t001.waers                                                                            as Currency,
       @ObjectModel.foreignKey.association: '_BaseUnitOfMeasure'
       _Product.BaseUnit,

       @Semantics.amount.currencyCode : 'Currency'
       ProjectStockValuation.verpr                                                           as MovingAveragePrice,

       @Semantics.amount.currencyCode : 'Currency'
       ProjectStockValuation.stprs                                                           as StandardPrice,
       @Semantics.quantity.unitOfMeasure: 'BaseUnit'
       ProjectStockValuation.peinh                                                           as ProductPriceUnitQuantity,
       @ObjectModel : {
                foreignKey.association: '_ValuationClass',
                text.association: '_ValuationClassText'
             }
       ProjectStockValuation.bklas                                                           as ValuationClass,
       cast ( ProjectStockValuation.vmvpr as cmd_prd_vmvpr_prev_perd preserving type )       as ProdPrcControlInPreviousPeriod,
       @Semantics.amount.currencyCode : 'Currency'
       cast ( ProjectStockValuation.vmver as cmd_prd_vmver_prev_perd preserving type )       as MvgAvgPriceInPreviousPeriod,
       @Semantics.amount.currencyCode : 'Currency'
       cast(ProjectStockValuation.vmstp as cmd_prd_vmstp_prev_perd preserving type )         as StandardPriceInPreviousPeriod,
       @Semantics.quantity.unitOfMeasure: 'BaseUnit'
       cast( ProjectStockValuation.vmpei as cmd_prd_vmpei_prev_perd preserving type )        as ProdPrcUntQtyInPreviousPeriod,
       cast( ProjectStockValuation.vmbkl as fml_vmbkl preserving type )                      as ValuationClassPreviousPeriod,
       cast( ProjectStockValuation.vjvpr as cmd_prd_vjvpr_prev_year preserving type )        as ProdPriceControlInPreviousYear,
       @Semantics.amount.currencyCode : 'Currency'
       cast ( ProjectStockValuation.vjver as cmd_prd_vjver_prev_year preserving type )       as MvgAveragePriceInPreviousYear,
       @Semantics.amount.currencyCode : 'Currency'
       cast ( ProjectStockValuation.vjstp as cmd_prd_vjstp_prev_year preserving type )       as StandardPricePrevYear,
       @Semantics.quantity.unitOfMeasure: 'BaseUnit'
       cast ( ProjectStockValuation.vjpei as cmd_prd_vjpei_prev_year preserving type )       as ProdPrcUntQtyInPreviousYear,
       cast( ProjectStockValuation.vjbkl as fml_vjbkl preserving type )                      as ValuationClassPreviousYear,
       ProjectStockValuation.lfgja                                                           as FiscalYearCurrentPeriod,
       cast ( ProjectStockValuation.lfmon as cmd_prd_lfmon_cur_perd preserving type )        as FiscalMonthCurrentPeriod,
       ProjectStockValuation.bwtty                                                           as ValuationCategory,
       @Semantics.amount.currencyCode : 'Currency'
       ProjectStockValuation.stprv                                                           as PrevInvtryPriceInCoCodeCrcy,
       ProjectStockValuation.laepr                                                           as PriceLastChangeDate,
       @Semantics.amount.currencyCode : 'Currency'
       ProjectStockValuation.zkprs                                                           as FuturePrice,
       ProjectStockValuation.zkdat                                                           as FuturePriceValidityStartDate,

       ProjectStockValuation.kalkz                                                           as ProdHasStdCostEstForFutrPeriod,

       ProjectStockValuation.kalkl                                                           as ProdHasStdCostEstForCurPeriod,
       ProjectStockValuation.kalkv                                                           as ProdHasStdCostEstForPrevPeriod,
       ProjectStockValuation.kaln1                                                           as ProdCostEstNumber,

       cast ( ProjectStockValuation.bwva1  as cmd_prd_bwva1_futr_cost_est preserving type )  as FutrCostEstValuationVariant,
       cast ( ProjectStockValuation.bwva2 as cmd_prd_bwva2_cur_cost_est preserving type )    as CurCostEstValuationVariant,
       cast ( ProjectStockValuation.bwva3 as cmd_prd_bwva3_prev_cost_est preserving type )   as PrevCostEstValuationVariant,
       cast ( ProjectStockValuation.vers1  as cmd_prd_vers1_futr_cost_est preserving type )  as FutureCostEstCostingVersion,
       cast ( ProjectStockValuation.vers2  as cmd_prd_vers2_cur_cost_est preserving type )   as CurrentCostEstCostingVersion,
       cast ( ProjectStockValuation.vers3   as cmd_prd_vers3_prev_cost_est preserving type ) as PreviousCostEstCostingVersion,
       ProjectStockValuation.hrkft                                                           as CostOriginGroup,
       ProjectStockValuation.kosgr                                                           as CostingOverheadGroup,
       ProjectStockValuation.pprdz                                                           as FutureCostEstimateFiscalPeriod,
       cast ( ProjectStockValuation.pprdl  as cmd_prd_pprdl_std_cost_est preserving type )   as CurrentCostEstFiscalPeriod,
       ProjectStockValuation.pprdv                                                           as PreviousCostEstFiscalPeriod,

       ProjectStockValuation.pdatz                                                           as FutureCostEstFiscalYear,

       ProjectStockValuation.pdatl                                                           as CurrentCostEstFiscalYear,
       ProjectStockValuation.pdatv                                                           as PreviousCostEstFiscalYear,
       ProjectStockValuation.ekalr                                                           as ProductIsCostedWithQtyStruc,
       @Semantics.amount.currencyCode : 'Currency'
       ProjectStockValuation.vplpr                                                           as PreviousPlanPriceInCoCodeCrcy,
       ProjectStockValuation.mlmaa                                                           as MLIsActiveAtProductLevel,
       ProjectStockValuation.mlast                                                           as PriceDeterminationControl,
       @Semantics.amount.currencyCode : 'Currency'
       ProjectStockValuation.lplpr                                                           as CurrentPlanPriceInCoCodeCrcy,
       @Semantics.booleanIndicator
       ProjectStockValuation.hkmat                                                           as ProductHasRelatedOrigin,
       ProjectStockValuation.bwspa                                                           as ValuationMarginPercent,
       @Semantics.amount.currencyCode : 'Currency'
       ProjectStockValuation.lplpx                                                           as FxdPortnOfPlanPrcInCoCodeCrcy,
       @Semantics.amount.currencyCode : 'Currency'
       ProjectStockValuation.vplpx                                                           as FxdPortOfPrevPlPrcInCoCodeCrcy,
       @Semantics.amount.currencyCode : 'Currency'
       ProjectStockValuation.fplpx                                                           as FxdPortnOfFutPlPrcInCoCodeCrcy,
       ProjectStockValuation.lbwst                                                           as CurPlanProjSlsOrdValnStrategy,
       ProjectStockValuation.vbwst                                                           as PrevPlanProjSlsOrdValnStrategy,
       ProjectStockValuation.fbwst                                                           as FutrPlanProjSlsOrdValnStrategy,
       ProjectStockValuation.oklas                                                           as ValnClsForSpclStkAtVndr,


       _InventoryValuationType,
       _InventoryValnProcedure,
       _InventoryValnProcedureText,
       _ValuationClass,
       _ValuationClassText,
       _Product,
       _BaseUnitOfMeasure
}