I_MfgOrderOperationBasic

@AbapCatalog.sqlViewName: 'IPPMFGORDOPBASIC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Analytics.dataCategory: #DIMENSION
@ClientHandling.algorithm: #SESSION_VARIABLE
@ClientHandling.type: #CLIENT_DEPENDENT
@Metadata.allowExtensions: true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.representativeKey: 'OrderIntBillOfOperationsItem'
@ObjectModel.semanticKey: ['ManufacturingOrder', 'ManufacturingOrderSequence', 'ManufacturingOrderOperation']
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.viewType: #BASIC
@EndUserText.label: 'Manufacturing Order Operation Basic'
// Basic view on Manufacturing Order Operations based on operation table AFVC only!

// For full operation data (incl. AFVV, AFVU) refer to #COMPOSITE view I_ManufacturingOrderOperation


/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view I_MfgOrderOperationBasic
  as select from I_OrderOperationBasic as afvc
    inner join   I_MfgOrderBasic       as aufv on afvc.OrderInternalID = aufv.OrderInternalID

  association [1..1] to I_OrdInternalBillOfOperations as _OrdInternalBillOfOperations on  $projection.OrderInternalBillOfOperations = _OrdInternalBillOfOperations.OrderInternalBillOfOperations
  association [1..1] to I_OrderInternalID             as _OrderInternalID             on  $projection.OrderInternalBillOfOperations = _OrderInternalID.OrderInternalID
  association [1..1] to I_ManufacturingOrder          as _ManufacturingOrder          on  $projection.ManufacturingOrder = _ManufacturingOrder.ManufacturingOrder
  association [1..1] to I_MfgOrder                    as _MfgOrder                    on  $projection.ManufacturingOrder = _MfgOrder.ManufacturingOrder
  association [1..1] to I_MfgOrderSequence            as _MfgOrderSequence            on  $projection.ManufacturingOrder         = _MfgOrderSequence.ManufacturingOrder
                                                                                      and $projection.ManufacturingOrderSequence = _MfgOrderSequence.ManufacturingOrderSequence
  association [1..1] to I_MfgOrderCategory            as _MfgOrderCategory            on  $projection.ManufacturingOrderCategory = _MfgOrderCategory.ManufacturingOrderCategory
  association [1..1] to I_MfgOrderType                as _MfgOrderType                on  $projection.ManufacturingOrderType = _MfgOrderType.ManufacturingOrderType
  association [0..1] to I_Language                    as _Language                    on  $projection.Language = _Language.Language
  association [1..1] to I_Plant                       as _ProductionPlant             on  $projection.ProductionPlant = _ProductionPlant.Plant
  association [0..1] to I_WorkCenter                  as _WorkCenter                  on  $projection.WorkCenterTypeCode_2 = _WorkCenter.WorkCenterTypeCode
                                                                                      and $projection.WorkCenterInternalID = _WorkCenter.WorkCenterInternalID
  association [0..1] to I_WorkCenterType              as _WorkCenterType              on  $projection.WorkCenterTypeCode_2 = _WorkCenterType.WorkCenterTypeCode
  association [0..1] to I_FactoryCalendar             as _FactoryCalendar             on  $projection.FactoryCalendar = _FactoryCalendar.FactoryCalendar
  association [1..1] to I_OperationControlProfile     as _OperationControlProfile     on  $projection.OperationControlProfile = _OperationControlProfile.OperationControlProfile
  association [0..1] to I_CapacityRequirement         as _CapacityRequirement         on  $projection.CapacityRequirement = _CapacityRequirement.CapacityRequirement
  association [0..1] to I_CapacityRequirementItem     as _CapacityRequirementItem     on  $projection.CapacityRequirement     = _CapacityRequirementItem.CapacityRequirement
                                                                                      and $projection.CapacityRequirementItem = _CapacityRequirementItem.CapacityRequirementItem
  association [0..1] to I_ChangeMaster                as _ChangeNumber                on  $projection.ChangeNumber = _ChangeNumber.ChangeNumber
  association [1..1] to I_ConfirmationGroup           as _ConfirmationGroup           on  $projection.OperationConfirmation = _ConfirmationGroup.ConfirmationGroup

{
      // Technical Key

      @ObjectModel.foreignKey.association: '_OrdInternalBillOfOperations'
  key cast(afvc.OrderInternalID          as pph_aufpl           preserving type) as OrderInternalBillOfOperations,
      -- representatice key
  key cast(afvc.OrderOperationInternalID as operationinternalid preserving type) as OrderIntBillOfOperationsItem,

      // Semantic key

      @ObjectModel.foreignKey.association: '_MfgOrder'
      aufv.ManufacturingOrder                           as ManufacturingOrder,
      @ObjectModel.foreignKey.association: '_MfgOrderSequence'
      afvc.Sequence                                     as ManufacturingOrderSequence,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'ManufacturingOrderOperation_2'
      @ObjectModel.text.element: ['MfgOrderOperationText']
      cast(afvc.Operation as co_vornr  preserving type) as ManufacturingOrderOperation,
      @ObjectModel.text.element: ['MfgOrderOperationText']
      afvc.Operation_2                                  as ManufacturingOrderOperation_2,

      // Order header data

      @ObjectModel.foreignKey.association: '_MfgOrderCategory'
      aufv.ManufacturingOrderCategory,
      @ObjectModel.foreignKey.association: '_MfgOrderType'
      aufv.ManufacturingOrderType,

      // Text

      @Semantics.text: true
      afvc.OperationText               as MfgOrderOperationText,
      @ObjectModel.foreignKey.association: '_Language'
      afvc.Language,
      afvc.OperationHasLongText,

      // Assignments

      @ObjectModel.foreignKey.association: '_ProductionPlant'
      afvc.Plant                       as ProductionPlant,
      @ObjectModel.foreignKey.association: '_WorkCenter'
      cast(afvc.WorkCenterInternalID as pph_arbid preserving type)    as WorkCenterInternalID,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'WorkCenterTypeCode_2'
      afvc.WorkCenterTypeCode,
      @ObjectModel.foreignKey.association: '_WorkCenterType'   
      cast(afvc.WorkCenterTypeCode_2 as vdm_arbty preserving type)    as WorkCenterTypeCode_2,
      @ObjectModel.foreignKey.association: '_OperationControlProfile'
      afvc.OperationControlProfile,
      @ObjectModel.foreignKey.association: '_FactoryCalendar'
      afvc.FactoryCalendar,   
      @ObjectModel.foreignKey.association: '_CapacityRequirement'
      afvc.CapacityRequirement,
      @ObjectModel.foreignKey.association: '_CapacityRequirementItem'
      cast(afvc.CapacityRequirementItem as pph_bedzl preserving type) as CapacityRequirementItem,
      @ObjectModel.foreignKey.association: '_ChangeNumber'
      afvc.ChangeNumber,
      @ObjectModel.foreignKey.association: '_ConfirmationGroup'      
      afvc.OperationConfirmation,
      afvc.SuperiorOperationInternalID, 
      afvc.ObjectInternalID,
      afvc.MfgOrderOperationIsPhase,
      afvc.OrderIntBillOfOpItemOfPhase as SuperiorOperationIntIDOfPhase,
      case
        when afvc.SuperiorOperationInternalID > '00000000' then 'X'
        when afvc.SuperiorOperationInternalID = '00000000' then ''
      end as OperationIsSubOperation,  
      afvc.OperationImportance,
      afvc.OperationScrapPercent,
      afvc.NumberOfOperationConfirmations,
      afvc.ActualNumberOfSplits,
      afvc.NumberOfCapacities,

      // Routing data

      afvc.BillOfOperationsSequence,
      afvc.BillOfOperationsType,
      afvc.BillOfOperationsGroup,
      afvc.BillOfOperationsVariant,
      afvc.BOOOperationInternalID,
      afvc.BillOfOperationsVersion,

      // OAN specific fields

      afvc.SetupOpActyNtwkInstance,
      afvc.ProduceOpActyNtwkInstance,
      afvc.TeardownOpActyNtwkInstance,

      // Associations

      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_OrderInternalID'
      _OrdInternalBillOfOperations,
      _OrderInternalID,
      _ManufacturingOrder,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_ManufacturingOrder'
      _MfgOrder,
      _MfgOrderSequence,
      _MfgOrderCategory,
      _MfgOrderType,
      _Language,
      _ProductionPlant,
      _WorkCenter,
      _WorkCenterType,
      _OperationControlProfile,
      _FactoryCalendar,
      _CapacityRequirement,
      _CapacityRequirementItem,
      _ChangeNumber,
      _ConfirmationGroup
}
where aufv.ManufacturingOrderCategory = '10'
   or aufv.ManufacturingOrderCategory = '40'; //Manufacturing orders only