I_Prodvaluationclass

DDL: I_PRODVALUATIONCLASS Type: view BASIC Package: VDM_MD_PRODUCT_DDIC

Valuation Class

I_Prodvaluationclass is a Basic CDS View (Dimension) that provides data about "Valuation Class" in SAP S/4HANA. It reads from 1 data source (t025) and exposes 3 fields with key field ValuationClass. It has 1 association to related views. Part of development package VDM_MD_PRODUCT_DDIC.

1 data source(s) 3 fields

Data Sources (1)

SourceAliasJoin Type
t025 t025 from

Associations (1)

CardinalityTargetAliasCondition
[0..*] I_Prodvaluationclasstxt _ValuationClassText $projection.ValuationClass = _ValuationClassText.ValuationClass

Annotations (18)

NameValueLevelField
AbapCatalog.sqlViewName IVALCLASS view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
VDM.viewType #BASIC view
AccessControl.authorizationCheck #NOT_REQUIRED view
EndUserText.label Valuation Class view
Search.searchable true view
ObjectModel.usageType.dataClass #CUSTOMIZING view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.dataCategory #VALUE_HELP view
ObjectModel.representativeKey ValuationClass view
ClientHandling.algorithm #SESSION_VARIABLE view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.sapObjectNodeType.name ProductValuationClass view
ObjectModel.objectIdentifier.oidElement ProductValuationClassOID view
Analytics.dataCategory #DIMENSION view
Analytics.internalName #LOCAL view

Fields (3)

KeyFieldSource TableSource FieldDescription
KEY ValuationClass t025 bklas
AcctCategoryRef t025 kkref
_ValuationClassText _ValuationClassText 
@AbapCatalog: {
  sqlViewName: 'IVALCLASS',
  compiler.compareFilter: true,
  preserveKey:true
 }
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Valuation Class'
@Search.searchable: true
@ObjectModel: {
  usageType: {
    dataClass: #CUSTOMIZING,
    serviceQuality: #A,
    sizeCategory: #S
  },
  dataCategory: #VALUE_HELP,
  representativeKey: 'ValuationClass',
  supportedCapabilities: [ #SQL_DATA_SOURCE,
                           #CDS_MODELING_DATA_SOURCE,
                           #CDS_MODELING_ASSOCIATION_TARGET,
                           #SEARCHABLE_ENTITY,
                           #ANALYTICAL_DIMENSION
                         ]
}

@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.sapObjectNodeType.name:'ProductValuationClass'
@ObjectModel.alternativeKey:[{id:'OID',element:['ProductValuationClassOID']}]
@ObjectModel.objectIdentifier.oidElement:'ProductValuationClassOID'
@Analytics.dataCategory: #DIMENSION
@Analytics.internalName: #LOCAL

define view I_Prodvaluationclass
  as select from           t025
    left outer to one join I_MdiOidConfiguration on I_MdiOidConfiguration.ObjectTypeCode = '5618'
  association [0..*] to I_Prodvaluationclasstxt as _ValuationClassText on $projection.ValuationClass = _ValuationClassText.ValuationClass

{
       @ObjectModel.text.association: '_ValuationClassText'
       @Search: {
          defaultSearchElement: true,
          fuzzinessThreshold: 0.8,
          ranking: #HIGH
         }  
  key  t025.bklas as ValuationClass,
       t025.kkref as AcctCategoryRef,
       @ObjectModel.filter.enabled:false
       @ObjectModel.sort.enabled:false
       //Context ID is not specified

       case when I_MdiOidConfiguration.Context is initial
       //            special handling for code with initial value; shall be skipped if such a code value does not exist

       //            or

       //Composition is disabled

              or I_MdiOidConfiguration.ComposeOid is initial then
             cast( t025.bklas as valuationclass_oid )
       //Context ID is specified

            when I_MdiOidConfiguration.Context is not initial
             and I_MdiOidConfiguration.ComposeOid is not initial then
             cast( concat( concat( I_MdiOidConfiguration.Context, ':' ), t025.bklas ) as valuationclass_oid )
        end       as ProductValuationClassOID,

       _ValuationClassText
}

Learn More