I_SDDOCUMENTCOMPLETEPARTNERS

@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'SD Document Complete Partners'
@VDM.viewType: #BASIC
@AccessControl: {
  authorizationCheck: #NOT_REQUIRED,
  personalData.blocking: #NOT_REQUIRED,
  privilegedAssociations: [ '_Address', '_DfltAddrRprstn','_PersonWorkplaceAddrDfltRprstn' ]
}
@AbapCatalog: {
  sqlViewName: 'ISDDOCCMPLTPART',
  compiler.compareFilter: true,
  preserveKey: true
}
@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #A,
     sizeCategory:   #XL
   }
}

define view I_SDDocumentCompletePartners
  as

  select from vbpa

  association [0..1] to I_PartnerFunction        as _PartnerFunction               on  $projection.PartnerFunction = _PartnerFunction.PartnerFunction
  association [0..1] to I_ContactPerson          as _ContactPerson                 on  $projection.ContactPerson = _ContactPerson.ContactPerson

  association [0..1] to I_Address                as _Address                       on  $projection.AddressID = _Address.AddressID
//  The address IDs from I_Address_2 are for customers and suppliers

  association [0..1] to I_Address_2              as _DfltAddrRprstn                on  $projection.AddressID                     = _DfltAddrRprstn.AddressID
                                                                                   and $projection.AddressPersonID               = _DfltAddrRprstn.AddressPersonID
                                                                                   and _DfltAddrRprstn.AddressRepresentationCode is initial
  association [0..1] to I_BusPartAddress         as _BusinessPartnerAddress        on  $projection.ReferenceBusinessPartner   = _BusinessPartnerAddress.BusinessPartner
                                                                                   and $projection.AddressID                  = _BusinessPartnerAddress.AddressID
                                                                                   and $projection.SDDocPartnerAddressRefType = 'H'
  association [0..1] to I_BusPartAddress         as _BPRefAddressForDocSpcfcAddr   on  $projection.ReferenceBusinessPartner      = _BPRefAddressForDocSpcfcAddr.BusinessPartner
                                                                                   and $projection.BPRefAddressIDForDocSpcfcAddr = _BPRefAddressForDocSpcfcAddr.AddressID
//   The address IDs from I_PersonWorkplaceAddress are for contact persons                                                                              

  association [0..1] to I_PersonWorkplaceAddress as _PersonWorkplaceAddrDfltRprstn on  $projection.AddressID                                    = _PersonWorkplaceAddrDfltRprstn.AddressID
                                                                                   and $projection.AddressPersonID                              = _PersonWorkplaceAddrDfltRprstn.AddressPersonID
                                                                                   and _PersonWorkplaceAddrDfltRprstn.AddressRepresentationCode is initial
{
  key vbpa.vbeln          as SDDocument,
  key vbpa.posnr          as SDDocumentItem,
      @ObjectModel.foreignKey.association: '_PartnerFunction'
  key vbpa.parvw          as PartnerFunction,

      vbpa.kunnr          as Customer,
      vbpa.lifnr          as Supplier,
      vbpa.pernr          as Personnel,
      @ObjectModel.foreignKey.association: '_ContactPerson'
      vbpa.parnr          as ContactPerson,

      vbpa.assigned_bp    as ReferenceBusinessPartner,

      // Address related fields

      @ObjectModel.foreignKey.association: '_Address'
      vbpa.adrnr          as AddressID,
      vbpa.adrnp          as AddressPersonID,
      vbpa.adrda          as SDDocPartnerAddressRefType,
      vbpa.addr_type      as AddressObjectType,
      vbpa.addr_operation as BPAddrDeterminationTransaction,
      vbpa.bp_ref_adrnr   as BPRefAddressIDForDocSpcfcAddr,

      vbpa.xcpdk          as PartnerIsOneTimeAccount,
      vbpa.stceg          as VATRegistration,
      @Semantics.text: true
      vbpa.ablad          as UnloadingPointName,
      vbpa.land1          as CountryCode,
      
      cast(
      case adrda 
        when 'E' then 'X'     
        when 'F' then 'X'            
        else ' '             
      end                 as sd_pd_doc_spec_addr_flag) as SDDocPartnerAddrIsDocSpecific,
      
      vbpa.hityp          as CustomerHierarchyType,
      vbpa.prfre          as CustIsPrcDetnRlvt,
      vbpa.bokre          as CustomerIsRebateRelevant,
      vbpa.histunr        as CustomerHierarchyLevel,
      vbpa.hzuor          as CustomerHierarchyFixedLevel,
      vbpa.lzone          as TransportZone,

      _PartnerFunction,
      _ContactPerson,

      // Address related associations

      _Address,
      _DfltAddrRprstn,
      _BusinessPartnerAddress,
      _PersonWorkplaceAddrDfltRprstn,
      _BPRefAddressForDocSpcfcAddr
      
};