I_DeliveryDocumentAddress

@EndUserText.label: 'Delivery Document Address'

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #BLOCKED_DATA_EXCLUDED
}

@VDM.viewType: #COMPOSITE

@ObjectModel: {
  usageType.dataClass: #MIXED,
  usageType.serviceQuality: #C,
  usageType.sizeCategory: #L
}

@Metadata.ignorePropagatedAnnotations: true
define view entity I_DeliveryDocumentAddress
  as select from I_SDDocumentCompletePartners as DeliveryDocumentAddress
  association [0..1] to I_DeliveryDocument as _DeliveryDocument on _DeliveryDocument.DeliveryDocument = DeliveryDocumentAddress.SDDocument
  association [0..1] to I_Supplier         as _AuthSupplier     on $projection.Supplier = _AuthSupplier.Supplier
  association [0..1] to I_Customer         as _AuthCustomer     on $projection.Customer = _AuthCustomer.Customer
{

  key SDDocument                                                                  as DeliveryDocument,
  key cast(PartnerFunction as parvw_unv preserving type )                         as PartnerFunction,

      AddressID,

      ///////////////////

      // Section: Name //

      ///////////////////



      // Title

      _DfltAddrRprstn.FormOfAddress,
      //Name for organisation

      _DfltAddrRprstn.OrganizationName1,
      _DfltAddrRprstn.OrganizationName2,
      _DfltAddrRprstn.OrganizationName3,
      _DfltAddrRprstn.OrganizationName4,

      /////////////////////////////

      // Section: Street Address //

      /////////////////////////////


      // Buildling Code ... Room ... Floor

      _DfltAddrRprstn.Building,
      _DfltAddrRprstn.Floor,
      _DfltAddrRprstn.RoomNumber,

      // c/o

      _DfltAddrRprstn.CareOfName,

      // Street 2

      _DfltAddrRprstn.StreetPrefixName1,
      // Street 3

      _DfltAddrRprstn.StreetPrefixName2,
      // Street ... House Number ... Suppl.

      _DfltAddrRprstn.StreetName,
      _DfltAddrRprstn.HouseNumber,
      _DfltAddrRprstn.HouseNumberSupplementText,
      // Street 4

      _DfltAddrRprstn.StreetSuffixName1,
      // Street 5

      _DfltAddrRprstn.StreetSuffixName2,
      // District

      _DfltAddrRprstn.DistrictName,
      // Home City

      _DfltAddrRprstn.VillageName,
      // Postal Code ... City

      _DfltAddrRprstn.PostalCode,
      _DfltAddrRprstn.CityName,
      // County

      _DfltAddrRprstn.SecondaryRegionName,
      // Township


      // Country

      _DfltAddrRprstn.Country,
      // Region

      _DfltAddrRprstn.Region,
      // Time Zone ... Tax Juris.

      _DfltAddrRprstn.AddressTimeZone,
      _DfltAddrRprstn.TaxJurisdiction,
      // Transportation Zone

      _DfltAddrRprstn.TransportZone,

      /////////////////////////////

      // Section: PO Box Address //

      /////////////////////////////


      // PO Box ... PO box w/o no.

      _DfltAddrRprstn.POBox,
      _DfltAddrRprstn.POBoxIsWithoutNumber,
      // Dlvry Serv/Dlvry No

      _DfltAddrRprstn.DeliveryServiceTypeCode,
      _DfltAddrRprstn.DeliveryServiceNumber,
      // PO Box Lobby

      _DfltAddrRprstn.POBoxLobbyName,
      // Postal code ... Other City

      _DfltAddrRprstn.POBoxPostalCode,
      _DfltAddrRprstn.POBoxDeviatingCityName,
      // Other Country ... Other Region

      _DfltAddrRprstn.POBoxDeviatingCountry,
      _DfltAddrRprstn.POBoxDeviatingRegion,
      // Company Postal Code

      _DfltAddrRprstn.CompanyPostalCode,
      // Undeliverable

      _DfltAddrRprstn.POBoxAddrNonDeliverableReason,

      ////////////////////////////

      // Section: Communication //

      ////////////////////////////

      _DfltAddrRprstn.CorrespondenceLanguage,
      // Telephone ... Extension

      _DfltAddrRprstn._CurrentDfltLandlinePhoneNmbr.PhoneAreaCodeSubscriberNumber,
      _DfltAddrRprstn._CurrentDfltLandlinePhoneNmbr.PhoneExtensionNumber,
      // Fax ... Extension

      _DfltAddrRprstn._CurrentDfltFaxNumber.FaxAreaCodeSubscriberNumber,
      _DfltAddrRprstn._CurrentDfltFaxNumber.FaxExtensionNumber,
      // E-Mail

      _DfltAddrRprstn._CurrentDfltEmailAddress.EmailAddress,
      // Standard Method

      _DfltAddrRprstn.PrfrdCommMediumType,

      _DeliveryDocument,

      //only for DCL

      @Consumption.hidden: true
      Customer,
      @Consumption.hidden: true
      Supplier,
      @Consumption.hidden: true
      _DeliveryDocument.ShippingPoint,
      _AuthSupplier,
      _AuthCustomer

}
where
       DeliveryDocumentAddress.SDDocumentItem is initial
  and(
       _DeliveryDocument.SDDocumentCategory   = 'J'
    or _DeliveryDocument.SDDocumentCategory   = '7'
    or _DeliveryDocument.SDDocumentCategory   = 'T'
  );