I_OrderSequenceBasic

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: ['_LongText']
@EndUserText.label: 'Order Sequence'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.viewType: #BASIC
define view entity I_OrderSequenceBasic
  as select from affl as affl

  association [1..1] to I_LogisticsOrder              as _LogisticsOrder              on  $projection.OrderInternalID = _LogisticsOrder.OrderInternalBillOfOperations
  association [1..1] to I_SequenceCategory            as _SequenceCategory            on  $projection.SequenceCategory = _SequenceCategory.SequenceCategory
  association [0..1] to I_SequenceSchedulingAlignment as _SequenceSchedulingAlignment on  $projection.SequenceSchedulingAlignment = _SequenceSchedulingAlignment.SequenceSchedulingAlignment
  association [0..1] to I_OrderSequenceBasic          as _ReferenceSequence           on  $projection.OrderInternalID   = _ReferenceSequence.OrderInternalID
                                                                                      and $projection.ReferenceSequence = _ReferenceSequence.Sequence
  association [1..1] to I_OrderInternalID             as _OrderInternalID             on  $projection.OrderInternalID = _OrderInternalID.OrderInternalID
  association [0..1] to I_BillOfOperationsType        as _BillOfOperationsType        on  $projection.BillOfOperationsType = _BillOfOperationsType.BillOfOperationsType
  association [0..1] to I_BillOfOperationsGroup       as _BillOfOperationsGroup       on  $projection.BillOfOperationsType  = _BillOfOperationsGroup.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup = _BillOfOperationsGroup.BillOfOperationsGroup
  association [0..1] to I_BillOfOperations            as _BillOfOperationsVariant     on  $projection.BillOfOperationsType    = _BillOfOperationsVariant.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup   = _BillOfOperationsVariant.BillOfOperationsGroup
                                                                                      and $projection.BillOfOperationsVariant = _BillOfOperationsVariant.BillOfOperationsVariant
  association [0..1] to I_Language                    as _Language                    on  $projection.Language = _Language.Language
  association [0..1] to I_OrderSequenceLongText       as _LongText                    on  $projection.OrderInternalID    = _LongText.OrderInternalID
                                                                                      and $projection.SequenceInternalID = _LongText.SequenceInternalID
{
      // Technical Key

      @ObjectModel.foreignKey.association: '_OrderInternalID'
  key cast(affl.aufpl as pph_aufpl preserving type)               as OrderInternalID,
      -- representative key
  key cast(affl.aplzl as pph_flgzl preserving type)               as SequenceInternalID,

      // Semantical key

      @ObjectModel.text.element: ['SequenceText']
      affl.plnfl                                                  as Sequence,

      // Text

      @Semantics.text: true
      affl.ltxa1                                                  as SequenceText,
      @ObjectModel.foreignKey.association: '_Language'
      affl.txtsp                                                  as Language,

      // Assignments

      @ObjectModel.foreignKey.association: '_SequenceCategory'
      affl.flgat                                                  as SequenceCategory,
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
      cast(affl.plnty as billofoperationstype    preserving type) as BillOfOperationsType,
      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
      cast(affl.plnnr as billofoperationsgroup   preserving type) as BillOfOperationsGroup,
      @ObjectModel.foreignKey.association: '_BillOfOperationsVariant'
      cast(affl.plnal as billofoperationsvariant preserving type) as BillOfOperationsVariant,
      @ObjectModel.foreignKey.association: '_SequenceSchedulingAlignment'
      affl.auschl                                                 as SequenceSchedulingAlignment,
      affl.bezfl                                                  as ReferenceSequence,
      affl.objnr                                                  as ObjectInternalID,
      affl.bknt1                                                  as BranchOperationInternalID,
      affl.bknt2                                                  as ReturnOperationInternalID,

      // Associations

      _LogisticsOrder,
      _SequenceCategory,
      _SequenceSchedulingAlignment,
      _ReferenceSequence,
      _OrderInternalID,
      _BillOfOperationsType,
      _BillOfOperationsGroup,
      _BillOfOperationsVariant,
      _LongText,
      _Language
};