I_MaterialValuation

@EndUserText.label: 'Material Valuation'
@AccessControl.authorizationCheck: #MANDATORY 
@AccessControl.personalData.blocking: #REQUIRED  
@ObjectModel.representativeKey: 'CostEstimate'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@VDM.viewType: #COMPOSITE
@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions:true
define view entity I_MaterialValuation as 

select from P_ProductValuationBasic // mbew

{
   key ProdCostEstNumber as CostEstimate,
   
   ValuationClass as MaterialValuationClass,
   ValuationCategory as InventoryValuationCategory,
   Product as Material,
   ValuationType as InventoryValuationType,
   ValuationArea,
   cast('00000000' as ps_psp_pnr) as WBSElement,
   cast('' as sobkz) as InventorySpecialStockType,
   cast('' as vbeln) as SDDocument,
   cast('000000' as posnr) as SDDocumentItem,
   cast('' as lifnr) as Supplier,
   PriceDeterminationControl
}

union all 

select from I_ProdSalesOrderStockValuation // ebew 

{
   key ProdCostEstNumber as CostEstimate,
   
   ValuationClass as MaterialValuationClass,
   ValuationCategory as InventoryValuationCategory,
   Product as Material,
   ValuationType as InventoryValuationType,
   ValuationArea,
   cast('00000000' as ps_psp_pnr) as WBSElement,
   InventorySpecialStockType,
   SDDocument,
   SDDocumentItem,
   cast('' as lifnr) as Supplier,
   PriceDeterminationControl
}

union all

select from I_ProdVltdStockSubcontractor //obew 

{
   key ProdCostEstNumber as CostEstimate,

   ValuationClass as MaterialValuationClass,
   ValuationCategory as  InventoryValuationCategory,
   Product as Material,
   ValuationType as InventoryValuationType,
   ValuationArea,
   cast('00000000' as ps_psp_pnr) as WBSElement,
   InventorySpecialStockType,
   cast('' as vbeln) as SDDocument,
   cast('000000' as posnr) as SDDocumentItem,
   Supplier,
   PriceDeterminationControl
}

union all

select from I_ProductProjectStockValuation //qbew 

{
   key ProdCostEstNumber as CostEstimate,

   ValuationClass as MaterialValuationClass,
   ValuationCategory as  InventoryValuationCategory,
   Product as Material,
   ValuationType as InventoryValuationType,
   ValuationArea,
   WBSElementInternalID as WBSElement,
   InventorySpecialStockType,
   cast('' as vbeln) as SDDocument,
   cast('000000' as posnr) as SDDocumentItem,
   cast('' as lifnr) as Supplier,
   PriceDeterminationControl
}