I_ChmlCmplncReq

@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.sqlViewName: 'ICCMPLCNREQ'

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.privilegedAssociations: [ '_CreatedByUser', '_LastChangedByUser', '_RequesterUser' ]

@ClientHandling.algorithm: #SESSION_VARIABLE

@EndUserText.label: 'Chemical Compliance Request'

@ObjectModel.representativeKey: 'ChmlCmplncRequestUUID'
@ObjectModel.usageType: { dataClass: #MASTER, sizeCategory: #L, serviceQuality: #B }

@VDM.viewType: #BASIC

define view I_ChmlCmplncReq
  as select from ehfndv_crq

  association [0..1] to I_ChmlCmplncInfo            as _ChmlCmplncInfo
    on $projection.ChmlCmplncInfoUUID = _ChmlCmplncInfo.ChmlCmplncInfoUUID

  association [0..1] to I_ChmlCmplncInfo            as _ChmlCmplncInfoProd
    on $projection.ChmlCmplncProdUUID = _ChmlCmplncInfoProd.ChmlCmplncInfoUUID

  association [0..1] to I_User                      as _CreatedByUser
    on $projection.CreatedByUser = _CreatedByUser.UserID

  association [0..1] to I_User                      as _LastChangedByUser
    on $projection.LastChangedByUser = _LastChangedByUser.UserID

  association [0..1] to I_User                      as _RequesterUser
    on $projection.ChmlCmplncReqRequester = _RequesterUser.UserID

  association [0..1] to I_Product                   as _Product
    on $projection.Material = _Product.Product

  association [0..1] to I_Product                   as _MultiComponentProduct
    on $projection.MultiComponentProduct = _MultiComponentProduct.Product

  association [0..1] to I_BusinessUserBasic         as _BusinessUserRequester
    on $projection.ChmlCmplncReqBPRequester = _BusinessUserRequester.BusinessPartner

  association [0..1] to I_BusinessUserBasic         as _BusinessUserProcessor
    on $projection.ChmlCmplncReqBPProcessor = _BusinessUserProcessor.BusinessPartner

  association [0..1] to I_ChmlCmplncReqCmplncProc   as _ChmlCmplncReqCmplncProc
    on $projection.ChmlCmplncReqCmplncProc = _ChmlCmplncReqCmplncProc.ChmlCmplncReqCmplncProc

  association [0..1] to I_ChmlCmplncBusProc         as _BusinessProcess
    on $projection.ChmlCmplncBusinessProcess = _BusinessProcess.ChmlCmplncBusinessProcess

  association [0..1] to I_ChmlCmplncReqOriginType   as _OriginType
    on $projection.ChmlCmplncRequestOriginType = _OriginType.ChmlCmplncRequestOriginType

  association [0..1] to I_ChmlCmplncReqOriginProc   as _OriginProcess
    on $projection.ChmlCmplncReqOriginProc = _OriginProcess.ChmlCmplncReqOriginProc

  association [0..1] to I_ChmlCmplncReqStatus       as _RequestStatus
    on $projection.ChmlCmplncRequestPrgrsStatus = _RequestStatus.ChmlCmplncReqStatus

  association [0..1] to I_ChemicalCustomerMaterial  as _ChemicalCustomerMaterial
    on $projection.ChemicalCustomerMaterialUUID = _ChemicalCustomerMaterial.ChemicalCustomerMaterialUUID

  association [0..*] to I_ChmlCmplncReqMkt          as _RequestedMarket
    on $projection.ChmlCmplncRequestUUID = _RequestedMarket.ChmlCmplncRequestUUID

  association [0..*] to I_ChmlCmplncReqApplication  as _RequestedApplication
    on $projection.ChmlCmplncRequestUUID = _RequestedApplication.ChmlCmplncRequestUUID

  association [0..*] to I_ChmlCmplncReqPrpsAssgmt   as _RequestedPurpose
    on $projection.ChmlCmplncRequestUUID = _RequestedPurpose.ChmlCmplncRequestUUID

  association [0..*] to I_ChmlCmplncReqSlsOrg       as _RequestedSlsOrg
    on $projection.ChmlCmplncRequestUUID = _RequestedSlsOrg.ChmlCmplncRequestUUID

  association [0..*] to I_ChmlCmplncReqPlnt         as _RequestedPlnt
    on $projection.ChmlCmplncRequestUUID = _RequestedPlnt.ChmlCmplncRequestUUID

  association [0..*] to I_ChmlCmplncReqRouteSegment as _RouteSegment
    on $projection.ChmlCmplncRequestUUID = _RouteSegment.ChmlCmplncRequestUUID

  association [0..*] to I_ChmlCmplncReqStep         as _Step
    on $projection.ChmlCmplncRequestUUID = _Step.ChmlCmplncRequestUUID

  association [0..1] to I_Supplier                  as _Supplier
    on $projection.Supplier = _Supplier.Supplier

  association [0..1] to I_Customer                  as _Customer
    on $projection.Customer = _Customer.Customer

  // Partners for Sales and Delivery Documents - restricted to Partner Function "Customer"

  association [0..1] to I_SDDocumentPartner         as _SDDocumentPartnerCustomer
    on  $projection.SalesDocument                  = _SDDocumentPartnerCustomer.SDDocument
    and _SDDocumentPartnerCustomer.PartnerFunction = 'WE'

  association [0..1] to I_DngrsGdsLogsPackgInstrn   as _PackingInstruction
    on $projection.DngrsGdsLogsPackgInstrnUUID = _PackingInstruction.DngrsGdsLogsPackgInstrnUUID

{
  key chmlcmplncrequestuuid                                                   as ChmlCmplncRequestUUID,

      @Semantics.systemDateTime.createdAt: true
      cast(creationutcdatetime as ehfnd_bo_crea_date_time preserving type)    as CreationUTCDateTime,

      @Semantics.user.createdBy: true
      cast(createdbyuser as ehfnd_bo_crea_uname preserving type)              as CreatedByUser,

      @Semantics.systemDateTime.lastChangedAt: true
      cast(lastchangeutcdatetime as ehfnd_bo_lchg_date_time preserving type)  as LastChangeUTCDateTime,

      @Semantics.user.lastChangedBy: true
      cast(lastchangedbyuser as ehfnd_bo_lchg_uname preserving type)          as LastChangedByUser,


      chmlcmplncrequestduedate                                                as ChmlCmplncRequestDueDate,
      chmlcmplncreqcmplncproc                                                 as ChmlCmplncReqCmplncProc,
      chmlcmplncrequestorigintype                                             as ChmlCmplncRequestOriginType,
      chmlcmplncreqoriginproc                                                 as ChmlCmplncReqOriginProc,
      chmlcmplncrequestprgrsstatus                                            as ChmlCmplncRequestPrgrsStatus,
      chmlcmplncbusinessprocess                                               as ChmlCmplncBusinessProcess,
      chmlcmplncreqbpprocessor                                                as ChmlCmplncReqBPProcessor,
      chmlcmplncreqbprequester                                                as ChmlCmplncReqBPRequester,
      chmlcmplncreqrequester                                                  as ChmlCmplncReqRequester,

      chmlcmplncinfouuid                                                      as ChmlCmplncInfoUUID,
      chmlcmplncproduuid                                                      as ChmlCmplncProdUUID,
      chemicalcustomermaterialuuid                                            as ChemicalCustomerMaterialUUID,

      material                                                                as Material,
      salesdocument                                                           as SalesDocument,
      salesdocumentitem                                                       as SalesDocumentItem,
      chmlcmplncreqlogisticdoccat                                             as ChmlCmplncReqLogisticDocCat,
      multicomponentproduct                                                   as MultiComponentProduct,

      chmlcmplncrequestremark                                                 as ChmlCmplncRequestRemark,

      chmlcmplncreqdetails                                                    as ChmlCmplncReqDetails,

      prodcmplnclogsdocument                                                  as ProdCmplncLogsDocument,
      cast(prodcmplnclogsdocument as ehfnd_log_doc_number_nc preserving type) as ProdCmplncLogsDocNotCnvrtd,
      prodcmplnclogsdocumentuuid                                              as ProdCmplncLogsDocumentUUID,
      prodcmplnclogsdocumentitem                                              as ProdCmplncLogsDocumentItem,
      businesssystemname                                                      as BusinessSystemName,
      dngrsgoodsmodeoftransport                                               as DngrsGoodsModeOfTransport,

      supplier                                                                as Supplier,
      customer                                                                as Customer,

      productcompliancerequest                                                as ProductComplianceRequest,
      dngrsgdslogspackginstrnuuid                                             as DngrsGdsLogsPackgInstrnUUID,


      -- associations
      _CreatedByUser,
      _LastChangedByUser,
      _Product,
      _ChmlCmplncInfo,
      _ChmlCmplncInfoProd,
      _ChemicalCustomerMaterial,
      _RequesterUser,
      _BusinessUserRequester,
      _BusinessUserProcessor,
      _ChmlCmplncReqCmplncProc,
      _BusinessProcess,
      _OriginType,
      _OriginProcess,
      _RequestStatus,
      _RequestedMarket,
      _RequestedApplication,
      _RequestedPurpose,
      _RequestedSlsOrg,
      _RequestedPlnt,
      _RouteSegment,
      _Step,
      _Supplier,
      _Customer,
      _SDDocumentPartnerCustomer,
      _MultiComponentProduct,
      _PackingInstruction
}