I_SchedulingFloatProfile

@AbapCatalog.sqlViewName: 'ISCHEDLFLOATPRFL'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.buffering: {status: #ACTIVE, type: #GENERIC, numberOfKeyFields: 001}
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.dataCategory: #DIMENSION
@Analytics.dataExtraction.enabled: true
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@Consumption.ranked: true
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.sapObjectNodeType.name: 'SchedulingFloatProfile' 
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE, #EXTRACTION_DATA_SOURCE, #SQL_DATA_SOURCE, #SEARCHABLE_ENTITY]
@ObjectModel.representativeKey: 'SchedulingFloatProfile'
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #S, dataClass: #CUSTOMIZING}
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Scheduling Float Profile'

define view I_SchedulingFloatProfile
  as select from t436a
  
  association [1..1] to I_Plant as _Plant on $projection.Plant = _Plant.Plant
  {
      @ObjectModel.foreignKey.association: '_Plant'
  key werks                                    as Plant,
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
  key cast(fhori as vdm_fhori preserving type) as SchedulingFloatProfile,

      // Floats

      erhor                                    as OpeningPeriodInWorkDays,
      cast(freiz as vdm_freiz preserving type) as ReleasePeriodInWorkDays,
      cast(sichz as vdm_sichz preserving type) as FloatAfterProductionInWorkDays,
      cast(vorgz as vdm_vorgz preserving type) as FloatBeforeProductionInWrkDays,

      // Associations

      _Plant
  };