I_OrderConfirmationRequest

DDL: I_ORDERCONFIRMATIONREQUEST Type: view_entity BASIC Package: VDM_PP_CNF

Order Confirmation Request

I_OrderConfirmationRequest is a Basic CDS View that provides data about "Order Confirmation Request" in SAP S/4HANA. It reads from 2 data sources (afrp0, I_LogisticsOrder) and exposes 27 fields with key field PlantDataCollectionItem. Part of development package VDM_PP_CNF.

2 data source(s) 27 fields

Data Sources (2)

SourceAliasJoin Type
afrp0 afrp0 from
I_LogisticsOrder LogisticsOrder inner

Annotations (10)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
AccessControl.personalData.blocking #NOT_REQUIRED view
EndUserText.label Order Confirmation Request view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.modelingPattern #NONE view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
VDM.viewType #BASIC view

Fields (27)

KeyFieldSource TableSource FieldDescription
KEY PlantDataCollectionItem afrp0 counter
ertstampsasCreationDateTime
EnteredByUser afrp0 ernam
ltxa1asConfirmationText
budatasPostingDate
OperationConfirmation afrp0 rueck
FinalConfirmationType afrp0 aueru
OpenReservationsIsCleared afrp0 ausor
ConfirmationApplicationOrigin afrp0 ru_orina
ConfirmationInterfaceOrigin afrp0 ru_orini
OrderConfirmationRecordType afrp0 satza
ExternalSystemConfirmation afrp0 extid
aufnrasOrderID
Sequence afrp0 aplfl
OrderOperation
OrderSuboperation
LeadingOrder I_LogisticsOrder LeadingOrder
Plant I_LogisticsOrder Plant
OrderCategory I_LogisticsOrder OrderCategory
OrderType
arbplasWorkCenter
WorkCenterPlant
meinhasConfirmationUnit
ConfirmationYieldQuantity afrp0 lmnga
ConfirmationScrapQuantity afrp0 xmnga
ConfirmationReworkQuantity afrp0 rmnga
VarianceReasonCode afrp0 grund 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Order Confirmation Request'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.usageType:{
  serviceQuality: #B,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC

define view entity I_OrderConfirmationRequest
  as select from afrp0            as afrp0
    inner join   I_LogisticsOrder as LogisticsOrder on LogisticsOrder.OrderID = afrp0.aufnr
{
      -- Key
  key cast(afrp0.pdsnr as vdm_pdsnr preserving type)           as SequentialPlantDataCollection,
      @ObjectModel.text.element: ['ConfirmationText']
  key afrp0.counter                                            as PlantDataCollectionItem,
  
      -- Admin data
      @Semantics.systemDateTime.createdAt: true
      afrp0.ertstamps                                          as CreationDateTime,
      @Semantics.user.createdBy: true
      afrp0.ernam                                              as EnteredByUser,

      -- Text
      @Semantics.text: true
      afrp0.ltxa1                                              as ConfirmationText,
      
      -- Conf data
      @Semantics.businessDate.at: true
      afrp0.budat                                              as PostingDate,
      afrp0.rueck                                              as OperationConfirmation,
      afrp0.aueru                                              as FinalConfirmationType,
      afrp0.ausor                                              as OpenReservationsIsCleared,
      afrp0.ru_orina                                           as ConfirmationApplicationOrigin,
      afrp0.ru_orini                                           as ConfirmationInterfaceOrigin,
      afrp0.satza                                              as OrderConfirmationRecordType,
      afrp0.extid                                              as ExternalSystemConfirmation,
      
      -- Order data
      afrp0.aufnr                                              as OrderID,
      afrp0.aplfl                                              as Sequence,
      cast(afrp0.vornr as vdm_vornr preserving type)           as OrderOperation,
      cast(afrp0.uvorn as vdm_uvorn preserving type)           as OrderSuboperation,
      LogisticsOrder.LeadingOrder                              as LeadingOrder,
      LogisticsOrder.Plant                                     as Plant,
      LogisticsOrder.OrderCategory                             as OrderCategory,
      cast(LogisticsOrder.OrderType as aufart preserving type) as OrderType,
      
      -- Work center
      afrp0.arbpl                                              as WorkCenter,
      cast(afrp0.werks as vdm_poplatzwrk preserving type)      as WorkCenterPlant,

      -- Quantities
      afrp0.meinh                                              as ConfirmationUnit,
      @Semantics.quantity.unitOfMeasure: 'ConfirmationUnit'
      @Aggregation.default: #SUM
      afrp0.lmnga                                              as ConfirmationYieldQuantity,
      @Semantics.quantity.unitOfMeasure: 'ConfirmationUnit'
      @Aggregation.default: #SUM
      afrp0.xmnga                                              as ConfirmationScrapQuantity,
      @Semantics.quantity.unitOfMeasure: 'ConfirmationUnit'
      @Aggregation.default: #SUM
      afrp0.rmnga                                              as ConfirmationReworkQuantity,
      afrp0.grund                                              as VarianceReasonCode
};

Learn More