C_ProdnOrderForSafetyInsights

DDL: C_PRODNORDERFORSAFETYINSIGHTS Type: view CONSUMPTION Package: EHHSS_CNS_RISK_ASSESSMENT

Production Orders for Safety Insights

C_ProdnOrderForSafetyInsights is a Consumption CDS View that provides data about "Production Orders for Safety Insights" in SAP S/4HANA. It reads from 3 data sources (I_LocationAccountAssignment, I_MfgOrderOperationBasic, I_TechnicalObject) and exposes 13 fields with key fields ProductionOrder, Equipment. It has 1 association to related views. Part of development package EHHSS_CNS_RISK_ASSESSMENT.

3 data source(s) 13 fields

Data Sources (3)

SourceAliasJoin Type
I_LocationAccountAssignment LocationAssignment inner
I_MfgOrderOperationBasic MfgOrderOperationBasic inner
I_TechnicalObject TechnicalObject inner

Associations (1)

CardinalityTargetAliasCondition
[0..*] C_ProdnOrdOpForSafetyInsights _ProductionOrderOperations $projection.ProductionOrder = _ProductionOrderOperations.ManufacturingOrder and $projection.WorkCenterInternalID = _ProductionOrderOperations.WorkCenterInternalID

Annotations (11)

NameValueLevelField
AbapCatalog.sqlViewName CPOFORSI view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #CHECK view
ClientHandling.algorithm #SESSION_VARIABLE view
EndUserText.label Production Orders for Safety Insights view
VDM.viewType #CONSUMPTION view
ObjectModel.representativeKey ProductionOrder view
ObjectModel.usageType.serviceQuality #D view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #MIXED view

Fields (13)

KeyFieldSource TableSource FieldDescription
KEY ProductionOrder ManufacturingOrder ManufacturingOrder
KEY Equipment I_TechnicalObject Equipment
WorkCenterInternalID I_MfgOrderOperationBasic WorkCenterInternalID
Material ManufacturingOrder Material
MaterialName
MfgOrderConfirmedYieldQty MfgOrderConfirmedYieldQty
ProductionUnit ProductionUnit
MfgOrderPlannedStartDate MfgOrderPlannedStartDate
MfgOrderPlannedEndDate MfgOrderPlannedEndDate
_ProductionOrderOperations _ProductionOrderOperations
ManufacturingOrderCategory ManufacturingOrder ManufacturingOrderCategory
ManufacturingOrderType ManufacturingOrder ManufacturingOrderType
ProductionPlant ManufacturingOrder ProductionPlant 
@AbapCatalog: { sqlViewName: 'CPOFORSI',
                compiler.compareFilter: true,
                preserveKey: true }
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@EndUserText.label: 'Production Orders for Safety Insights'
@VDM.viewType: #CONSUMPTION
@ObjectModel: {
  representativeKey: 'ProductionOrder',
  usageType:{ serviceQuality: #D,
              sizeCategory:   #XL,
              dataClass:      #MIXED }
}
define view C_ProdnOrderForSafetyInsights
  as select distinct from I_ManufacturingOrder        as ManufacturingOrder
    inner join            I_MfgOrderOperationBasic    as MfgOrderOperationBasic on ManufacturingOrder.ManufacturingOrder = MfgOrderOperationBasic.ManufacturingOrder
    inner join            I_LocationAccountAssignment as LocationAssignment     on MfgOrderOperationBasic.WorkCenterInternalID = LocationAssignment.WorkCenterInternalID
    inner join            I_TechnicalObject           as TechnicalObject        on LocationAssignment.MaintObjectLocAcctAssgmtNmbr = TechnicalObject.MaintObjectLocAcctAssgmtNmbr

  association [0..*] to C_ProdnOrdOpForSafetyInsights as _ProductionOrderOperations on  $projection.ProductionOrder      = _ProductionOrderOperations.ManufacturingOrder
                                                                                    and $projection.WorkCenterInternalID = _ProductionOrderOperations.WorkCenterInternalID
{
  key ManufacturingOrder.ManufacturingOrder as ProductionOrder,
  key TechnicalObject.Equipment,
      MfgOrderOperationBasic.WorkCenterInternalID,
      ManufacturingOrder.Material,
      _Material._Text[1: Language=$session.system_language].MaterialName,
      MfgOrderConfirmedYieldQty,
      ProductionUnit,
      MfgOrderPlannedStartDate,
      MfgOrderPlannedEndDate,

      _ProductionOrderOperations,

      // required for autorization check

      @Consumption.hidden: true
      ManufacturingOrder.ManufacturingOrderCategory,
      @Consumption.hidden: true
      ManufacturingOrder.ManufacturingOrderType,
      @Consumption.hidden: true
      ManufacturingOrder.ProductionPlant
}
where
      Equipment != ''
  and ManufacturingOrder.ManufacturingOrderCategory = '10' // only Production Order category

  and MfgOrderPlannedEndDate                        >= $session.system_date //consider current and future production orders

  and MfgOrderPlannedStartDate                      <= $session.system_date

Learn More