I_OpenMaintOrderForTechObject

@AbapCatalog.sqlViewName: 'IOPENMAINTORDER'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Open Maintainance Orders for Technical Object'

@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA') 

define view I_OpenMaintOrderForTechObject 
   as select from I_MaintenanceOrder as _Order
{

         key   _Order.MaintenanceOrder,
   
   key  case when Equipment = '' then
                  cast( _LocationAccountAssignment.FunctionalLocation as eams_tec_obj )
              when Equipment <> ''   
              then 
           cast( Equipment as eams_tec_obj ) end             as TechnicalObject,

  
  key    cast( case when Equipment = '' and _LocationAccountAssignment.FunctionalLocation = '' then ''
              when Equipment = '' then 'EAMS_FL'
            when Equipment <> '' then 'EAMS_EQUI' end as eams_tec_obj_type_value ) as TechObjIsEquipOrFuncnlLoc,
   
    
      _Order.MaintenanceProcessingPhase,
      
       // Maintanence Order Type Description

      _Order.MaintenanceOrderDesc,

      // Maintanence Order Type Text

       _Order.MaintenanceOrderType,

      // Maintanence Order Type Text

      _Order._MaintenanceOrderType._Text[1:Language = $session.system_language].OrderTypeName as MaintenanceOrderTypeName,

      // Maintanence Planning Plant

      _Order.MaintenancePlanningPlant,

      // Maintanence Planner Group

      _Order.MaintenancePlannerGroup,

      // Maintanence LACD

      _Order.LatestAcceptableCompletionDate,

      // Maintanence Order Required Start Date

      _Order.MaintOrdBasicStartDate,

     // Maintanence Order Required End Date 

      _Order.MaintOrdBasicEndDate,

      // MaintenanceOrderInternalID

      _Order.MaintenanceOrderInternalID,

      _Order.Equipment,

      _Order.MaintObjectLocAcctAssgmtNmbr,

      _Order._Equipment,

      _Order._LocationAccountAssignment

}
where _Order.MaintenanceOrder != ''
and  ( _Order.MaintenanceProcessingPhase = '0'
  or  _Order.MaintenanceProcessingPhase = '1'
  or  _Order.MaintenanceProcessingPhase = '2')
  
  
union 

select from I_MaintenanceItemObject as _ObjectList
  inner join      I_MaintenanceOrder as _MaintOrder    on _MaintOrder.MaintenanceItemObjectList = _ObjectList.MaintenanceItemObjectList
             
{

         key   _MaintOrder.MaintenanceOrder,
   
         key  cast( case when _ObjectList.Equipment <> '' then _ObjectList.Equipment
           when _ObjectList.FunctionalLocation <> '' then _ObjectList.FunctionalLocation 
                        end  as eams_tec_obj )  as TechnicalObject,
 
         key  cast( case when _ObjectList.Equipment <> '' then 'EAMS_EQUI'
           when _ObjectList.FunctionalLocation <> '' then 'EAMS_FL' 
                end  as eams_tec_obj_type_value ) as TechObjIsEquipOrFuncnlLoc,
    
      _MaintOrder.MaintenanceProcessingPhase,
      
       // Maintanence Order Type Description

      _MaintOrder.MaintenanceOrderDesc,

      // Maintanence Order Type Text

       _MaintOrder.MaintenanceOrderType,

      // Maintanence Order Type Text

      _MaintOrder._MaintenanceOrderType._Text[1:Language = $session.system_language].OrderTypeName as MaintenanceOrderTypeName,

      // Maintanence Planning Plant

      _MaintOrder.MaintenancePlanningPlant,

      // Maintanence Planner Group

      _MaintOrder.MaintenancePlannerGroup,

      // Maintanence LACD

      _MaintOrder.LatestAcceptableCompletionDate,

      // Maintanence Order Required Start Date

      _MaintOrder.MaintOrdBasicStartDate,

     // Maintanence Order Required End Date 

      _MaintOrder.MaintOrdBasicEndDate,

      // MaintenanceOrderInternalID

      _MaintOrder.MaintenanceOrderInternalID,

      _MaintOrder.Equipment,

      _MaintOrder.MaintObjectLocAcctAssgmtNmbr,

      _MaintOrder._Equipment,

      _MaintOrder._LocationAccountAssignment

}
where _MaintOrder.MaintenanceOrder != ''
and  ( _MaintOrder.MaintenanceProcessingPhase = '0'
  or  _MaintOrder.MaintenanceProcessingPhase = '1'
  or  _MaintOrder.MaintenanceProcessingPhase = '2')