I_CADocumentBPItemPhysical

// !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

// DEPRECATED - DON'T USE ANYMORE

// use I_CADocumentBPItem instead

// !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!


@AbapCatalog: { preserveKey: true,
                sqlViewName: 'ICADOCBPITEMPHYS' }

@AccessControl.authorizationCheck: #CHECK

@ClientHandling.algorithm: #SESSION_VARIABLE

@EndUserText.label: 'Document Physical Business Partner Item'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: { supportedCapabilities: [ #CDS_MODELING_ASSOCIATION_TARGET,
                                         #SQL_DATA_SOURCE,
                                         #CDS_MODELING_DATA_SOURCE  ],
                usageType: { serviceQuality: #C,
                             sizeCategory: #XXL,
                             dataClass: #TRANSACTIONAL } }

@Search.searchable: true

@VDM.viewType: #COMPOSITE


define view I_CADocumentBPItemPhysical
  as select from I_CADocumentBPItem as CADocBPItem

  association [1..1] to I_CADocumentHeader           as _DocHeader         on  $projection.CADocumentNumber = _DocHeader.CADocumentNumber
  association [0..1] to I_CADocumentHeader           as _SubstitDocHeader  on  $projection.CASubstituteDocumentNumber = _SubstitDocHeader.CADocumentNumber
  association [0..1] to I_CADocumentHeader           as _ClearingDocHeader on  $projection.CAClearingDocumentNumber = _ClearingDocHeader.CADocumentNumber
  association [0..1] to I_CADocumentHeader           as _OriginDocHeader   on  $projection.CADocumentNumberOfOriginItem = _OriginDocHeader.CADocumentNumber
  association [1..1] to I_GLAccountInChartOfAccounts as _ReconAccount      on  $projection.ChartOfAccounts         = _ReconAccount.ChartOfAccounts
                                                                           and $projection.CAReconciliationAccount = _ReconAccount.GLAccount
  association [0..1] to I_GLAccountInChartOfAccounts as _TaxAccount        on  $projection.ChartOfAccounts         = _TaxAccount.ChartOfAccounts
                                                                           and $projection.CADownPaymentTaxAccount = _TaxAccount.GLAccount
  association [0..1] to I_GLAccountInChartOfAccounts as _OffsetTaxAccount  on  $projection.ChartOfAccounts               = _OffsetTaxAccount.ChartOfAccounts
                                                                           and $projection.CADownPaymentOffsetTaxAccount = _OffsetTaxAccount.GLAccount
  association [0..1] to I_GLAccountInChartOfAccounts as _CashFlowAccount   on  $projection.ChartOfAccounts   = _CashFlowAccount.ChartOfAccounts
                                                                           and $projection.CACashFlowAccount = _CashFlowAccount.GLAccount

  association [1..1] to E_CADocumentBPItemPhysical   as _Extension         on  $projection.CADocumentNumber       = _Extension.CADocumentNumber
                                                                           and $projection.CARepetitionItemNumber = _Extension.CARepetitionItemNumber
                                                                           and $projection.CABPItemNumber         = _Extension.CABPItemNumber
                                                                           and $projection.CASubItemNumber        = _Extension.CASubItemNumber
{
      /* business partner item identification */
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
  key CADocBPItem.CADocumentNumber,
  key CADocBPItem.CARepetitionItemNumber,
  key CADocBPItem.CABPItemNumber,
  key CADocBPItem.CASubItemNumber,

      CADocBPItem.CompanyCode,
      CADocBPItem.BusinessArea,
      CADocBPItem.BusinessPlace,
      CADocBPItem.Segment,
      CADocBPItem.ProfitCenter,
      CADocBPItem.Division,
      CADocBPItem.PersonnelNumber,
      CADocBPItem.PartnerCompany,
      CADocBPItem.BusinessPartner,
      CADocBPItem.CAContract,
      CADocBPItem.CAProviderContractItemNumber,
      CADocBPItem.CAAdditionalContract,
      CADocBPItem.ContractAccount,
      CADocBPItem.CASubApplication,
      CADocBPItem.AltvContractAcctForCollvBills,
      CADocBPItem.CAReconciliationAccount,

      /* posting attributes */
      CADocBPItem.CAApplicationArea,
      CADocBPItem.CAMainTransaction,
      CADocBPItem.CASubTransaction,
      CADocBPItem.CAAccountDeterminationCode,
      CADocBPItem.CADoubtfulOrValueAdjmtCode,
      CADocBPItem.CAAccountAssignmentCategory,
      CADocBPItem.CAAccountAssignment,
      CADocBPItem.CADocumentType,
      CADocBPItem.CAIsDownPaymentRequest,
      CADocBPItem.CAItemIsOnlyForSettlement,
      CADocBPItem.CAStatisticalItemCode,
      CADocBPItem.CABPItemText,
      CADocBPItem.CANumberOfRepetitionItems,
      CADocBPItem.CARepetitionGroup,
      CADocBPItem.CAStartDateOfBillingPeriod,
      CADocBPItem.CAEndDateOfBillingPeriod,
      CADocBPItem.CAGroupingCodeForBPItems,
      CADocBPItem.CAPeriodCode,
      CADocBPItem.CAChangeIsForbidden,
      CADocBPItem.CAInterestCode,
      CADocBPItem.CARoundingItemCode,
      CADocBPItem.CAReceivingCountry,
      CADocBPItem.CAInternalPostingReasonCode,
      CADocBPItem.CAWorkflowCheckReason,
      CADocBPItem.CAWorkflowCheckProcess,
      CADocBPItem.CANegativePostingControlCode,
      CADocBPItem.CAPartnerSettlementStatus,
      CADocBPItem.CAIsPartOfJointLiability,
      CADocBPItem.CADocumentOriginCode,

      /* document references */
      CADocBPItem.CASubstituteDocumentNumber,
      CADocBPItem.CASubstituteDocumentCategory,
      CADocBPItem.CAStatisticalCodeOfOriginItem,
      CADocBPItem.CADocumentNumberOfOriginItem,
      CADocBPItem.CAReferenceDocument,

      /* dates and amounts */
      CADocBPItem.DocumentDate,
      CADocBPItem.CAPostingDate,
      CADocBPItem.CANetDueDate,
      CADocBPItem.CADeferralDate,
      CADocBPItem.TransactionCurrency,
      CADocBPItem.CompanyCodeCurrency,

      //kursf                                                                                                                                                                                                                                                                                                           as  CAExchangeRate,  ////replace due to conversion exit EXCRT

      CADocBPItem.CAExchangeRate,
      CADocBPItem.ExchRateIsIndirectQuotation,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      CADocBPItem.CAAmountInLocalCurrency,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CADocBPItem.CAAmountInTransactionCurrency,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      CADocBPItem.CAAmountInSecondCurrency,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      CADocBPItem.CAAmountInThirdCurrency,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CADocBPItem.CADocBPItemTotalAmountInTC,

      /* cash discount */
      CADocBPItem.CACashDiscountDueDate,
      CADocBPItem.CACashDiscountRate,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CADocBPItem.CAEligibleAmountForCshDiscount,

      /* tax data */
      CADocBPItem.TaxCode,
      CADocBPItem.CASupplementaryTaxCode,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      CADocBPItem.CATaxAmountInLocalCurrency,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CADocBPItem.CATaxAmountInTransCurrency,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      CADocBPItem.CATaxAmountInSecondCurrency,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      CADocBPItem.CATaxAmountInThirdCurrency,
      CADocBPItem.CADownPaymentTaxAccount,
      CADocBPItem.CADownPaymentOffsetTaxAccount,
      CADocBPItem.TaxJurisdiction,
      CADocBPItem.CATaxDate,
      CADocBPItem.WithholdingTaxCode,
      CADocBPItem.CAWithholdingTaxSupplement,
      CADocBPItem.CAWithholdingTaxCategory,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CADocBPItem.CABaseAmountForWithholdingTax,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CADocBPItem.CAWithholdingTaxAmount,
      CADocBPItem.CAWithholdingTaxPercentage,
      CADocBPItem.WithholdingTaxCertificate,
      CADocBPItem.CAOtherTaxCode,
      CADocBPItem.CAGroupingCodeForTaxItems,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      CADocBPItem.CATaxPortionInLocalCurrency,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CADocBPItem.CATaxPortionInTransCurrency,
      CADocBPItem.CATaxIsCalculatedExternally,
      CADocBPItem.CATaxAmountIsSetFromExternal,

      /* payment data */
      CADocBPItem.CAPaymentMethod,
      CADocBPItem.CAPaymentCompanyCode,
      CADocBPItem.CAGroupingForPayment,
      CADocBPItem.CAPaymentSpecificationCategory,

      /* clearing data */
      CADocBPItem.CAClearingStatus,
      CADocBPItem.CAClearingDate,
      CADocBPItem.CAClearingDocumentNumber,
      CADocBPItem.CAPostingDateOfClearingDoc,
      CADocBPItem.CAClearingReason,
      CADocBPItem.CAClearingCurrency,
      @Semantics.amount.currencyCode: 'CAClearingCurrency'
      CADocBPItem.CAClearingAmountInClearingCrcy,
      @Semantics.amount.currencyCode: 'CAClearingCurrency'
      CADocBPItem.CATaxAmountInClearingCrcy,
      @Semantics.amount.currencyCode: 'CAClearingCurrency'
      CADocBPItem.CACashDiscAmountInClearingCrcy,
      CADocBPItem.CAValueDateForClearing,
      CADocBPItem.CAClearingRestrictionCode,
      CADocBPItem.CAClearingPostingIsReset,
      CADocBPItem.CAItemIsWithdrawn,

      /* dunning and collections */
      CADocBPItem.CAItemIsExcludedFromDunning,
      CADocBPItem.CADunningProcedure,
      CADocBPItem.CAGrpgCodeForTransfToCollAgcy,
      CADocBPItem.CAIsIncludedInCollectionCase,

      /* cash management data */
      CADocBPItem.CashPlanningGroup,
      CADocBPItem.PlanningLevel,
      CADocBPItem.CAAdditionalDaysForCashMgmt,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CADocBPItem.PlannedAmtInTransactionCrcy,

      /* alternative business partner for payment */
      CADocBPItem.CAAltvBPForPayment,
      CADocBPItem.CABankOfAltvBPForPayment,
      CADocBPItem.CAAddressOfAltvBPForPayment,
      CADocBPItem.CACardOfAltvBPForPayment,
      CADocBPItem.SEPAMandateCAInternalID,

      /* GL data */
      CADocBPItem.CAGLPostingCurrency,
      @Semantics.amount.currencyCode: 'CAGLPostingCurrency'
      CADocBPItem.CAGLPostingAmount,
      @Semantics.amount.currencyCode: 'CAGLPostingCurrency'
      CADocBPItem.CAGLPostingTaxAmount,
      CADocBPItem.CAIsSeparateLineItemInGL,

      /* cash flow data */
      CADocBPItem.CAIsCashFlowItem,
      CADocBPItem.CACashFlowAccount,
      CADocBPItem.CACashFlowCompanyCode,

      /* pre notification data */
      CADocBPItem.CAPaymentPreNotificationCode,
      CADocBPItem.CASEPAPreNotificationNumber,
      CADocBPItem.CASEPAPreNotifOriginCode,
      CADocBPItem.CASEPAPreNotifExecutionDate,
      CADocBPItem.CASEPAPreNotificationRqmtCode,

      /* revenue distribution data */
      CADocBPItem.CARevenueDistrFinalRecipient,
      CADocBPItem.CARevenueDistrCurrentStatus,
      CADocBPItem.CARevenueDistrLastStatus,

      /* Factoring */
      CADocBPItem.CACurrentFactoringStatusOfRbl,
      CADocBPItem.CAFactoringCheckStsForClrgInfo,
      CADocBPItem.CAFactoringItem,

      /* additional data */
      CADocBPItem.ControllingArea,
      CADocBPItem.ChartOfAccounts,
      CADocBPItem.Country,
      CADocBPItem._Country.TaxCalculationProcedure as TaxCalculationProcedure,


      /* associations from I_CADocumentBPItem */
      CADocBPItem._CAAccountAssignmentCategory     as _AcctAssgmtCat,
      CADocBPItem._CAAccountDeterminationCode      as _AcctDetnCode,
      CADocBPItem._PaytAltvBusinessPartner         as _AltvBPForPayment,
      CADocBPItem._CAApplicationArea               as _ApplArea,
      CADocBPItem._BusinessArea,
      CADocBPItem._BusinessPartner,
      CADocBPItem._ContractAccount                 as _CAHeader,
      CADocBPItem._CollvBillsAltvContractAccount   as _CAHeaderCollvBills,
      CADocBPItem._RevnDistrFnlRcpntContrAccount   as _CAHeaderFinalRec,
      CADocBPItem._ContractAccountPartner          as _CAPartner,
      CADocBPItem._CARevenueDistrCurrentStatus     as _CARevnDistrCurSts,
      CADocBPItem._CARevenueDistrLastStatus        as _CARevnDistrLastSts,
      CADocBPItem._CARoundingItemCode,
      CADocBPItem._CASEPAPreNotifOriginCode        as _SEPAPreNotifOrignCd,
      CADocBPItem._CASEPAPreNotificationRqmtCode   as _SEPAPreNotifRqmtCode,
      _CashFlowAccount,
      CADocBPItem._CASubApplication,
      CADocBPItem._ClearingCurrency,
      _ClearingDocHeader,
      CADocBPItem._CAClearingReason                as _ClearingReason,
      CADocBPItem._CAClearingStatus                as _ClearingStatus,
      CADocBPItem._CAClearingRestrictionCode       as _ClrgRstrcnCode,
      CADocBPItem._TransactionCurrency             as _Currency,
      CADocBPItem._CompanyCodeCurrency,
      CADocBPItem._CompanyCode                     as _CompCode,
      CADocBPItem._CashFlowCompanyCode             as _CompCodeCashFlow,
      CADocBPItem._PaymentCompanyCode              as _CompCodePayt,
      CADocBPItem._ControllingArea,
      CADocBPItem._ChartOfAccounts,
      CADocBPItem._Country,
      CADocBPItem._CADbtflOrValueAdjmtCode         as _DbtflOrValAdjmtCode,
      CADocBPItem._Division,
      _DocHeader,
      CADocBPItem._CADocumentType                  as _DocType,
      CADocBPItem._CADunningProcedure              as _DunningProcedure,
      CADocBPItem._CAFactoringReceivableStatus     as _FactoringRblStatus,
      CADocBPItem._CAFactoringClrgCheckStatus      as _FctrngClrgChkStatus,
      CADocBPItem._GLPostingCurrency,
      CADocBPItem._CAInterestCode                  as _InterestCode,
      CADocBPItem._CAInternalPostingReasonCode     as _IntPostingReasonCode,
      CADocBPItem._CAMainTransaction               as _MainTransaction,
      CADocBPItem._CANegativePostingControlCode    as _NgtvPostingCtrlCode,
      _OffsetTaxAccount,
      _OriginDocHeader,
      CADocBPItem._CAOriglStatisticalItemCode      as _OriglStstclItemCode,
      CADocBPItem._CAOtherTaxCode                  as _OtherTaxCode,
      CADocBPItem._PartnerCompany,
      CADocBPItem._CAPaymentMethod                 as _PaytMethod,
      CADocBPItem._CAPaytPreNotificationCode       as _PaytPreNotifCode,
      CADocBPItem._CAPaytSpecificationCategory     as _PaytSpecCategory,
      CADocBPItem._CAPeriodCode                    as _PeriodCode,
      CADocBPItem._ProfitCenter,
      CADocBPItem._CAProviderContract              as _ProviderContract,
      CADocBPItem._CAPartnerSettlementStatus       as _PrtnSettlementStatus,
      CADocBPItem._ReceivingCountry,
      CADocBPItem._Segment,
      CADocBPItem._CAStatisticalItemCode           as _StatisticalItemCode,
      CADocBPItem._CASubstituteDocumentCategory    as _SubstitDocCategory,
      _ReconAccount,
      _SubstitDocHeader,
      CADocBPItem._CASubTransaction                as _SubTransaction,
      _TaxAccount,
      CADocBPItem._CAWithholdingTaxSupplement      as _WhldgTaxSuplmnt,
      CADocBPItem._CAWithholdingTaxCategory        as _CAWithholdingTaxCat,
      CADocBPItem._WithholdingTaxCode,
      CADocBPItem._CAWorkflowCheckProcess          as _WorkflowCheckProcess,
      CADocBPItem._CAWorkflowCheckReason           as _WorkflowCheckReason
}

// don't append/show budget billing requests with clearing restrictions 1 and 6

where
         not(
           CAApplicationArea              = 'R'
           and(
                CAStatisticalItemCode     = 'P'
             or CAStatisticalItemCode     = 'Z'
           )
           and(
                CAClearingRestrictionCode = '1'
             or CAClearingRestrictionCode = '6'
           )
         )