@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Business Partner Items Transfer'
@Search.searchable: true
@ObjectModel: {
usageType.dataClass: #TRANSACTIONAL,
usageType: {
sizeCategory: #XL,
serviceQuality: #D
}
}
define view entity C_CADocumentBPItemTransfer
as select from I_CADocumentBPItemPhysical
{
@UI: {
selectionField: [{ position:5 }],
lineItem: [{ position: 5, importance: #HIGH }]
}
@EndUserText.label: 'Document Number'
@Search: { defaultSearchElement: true, fuzzinessThreshold: 0.9 }
@Consumption.valueHelpDefinition: [{entity: { name: 'C_CADocumentHeaderValueHelp', element: 'CADocumentNumber'}}]
@Consumption.filter: { selectionType: #SINGLE}
key CADocumentNumber,
@UI.hidden: true
key CARepetitionItemNumber,
@UI.hidden: true
key CABPItemNumber,
@UI.hidden: true
key CASubItemNumber,
@UI.hidden: true
key case
when CAAmountInTransactionCurrency < 0
then cast('05' as abap.char(10))
else cast('' as abap.char(10))
end as CAOpenItemStatus,
@Consumption.filter.hidden: true
@Semantics.text: true
@EndUserText.label: 'Business Partner Text'
_BusinessPartner.BusinessPartnerFullName,
@Consumption.filter.hidden: true
@Semantics.text: true
@EndUserText.label: 'Contract Account Text'
_CAHeader.ContractAccountName,
@UI.hidden: true
cast ('' as abap.char(100)) as CABPItemText,
@UI: {
selectionField: [{ position: 20 }],
lineItem: [{ position: 20, importance: #HIGH }],
textArrangement: #TEXT_FIRST
}
@EndUserText.label: 'Business Partner'
@Search: { defaultSearchElement: true, fuzzinessThreshold: 0.9 }
@Consumption.semanticObject: 'CAContractPartner'
@Consumption.valueHelpDefinition: [{entity: { name: 'C_CAContractPartnerValueHelp', element: 'BusinessPartner'}}]
@ObjectModel.text.element: [ 'BusinessPartnerFullName' ]
@Consumption.filter: { selectionType: #SINGLE }
BusinessPartner,
@UI: {
selectionField: [{ position: 30 }],
lineItem: [{ position: 30, importance: #HIGH }]
}
@EndUserText.label: 'Contract Account'
@Search: { defaultSearchElement: true, fuzzinessThreshold: 0.9 }
@Consumption.semanticObject: 'ContractAccount'
@Consumption.valueHelpDefinition: [{entity: { name: 'C_ContractAccountValueHelp', element: 'ContractAccount'}}]
@ObjectModel.text.element: [ 'ContractAccountName' ]
@UI.textArrangement: #TEXT_FIRST
ContractAccount,
// the value help of this field is in DPC and MPC classes
@UI: {
selectionField: [{ position: 40 }],
lineItem: [{ position: 40, importance: #HIGH }]
}
@EndUserText.label: 'Contract'
@ObjectModel.text.element: [ 'CAProviderContractName' ]
@Consumption.semanticObject: 'CAProviderContract'
CAContract,
@UI: {
selectionField: [{ position: 50 }],
lineItem: [{ position: 50, importance: #MEDIUM }]
}
@EndUserText.label: 'Due Date'
@Search: { defaultSearchElement: true, fuzzinessThreshold: 0.9 }
@Consumption.filter.selectionType: #INTERVAL
CANetDueDate,
@UI: {
selectionField: [{ position: 60 }],
lineItem: [{ position: 60, importance: #HIGH }]
}
@EndUserText.label: 'Open Amount'
@Search: { defaultSearchElement: true, fuzzinessThreshold: 0.9 }
CAAmountInTransactionCurrency,
@UI: {
selectionField: [{ position: 65 }]
}
@Consumption.valueHelpDefinition: [{ entity: { name: 'C_CurrencyValueHelp', element: 'Currency' }}]
@EndUserText.label: 'Currency'
@Search: { defaultSearchElement: true, fuzzinessThreshold: 0.9 }
@Consumption.filter: { mandatory: true, selectionType: #SINGLE }
TransactionCurrency,
@EndUserText.label: 'Subapplication'
@ObjectModel: { text.element: [ 'CASubApplicationText' ] }
@Consumption.filter: {selectionType: #SINGLE}
@Consumption.valueHelpDefinition: [{entity: { name: 'I_CASubApplicationVH', element: 'CASubApplication'}}]
cast('' as subap_kk) as CASubApplicationPrimary,
@UI.hidden: true
cast('' as abap.char(50)) as CASubApplicationText,
@EndUserText.label: 'Payment Lock Reason'
@ObjectModel.text.element: [ 'CAPaymentLockReasonName' ]
@Consumption.valueHelpDefinition: [{entity: { name: 'I_CAPaymentLockReasonVH', element: 'CAPaymentLockReason'}}]
cast('' as abap.char(100)) as CAPaymentLockReason,
@Consumption.filter.hidden: true
@Semantics.text: true
@EndUserText.label: 'Payment Lock Reason Text'
cast('' as abap.char(50)) as CAPaymentLockReasonName,
@EndUserText.label: 'Dunning Lock Reason'
@ObjectModel.text.element: [ 'CADunningLockReasonName' ]
@Consumption.valueHelpDefinition: [{entity: { name: 'I_CADunningLockReasonVH', element: 'CADunningLockReason'}}]
cast('' as abap.char(100)) as CADunningLockReason,
@Consumption.filter.hidden: true
@Semantics.text: true
@EndUserText.label: 'Dunning Lock Reason Text'
cast('' as abap.char(50)) as CADunningLockReasonName,
@UI.hidden: true
case
when CAStatisticalItemCode = 'R'
then cast('CAInstallmentPlan' as abap.char(30))
else cast('CADocument' as abap.char(30))
end
as SemanticObject,
@UI.hidden: true
cast('X' as abap.char(1)) as CADocumentBPItemIsTransferable,
@Consumption.filter.hidden: true
@Consumption.valueHelpDefinition: [{ entity: { name: 'C_CAContractPartnerValueHelp', element: 'BusinessPartner' }}]
cast('' as gpart_kk ) as CASrceDocBusinessPartner,
@Consumption.filter.hidden: true
@Consumption.valueHelpDefinition: [{entity: { name: 'C_ContractAccountValueHelp', element: 'ContractAccount'}}]
cast('' as vkont_kk ) as CASrceDocContractAccount,
@Consumption.filter.hidden: true
cast('' as vtref_kk ) as SourceDocumentCAContract,
@Consumption.filter.hidden: true
@Semantics.text: true
@EndUserText.label: 'Contract Text'
_ProviderContract.CAProviderContractName as CAProviderContractName,
@UI.hidden: true
cast('' as vtref_semobj_kk) as CAContractSemanticObject,
@Consumption.filter.hidden: true
@Consumption.valueHelpDefinition: [{entity: { name: 'I_CAOpenItemTransferReasonVH', element: 'CATransferReason'}}]
cast('' as umgrd_kk) as CATransferReason,
@Consumption.filter.hidden: true
@Semantics.text: true
@EndUserText.label: 'Document Type Text'
_DocType._Text[1:Language = $session.system_language].CADocumentTypeName as CADocumentTypeName,
@UI: {
selectionField: [{ position: 70 }],
lineItem: [{ position: 70, importance: #HIGH }]
}
@EndUserText.label: 'Document Type'
@Consumption.filter.hidden: true
@Consumption.valueHelpDefinition: [{entity: { name: 'I_CADocumentTypeVH', element: 'CADocumentType'},
additionalBinding: [{localElement: 'CAApplicationArea',element: 'CAApplicationArea'}]
}]
@ObjectModel.text.element: [ 'CADocumentTypeName' ]
@UI.textArrangement: #TEXT_FIRST
CADocumentType,
@Consumption.filter.hidden: true
@Consumption.valueHelpDefinition: [{entity: { name: 'I_CAReconciliationKeyVH', element: 'CAReconciliationKey'}}]
cast('' as fikey_kk) as CAReconciliationKey,
@Consumption.filter.hidden: true
cast($session.system_date as budat_kk) as CAPostingDate,
@Consumption.filter.hidden: true
@Consumption.valueHelpDefinition: [{entity: { name: 'I_CASubApplicationVH', element: 'CASubApplication'}}]
cast('' as subap_kk) as CASubApplication,
@UI.hidden: true
cast('' as is_cloud_system ) as IsCloudSystem,
@UI.hidden: true
BusinessArea,
@UI.hidden: true
CompanyCode,
@UI.hidden: true
CAApplicationArea,
@UI.hidden: true
_BusinessPartner.IsBusinessPurposeCompleted as IsBusinessPurposeCompleted,
@UI.hidden: true
cast('' as fkk_boole_d ) as TransferIsHidden
}
where
CAClearingStatus = ''