I_ProdVltdStockSubcontractor

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Prod Valuated Stock with Subcontractor'
@VDM.viewType: #BASIC
@ObjectModel: {
   usageType: {
     dataClass:      #MIXED,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}
@Metadata.ignorePropagatedAnnotations:true

define view entity I_ProdVltdStockSubcontractor
  as select from obew as ValuatedStockSubcontractor
    inner join   t001k on ValuatedStockSubcontractor.bwkey = t001k.bwkey
    inner join   t001  on t001.bukrs = t001k.bukrs

  association [0..1] to I_InventoryValuationType   as _InventoryValuationType     on $projection.ValuationType = _InventoryValuationType.InventoryValuationType
  association [0..1] to I_ProdValnPriceControl     as _InventoryValnProcedure     on $projection.InventoryValuationProcedure = _InventoryValnProcedure.InventoryValuationProcedure
  association [0..*] to I_ProdValnPriceControlText as _InventoryValnProcedureText on $projection.InventoryValuationProcedure = _InventoryValnProcedureText.InventoryValuationProcedure
  association [0..1] to I_Prodvaluationclass       as _ValuationClass             on $projection.ValuationClass = _ValuationClass.ValuationClass
  association [0..*] to I_Prodvaluationclasstxt    as _ValuationClassText         on $projection.ValuationClass = _ValuationClassText.ValuationClass
  association [1..1] to I_Product                  as _Product                    on $projection.Product = _Product.Product
  association [1..1] to I_UnitOfMeasure            as _BaseUnitOfMeasure          on $projection.baseunit = _BaseUnitOfMeasure.UnitOfMeasure


{
  key  ValuatedStockSubcontractor.matnr                                                           as Product,
  key  ValuatedStockSubcontractor.bwkey                                                           as ValuationArea,
       @ObjectModel.foreignKey.association: '_InventoryValuationType'
  key  ValuatedStockSubcontractor.bwtar                                                           as ValuationType,
  key  ValuatedStockSubcontractor.sobkz                                                           as InventorySpecialStockType,
  key  ValuatedStockSubcontractor.lifnr                                                           as Supplier,


       @ObjectModel.foreignKey.association: '_InventoryValnProcedure'
       @ObjectModel.text.association:'_InventoryValnProcedureText'
       ValuatedStockSubcontractor.vprsv                                                           as InventoryValuationProcedure,

       t001.waers                                                                                 as Currency,

       @ObjectModel.foreignKey.association: '_BaseUnitOfMeasure'
       _Product.BaseUnit,

       @Semantics.amount.currencyCode : 'Currency'
       ValuatedStockSubcontractor.verpr                                                           as MovingAveragePrice,

       @Semantics.amount.currencyCode : 'Currency'
       ValuatedStockSubcontractor.stprs                                                           as StandardPrice,
       @Semantics.quantity.unitOfMeasure: 'BaseUnit'
       ValuatedStockSubcontractor.peinh                                                           as ProductPriceUnitQuantity,
       @ObjectModel : {
                foreignKey.association: '_ValuationClass',
                text.association: '_ValuationClassText'
             }
       ValuatedStockSubcontractor.bklas                                                           as ValuationClass,
       cast ( ValuatedStockSubcontractor.vmvpr as cmd_prd_vmvpr_prev_perd preserving type )       as ProdPrcControlInPreviousPeriod,
       @Semantics.amount.currencyCode : 'Currency'
       cast ( ValuatedStockSubcontractor.vmver as cmd_prd_vmver_prev_perd preserving type )       as MvgAvgPriceInPreviousPeriod,
       @Semantics.amount.currencyCode : 'Currency'
       cast(ValuatedStockSubcontractor.vmstp as cmd_prd_vmstp_prev_perd preserving type )         as StandardPriceInPreviousPeriod,
       @Semantics.quantity.unitOfMeasure: 'BaseUnit'
       cast( ValuatedStockSubcontractor.vmpei as cmd_prd_vmpei_prev_perd preserving type )        as ProdPrcUntQtyInPreviousPeriod,
       cast( ValuatedStockSubcontractor.vmbkl as fml_vmbkl preserving type )                      as ValuationClassPreviousPeriod,
       cast( ValuatedStockSubcontractor.vjvpr as cmd_prd_vjvpr_prev_year preserving type )        as ProdPriceControlInPreviousYear,
       @Semantics.amount.currencyCode : 'Currency'
       cast ( ValuatedStockSubcontractor.vjver as cmd_prd_vjver_prev_year preserving type )       as MvgAveragePriceInPreviousYear,
       @Semantics.amount.currencyCode : 'Currency'
       cast ( ValuatedStockSubcontractor.vjstp as cmd_prd_vjstp_prev_year preserving type )       as StandardPricePrevYear,
       @Semantics.quantity.unitOfMeasure: 'BaseUnit'
       cast ( ValuatedStockSubcontractor.vjpei as cmd_prd_vjpei_prev_year preserving type )       as ProdPrcUntQtyInPreviousYear,
       cast( ValuatedStockSubcontractor.vjbkl as fml_vjbkl preserving type )                      as ValuationClassPreviousYear,
       ValuatedStockSubcontractor.lfgja                                                           as FiscalYearCurrentPeriod,
       cast ( ValuatedStockSubcontractor.lfmon as cmd_prd_lfmon_cur_perd preserving type )        as FiscalMonthCurrentPeriod,
       ValuatedStockSubcontractor.bwtty                                                           as ValuationCategory,
       @Semantics.amount.currencyCode : 'Currency'
       ValuatedStockSubcontractor.stprv                                                           as PrevInvtryPriceInCoCodeCrcy,
       ValuatedStockSubcontractor.laepr                                                           as PriceLastChangeDate,
       @Semantics.amount.currencyCode : 'Currency'
       ValuatedStockSubcontractor.zkprs                                                           as FuturePrice,
       ValuatedStockSubcontractor.zkdat                                                           as FuturePriceValidityStartDate,

       ValuatedStockSubcontractor.kalkz                                                           as ProdHasStdCostEstForFutrPeriod,

       ValuatedStockSubcontractor.kalkl                                                           as ProdHasStdCostEstForCurPeriod,
       ValuatedStockSubcontractor.kalkv                                                           as ProdHasStdCostEstForPrevPeriod,
       ValuatedStockSubcontractor.kaln1                                                           as ProdCostEstNumber,

       cast ( ValuatedStockSubcontractor.bwva1  as cmd_prd_bwva1_futr_cost_est preserving type )  as FutrCostEstValuationVariant,
       cast ( ValuatedStockSubcontractor.bwva2 as cmd_prd_bwva2_cur_cost_est preserving type )    as CurCostEstValuationVariant,
       cast ( ValuatedStockSubcontractor.bwva3 as cmd_prd_bwva3_prev_cost_est preserving type )   as PrevCostEstValuationVariant,
       cast ( ValuatedStockSubcontractor.vers1  as cmd_prd_vers1_futr_cost_est preserving type )  as FutureCostEstCostingVersion,
       cast ( ValuatedStockSubcontractor.vers2  as cmd_prd_vers2_cur_cost_est preserving type )   as CurrentCostEstCostingVersion,
       cast ( ValuatedStockSubcontractor.vers3   as cmd_prd_vers3_prev_cost_est preserving type ) as PreviousCostEstCostingVersion,
       ValuatedStockSubcontractor.hrkft                                                           as CostOriginGroup,
       ValuatedStockSubcontractor.kosgr                                                           as CostingOverheadGroup,
       ValuatedStockSubcontractor.pprdz                                                           as FutureCostEstimateFiscalPeriod,
       cast ( ValuatedStockSubcontractor.pprdl  as cmd_prd_pprdl_std_cost_est preserving type )   as CurrentCostEstFiscalPeriod,
       ValuatedStockSubcontractor.pprdv                                                           as PreviousCostEstFiscalPeriod,

       ValuatedStockSubcontractor.pdatz                                                           as FutureCostEstFiscalYear,

       ValuatedStockSubcontractor.pdatl                                                           as CurrentCostEstFiscalYear,
       ValuatedStockSubcontractor.pdatv                                                           as PreviousCostEstFiscalYear,
       ValuatedStockSubcontractor.ekalr                                                           as ProductIsCostedWithQtyStruc,
       @Semantics.amount.currencyCode : 'Currency'
       ValuatedStockSubcontractor.vplpr                                                           as PreviousPlanPriceInCoCodeCrcy,
       ValuatedStockSubcontractor.mlmaa                                                           as MLIsActiveAtProductLevel,
       ValuatedStockSubcontractor.mlast                                                           as PriceDeterminationControl,
       @Semantics.amount.currencyCode : 'Currency'
       ValuatedStockSubcontractor.lplpr                                                           as CurrentPlanPriceInCoCodeCrcy,
       @Semantics.booleanIndicator
       ValuatedStockSubcontractor.hkmat                                                           as ProductHasRelatedOrigin,
       ValuatedStockSubcontractor.bwspa                                                           as ValuationMarginPercent,
       @Semantics.amount.currencyCode : 'Currency'
       ValuatedStockSubcontractor.lplpx                                                           as FxdPortnOfPlanPrcInCoCodeCrcy,
       @Semantics.amount.currencyCode : 'Currency'
       ValuatedStockSubcontractor.vplpx                                                           as FxdPortOfPrevPlPrcInCoCodeCrcy,
       @Semantics.amount.currencyCode : 'Currency'
       ValuatedStockSubcontractor.fplpx                                                           as FxdPortnOfFutPlPrcInCoCodeCrcy,
       ValuatedStockSubcontractor.lbwst                                                           as CurPlanProjSlsOrdValnStrategy,
       ValuatedStockSubcontractor.vbwst                                                           as PrevPlanProjSlsOrdValnStrategy,
       ValuatedStockSubcontractor.fbwst                                                           as FutrPlanProjSlsOrdValnStrategy,
       ValuatedStockSubcontractor.oklas                                                           as ValnClsForSpclStkAtVndr,


       _InventoryValuationType,
       _InventoryValnProcedure,
       _InventoryValnProcedureText,
       _ValuationClass,
       _ValuationClassText,
       _Product,
       _BaseUnitOfMeasure
}