I_FunctionalLocationLabel

@EndUserText.label: 'Functional Location Label'
@Analytics: { dataCategory: #DIMENSION }
@VDM.viewType: #COMPOSITE
@AbapCatalog: { sqlViewName: 'IFUNCLOCLABEL', preserveKey }
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck:#NOT_REQUIRED
@ObjectModel.representativeKey: 'FunctionalLocation'

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #L

@Metadata: { allowExtensions, ignorePropagatedAnnotations }
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE]

define view I_FunctionalLocationLabel
  as select from I_FunctionalLocation
  association [0..1] to I_FlocLabelingState       as _FlocLabelingState       on  _FlocLabelingState.AlternativeLabelingIsActive = 'X'
                                                                              or  _FlocLabelingState.AlternativeLabelingIsActive = ''

  association [0..1] to P_FlocUserLabel           as _FlocUserlabel           on  _FlocUserlabel.FunctionalLocation = $projection.FunctionalLocation
  association [0..1] to P_FlocPrimaryLabel        as _FlocPrimaryLabel        on  _FlocPrimaryLabel.FunctionalLocation = $projection.FunctionalLocation

  // Use the calculated Functional Location Label and Labeling System to fetch a raw version of the Functional Location Label which can be used in HANA contains() statement

  association [0..1] to I_FuncLocationLabelSearch as _FuncLocationLabelSearch on  $projection.FunctionalLocation          = _FuncLocationLabelSearch.FunctionalLocation
                                                                              and $projection.FunctionalLocLabelingSyst   = _FuncLocationLabelSearch.FunctionalLocLabelingSyst
                                                                              and $projection.FunctionalLocationLabelName = _FuncLocationLabelSearch.FunctionalLocationLabelName
{

  key  FunctionalLocation,

      // --------------------------------------------------------------------------------------------------

      // Calculate the active Functional Location Label (if available)

      // --------------------------------------------------------------------------------------------------

      cast( case when _FlocLabelingState.AlternativeLabelingStatus = '2' and _FlocLabelingState.AlternativeLabelingIsActive = 'X' then  // 2 = Alternative Labeling is active

            coalesce( coalesce(_FlocUserlabel.FunctionalLocationLabelName, _FlocPrimaryLabel.FunctionalLocationLabelName), FunctionalLocation )
        when _FlocLabelingState.AlternativeLabelingStatus = '3' and _FlocLabelingState.AlternativeLabelingIsActive = '' then // 3 = Alternative Labeling is deactivated

            coalesce(_FlocPrimaryLabel.FunctionalLocationLabelName, FunctionalLocation)
        else          // 1 = Alternative Labeling has never been active (no entries in IFLOS table)

            FunctionalLocation
      end as  ilom_strno    )                       as FunctionalLocationLabelName,

      // --------------------------------------------------------------------------------------------------

      // Calculate the active Functional Location Labeling System (if available)

      // --------------------------------------------------------------------------------------------------

      cast( case when _FlocLabelingState.AlternativeLabelingStatus = '2' and _FlocLabelingState.AlternativeLabelingIsActive = 'X' then  // 2 = Alternative Labeling is active

            coalesce(coalesce(_FlocUserlabel.FunctionalLocLabelingSyst, _FlocPrimaryLabel.FunctionalLocLabelingSyst),'')
        when _FlocLabelingState.AlternativeLabelingStatus = '3' and _FlocLabelingState.AlternativeLabelingIsActive = '' then // 3 = Alternative Labeling is deactivated

            coalesce(_FlocPrimaryLabel.FunctionalLocLabelingSyst,'')
        else          // 1 = Alternative Labeling has never been active (no entries in IFLOS table)

            ''
      end as  ilom_alkey     )                      as FunctionalLocLabelingSyst,

      // For searching purposes

      _FlocUserlabel.FunctionalLocationLabelName    as FuncnlLocUserLabelName,
      _FlocPrimaryLabel.FunctionalLocationLabelName as FuncnlLocPrimaryLabelName,

      // Propagate the raw version version of the Functional Location Label to enable HANA search on the field

      _FuncLocationLabelSearch,
      _FunctionalLocationText
}