I_ProdnOrderOperationLongText

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Analytics.technicalName: 'IPRODNORDOPLTXT'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #TEXT
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.representativeKey: 'OrderOperationInternalID'
@ObjectModel.supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT, #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Production Order Operation - Text'

define view entity I_ProdnOrderOperationLongText
    as select from I_OrderOperationLongText as text
        inner join I_MfgOrderOperationBasic as oper on  oper.OrderInternalBillOfOperations = text.OrderInternalID
                                                    and oper.OrderIntBillOfOperationsItem  = text.OrderOperationInternalID

    association [1..1] to I_Language                   as _LongTextLanguage         on  $projection.LongTextLanguage = _LongTextLanguage.Language
--  SOT relations
    association [1..1] to I_ProductionOrder            as _ProductionOrderHeader    on  $projection.ProductionOrder = _ProductionOrderHeader.ProductionOrder
    association to parent I_ProductionOrderOperation_2 as _ProductionOrderOperation on  $projection.OrderInternalID          = _ProductionOrderOperation.OrderInternalID
                                                                                    and $projection.OrderOperationInternalID = _ProductionOrderOperation.OrderOperationInternalID
{
      // Key

      @ObjectModel.foreignKey.association: '_OrderInternalID'
  key oper.OrderInternalBillOfOperations                      as OrderInternalID,
      @ObjectModel.text.element: ['OrderOperationText', 'OrderOperationLongText']
  key oper.OrderIntBillOfOperationsItem                       as OrderOperationInternalID,
      @ObjectModel.foreignKey.association: '_LongTextLanguage'
      @Semantics.language: true
  key cast(oper.Language as pph_longtextlang preserving type) as LongTextLanguage,

      // Semantic key

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProductionOrderStdVH', element: 'ProductionOrder' } } ]
      cast(oper.ManufacturingOrder         as vdm_manufacturingorder preserving type)     as ProductionOrder,
--    @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProductionOrderSequenceVH', element: 'ProductionOrderSequence' } } ]
      cast(oper.ManufacturingOrderSequence as vdm_prodnordersequence preserving type)     as ProductionOrderSequence,
      @ObjectModel.text.element: ['OrderOperationText', 'OrderOperationLongText']
      cast(oper.ManufacturingOrderOperation_2 as vdm_prodnorderoperation preserving type) as ProductionOrderOperation,

      // Text

      @Semantics.text: true
      oper.MfgOrderOperationText as OrderOperationText,
      @Semantics.text: true
      text.OrderOperationLongText,

      // Associations

      _ProductionOrderOperation,
      _ProductionOrderHeader,
      _LongTextLanguage,
      oper._OrderInternalID
}
where 
  oper.ManufacturingOrderCategory = '10' and
  oper.OperationHasLongText = 'X';