I_MaintPlanningBucketScopeTP

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Maintenance Planning Bucket Scope TP'

@ObjectModel: {
  createEnabled:                  true,
  updateEnabled:                  true,
  deleteEnabled:                  true,
  writeDraftPersistence:          'EAM_PLNGBKTSCP_D',
  writeActivePersistence:         'EAM_PLNGBKTSCP',
  modelCategory:                  #BUSINESS_OBJECT,
  representativeKey:              'MaintPlanningBucketScopeUUID',
  semanticKey:                    ['MaintPlanningBucketScopeUUID'],
  usageType: {
    serviceQuality: #C,
    dataClass:      #TRANSACTIONAL,
    sizeCategory:   #L
  }
}
@Analytics.technicalName: 'IMTPLNGBKTSCPTP'

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

define view entity I_MaintPlanningBucketScopeTP
  as select from I_MaintPlanningBucketScope
  association [1..1] to I_MaintPlanningBucketTP    as _MaintPlanningBucket         on  _MaintPlanningBucket.MaintPlanningBucketUUID = $projection.MaintPlanningBucketUUID

  association [0..1] to I_MaintenancePlannerGroup  as _MaintenancePlannerGroup     on  _MaintenancePlannerGroup.MaintenancePlannerGroup  = $projection.MaintenancePlannerGroup
                                                                                   and _MaintenancePlannerGroup.MaintenancePlanningPlant = $projection.maintenanceplanningplant

  association [0..1] to I_TechnicalObject          as _TechnicalObject             on  _TechnicalObject.TechnicalObject           = $projection.TechnicalObject
                                                                                   and _TechnicalObject.TechObjIsEquipOrFuncnlLoc = $projection.TechObjIsEquipOrFuncnlLoc

  association [0..1] to I_WorkCenter               as _MainWorkCenter              on  _MainWorkCenter.WorkCenterInternalID = $projection.WorkCenterInternalID
                                                                                   and _MainWorkCenter.WorkCenterTypeCode   = $projection.WorkCenterTypeCode
  association [0..1] to I_WorkCenter               as _WorkCenter                  on  _WorkCenter.WorkCenterInternalID           = $projection.MaintPlngBucketScopeRgFr
                                                                                   and _WorkCenter.WorkCenterTypeCode             = 'A'
                                                                                   and $projection.MaintPlngBcktScpRangeFieldName = 'MainWorkCenterInternalID'
  association [0..1] to I_FunctionalLocationLabel  as _FunctionalLocationLabel     on  _FunctionalLocationLabel.FunctionalLocation = $projection.MaintPlngBucketScopeRgFr
                                                                                   and $projection.MaintPlngBcktScpRangeFieldName  = 'FunctionalLocation'


{
      @UI.hidden
  key MaintPlanningBucketScopeUUID,
      @UI.hidden
      MaintPlanningBucketUUID,

      MaintPlngBcktScpRangeFieldName,
      MaintPlngBucketScopeRgSg,
      MaintPlngBucketScopeRgOp,
      MaintPlngBucketScopeRgFr,
      MaintPlngBucketScopeRgTo,

      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EAM_CALC_MTPLNGBKTSCPDESC'
      @ObjectModel.readOnly
      cast( '' as ktext40 )                                                                                                                                     as MaintPlngBcktScopeDescription,

      @UI.hidden
      @ObjectModel.readOnly
      cast( 0 as abap.int1 )                                                                                                                                    as NumberOfItems,

      /*** Dummy Fields for Value Helps ***/
      @ObjectModel.readOnly
      _MaintPlanningBucket.MaintenancePlanningPlant,

      @ObjectModel.foreignKey.association: '_MaintenancePlannerGroup'
      @Consumption.valueHelpDefinition: [{ entity : { name: 'C_MaintenancePlannerGroupVH', element: 'MaintenancePlannerGroup' },
                                           additionalBinding: [{ element: 'MaintenancePlanningPlant', localElement: 'MaintenancePlanningPlant' }],useForValidation: true }] 
                                           
      cast( '' as eam_planner_group )                                                                                                                           as MaintenancePlannerGroup,

      @Consumption.valueHelpDefinition: [{ entity : { name: 'I_PlantStdVH', element: 'Plant' } }]
      cast( '' as eams_maintplant )                                                                                                                             as MaintenancePlant,

      @Consumption.valueHelpDefinition: [{ entity : { name: 'I_PlantSectionStdVH', element: 'PlantSection' },
                                           additionalBinding: [{ element: 'Plant', localElement: 'MaintenancePlant' }] }]
      cast( '' as beber )                                                                                                                                       as PlantSection,

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_TechnicalObjectStdVH',
                     element: 'TechnicalObject' },
          additionalBinding: [{ localElement: 'TechObjIsEquipOrFuncnlLoc',
                                element: 'TechObjIsEquipOrFuncnlLoc' }]
        }]
      cast( '' as eams_tec_obj )                                                                                                                                as TechnicalObject,

      cast( case MaintPlngBcktScpRangeFieldName when 'Equipment' then 'EAMS_EQUI'
                                                when 'FunctionalLocation' then 'EAMS_FL' end as eams_tec_obj_type )                                             as TechObjIsEquipOrFuncnlLoc,

      @ObjectModel.foreignKey.association: '_MainWorkCenter'
      @Consumption.valueHelpDefinition: [
      { entity:  { name:    'I_WorkCenterStdVh',
               element: 'WorkCenter' },
      additionalBinding: [{ localElement: 'WorkCenterTypeCode',
                          element: 'WorkCenterTypeCode' }]
      }]
      cast( case when MaintPlngBcktScpRangeFieldName = 'MainWorkCenterInternalID' then MaintPlngBucketScopeRgFr end as arbpl )                                  as WorkCenterInternalID,

      cast( 'A' as cr_objty )                                                                                                                                   as WorkCenterTypeCode, // 'A' = Work center


      @Consumption.valueHelpDefinition: [{ entity: { name: 'C_PMWorkCenterVH', element: 'WorkCenter' },
                                          additionalBinding: [{ localElement: 'WorkCenterInternalID',
                                                                element: 'WorkCenterInternalID',
                                                                usage: #RESULT }] }]
      cast( _WorkCenter.WorkCenter as eam_main_work_center preserving type )                                                                                    as MainWorkCenter,

      @Consumption.valueHelpDefinition: [{ entity: { name: 'C_TechnicalObjectLabelVH', element: 'TechnicalObjectLabel' },
                                          additionalBinding: [{ localElement: 'TechnicalObject',
                                                                element: 'TechnicalObject',
                                                                usage: #RESULT },
                                                              { localElement: 'TechObjIsEquipOrFuncnlLoc',
                                                                element: 'TechObjIsEquipOrFuncnlLoc',
                                                                usage: #RESULT }] }]
      cast( case MaintPlngBcktScpRangeFieldName when 'Equipment' then MaintPlngBucketScopeRgFr
                                                when 'FunctionalLocation' then _FunctionalLocationLabel.FunctionalLocationLabelName end as eams_tech_obj_conv ) as TechnicalObjectLabel,


      /*** Dummy Fields for Value Helps ***/



      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT ]
      _MaintPlanningBucket,
      _MaintenancePlannerGroup,
      _TechnicalObject,
      _MainWorkCenter
}