I_CADocumentBPItemLogical

// !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

// DEPRECATED - DON'T USE ANYMORE

// use I_CADocumentBPItem instead 

// !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!


@AbapCatalog: { preserveKey: true,
                sqlViewName: 'ICADOCBPITEMLOGI' }

@AccessControl.authorizationCheck: #CHECK

@ClientHandling.algorithm: #SESSION_VARIABLE

@EndUserText.label: 'Document Logical Business Partner Item'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: { supportedCapabilities: [ #CDS_MODELING_ASSOCIATION_TARGET,
                                         #SQL_DATA_SOURCE,
                                         #CDS_MODELING_DATA_SOURCE ],
                usageType: { dataClass: #TRANSACTIONAL,
                            serviceQuality: #C,
                            sizeCategory: #XXL } }

@Search.searchable: true

@VDM.viewType: #COMPOSITE

define view I_CADocumentBPItemLogical
  as select from I_CADocumentBPItemPhysical as BPItem

  association [1..1] to E_CADocumentBPItemPhysical as _Extension on  $projection.CADocumentNumber       = _Extension.CADocumentNumber
                                                                 and $projection.CARepetitionItemNumber = _Extension.CARepetitionItemNumber
                                                                 and $projection.CABPItemNumber         = _Extension.CABPItemNumber
                                                                 and $projection.CASubItemNumber        = _Extension.CASubItemNumber
{
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
  key BPItem.CADocumentNumber,
  key BPItem.CARepetitionItemNumber,
  key BPItem.CABPItemNumber,
  key BPItem.CASubItemNumber,
      BPItem.CompanyCode,
      BPItem.BusinessArea,
      BPItem.BusinessPlace,
      BPItem.Segment,
      BPItem.ProfitCenter,
      BPItem.Division,
      BPItem.PersonnelNumber,
      BPItem.PartnerCompany,
      BPItem.BusinessPartner,
      BPItem.CAContract,
      BPItem.CAProviderContractItemNumber,
      BPItem.CAAdditionalContract,
      BPItem.ContractAccount,
      BPItem.CASubApplication,
      BPItem.AltvContractAcctForCollvBills,
      BPItem.CAReconciliationAccount,
      BPItem.CAApplicationArea,
      BPItem.CAMainTransaction,
      BPItem.CASubTransaction,
      BPItem.CAAccountDeterminationCode,
      BPItem.CADoubtfulOrValueAdjmtCode,
      BPItem.CAAccountAssignmentCategory,
      BPItem.CAAccountAssignment,
      BPItem.CADocumentType,
      BPItem.CAIsDownPaymentRequest,
      BPItem.CAItemIsOnlyForSettlement,
      BPItem.CAStatisticalItemCode,
      BPItem.CABPItemText,
      BPItem.CANumberOfRepetitionItems,
      BPItem.CARepetitionGroup,
      BPItem.CAStartDateOfBillingPeriod,
      BPItem.CAEndDateOfBillingPeriod,
      BPItem.CAGroupingCodeForBPItems,
      BPItem.CAPeriodCode,
      BPItem.CAChangeIsForbidden,
      BPItem.CAInterestCode,
      BPItem.CARoundingItemCode,
      BPItem.CAReceivingCountry,
      BPItem.CAInternalPostingReasonCode,
      BPItem.CAWorkflowCheckReason,
      BPItem.CAWorkflowCheckProcess,
      BPItem.CANegativePostingControlCode,
      BPItem.CAPartnerSettlementStatus,
      BPItem.CAIsPartOfJointLiability,
      BPItem.CADocumentOriginCode,
      BPItem.CASubstituteDocumentNumber,
      BPItem.CASubstituteDocumentCategory,
      BPItem.CAStatisticalCodeOfOriginItem,
      BPItem.CADocumentNumberOfOriginItem,
      BPItem.CAReferenceDocument,
      BPItem.DocumentDate,
      BPItem.CAPostingDate,
      BPItem.CANetDueDate,
      BPItem.CADeferralDate,
      BPItem.TransactionCurrency,
      BPItem.CompanyCodeCurrency,
      BPItem.CAExchangeRate,
      BPItem.ExchRateIsIndirectQuotation,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      BPItem.CAAmountInLocalCurrency,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      BPItem.CAAmountInTransactionCurrency,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      BPItem.CAAmountInSecondCurrency,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      BPItem.CAAmountInThirdCurrency,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      BPItem.CADocBPItemTotalAmountInTC,
      BPItem.CACashDiscountDueDate,
      BPItem.CACashDiscountRate,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      BPItem.CAEligibleAmountForCshDiscount,
      @Semantics.amount.currencyCode: 'CAClearingCurrency'
      BPItem.CACashDiscAmountInClearingCrcy,
      BPItem.TaxCode,
      BPItem.CASupplementaryTaxCode,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      BPItem.CATaxAmountInLocalCurrency,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      BPItem.CATaxAmountInTransCurrency,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      BPItem.CATaxAmountInSecondCurrency,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      BPItem.CATaxAmountInThirdCurrency,
      BPItem.CADownPaymentTaxAccount,
      BPItem.CADownPaymentOffsetTaxAccount,
      BPItem.TaxJurisdiction,
      BPItem.CATaxDate,
      BPItem.WithholdingTaxCode,
      BPItem.CAWithholdingTaxSupplement,
      BPItem.CAWithholdingTaxCategory,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      BPItem.CABaseAmountForWithholdingTax,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      BPItem.CAWithholdingTaxAmount,
      BPItem.CAWithholdingTaxPercentage,
      BPItem.WithholdingTaxCertificate,
      BPItem.CAOtherTaxCode,
      BPItem.CAGroupingCodeForTaxItems,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      BPItem.CATaxPortionInLocalCurrency,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      BPItem.CATaxPortionInTransCurrency,
      BPItem.CATaxIsCalculatedExternally,
      BPItem.CAPaymentMethod,
      BPItem.CAPaymentCompanyCode,
      BPItem.CAGroupingForPayment,
      BPItem.CAPaymentSpecificationCategory,
      BPItem.CAClearingStatus,
      BPItem.CAClearingDate,
      BPItem.CAClearingDocumentNumber,
      BPItem.CAPostingDateOfClearingDoc,
      BPItem.CAClearingReason,
      BPItem.CAClearingCurrency,
      @Semantics.amount.currencyCode: 'CAClearingCurrency'
      BPItem.CAClearingAmountInClearingCrcy,
      @Semantics.amount.currencyCode: 'CAClearingCurrency'
      BPItem.CATaxAmountInClearingCrcy,
      BPItem.CAValueDateForClearing,
      BPItem.CAClearingRestrictionCode,
      BPItem.CAClearingPostingIsReset,
      BPItem.CAItemIsWithdrawn,
      BPItem.CAItemIsExcludedFromDunning,
      BPItem.CADunningProcedure,
      BPItem.CAGrpgCodeForTransfToCollAgcy,
      BPItem.CAIsIncludedInCollectionCase,
      BPItem.CashPlanningGroup,
      BPItem.PlanningLevel,
      BPItem.CAAdditionalDaysForCashMgmt,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      BPItem.PlannedAmtInTransactionCrcy,
      BPItem.CAAltvBPForPayment,
      BPItem.CABankOfAltvBPForPayment,
      BPItem.CAAddressOfAltvBPForPayment,
      BPItem.CACardOfAltvBPForPayment,
      BPItem.CAGLPostingCurrency,
      @Semantics.amount.currencyCode: 'CAGLPostingCurrency'
      BPItem.CAGLPostingAmount,
      @Semantics.amount.currencyCode: 'CAGLPostingCurrency'
      BPItem.CAGLPostingTaxAmount,
      BPItem.CAIsSeparateLineItemInGL,
      BPItem.CAIsCashFlowItem,
      BPItem.CACashFlowAccount,
      BPItem.CACashFlowCompanyCode,
      BPItem.CAPaymentPreNotificationCode,
      BPItem.CASEPAPreNotificationNumber,
      BPItem.CASEPAPreNotifOriginCode,
      BPItem.CASEPAPreNotifExecutionDate,
      BPItem.CASEPAPreNotificationRqmtCode,
      BPItem.CARevenueDistrFinalRecipient,
      BPItem.CARevenueDistrCurrentStatus,
      BPItem.CARevenueDistrLastStatus,
      BPItem.CACurrentFactoringStatusOfRbl,
      BPItem.CAFactoringCheckStsForClrgInfo,
      BPItem.ControllingArea,
      BPItem.ChartOfAccounts,
      BPItem.Country,
      BPItem.TaxCalculationProcedure,
      BPItem.SEPAMandateCAInternalID,

      /* associations from I_CADocumentBPItemPhysical */
      BPItem._AcctAssgmtCat,
      BPItem._AcctDetnCode,
      BPItem._AltvBPForPayment,
      BPItem._ApplArea,
      BPItem._BusinessArea,
      BPItem._BusinessPartner,
      BPItem._CAHeader,
      BPItem._CAHeaderCollvBills,
      BPItem._CAHeaderFinalRec,
      BPItem._CAPartner,
      BPItem._CARevnDistrCurSts,
      BPItem._CARevnDistrLastSts,
      BPItem._CARoundingItemCode,
      BPItem._SEPAPreNotifOrignCd,
      BPItem._SEPAPreNotifRqmtCode,
      BPItem._CashFlowAccount,
      BPItem._CASubApplication,
      BPItem._ClearingCurrency,
      BPItem._ClearingDocHeader,
      BPItem._ClearingReason,
      BPItem._ClrgRstrcnCode,
      BPItem._Currency,
      BPItem._CompanyCodeCurrency,
      BPItem._CompCode,
      BPItem._CompCodeCashFlow,
      BPItem._CompCodePayt,
      BPItem._ControllingArea,
      BPItem._ChartOfAccounts,
      BPItem._Country,
      BPItem._DbtflOrValAdjmtCode,
      BPItem._Division,
      BPItem._DocHeader,
      BPItem._DocType,
      BPItem._DunningProcedure,
      BPItem._FactoringRblStatus,
      BPItem._FctrngClrgChkStatus,
      BPItem._GLPostingCurrency,
      BPItem._InterestCode,
      BPItem._IntPostingReasonCode,
      BPItem._MainTransaction,
      BPItem._NgtvPostingCtrlCode,
      BPItem._OffsetTaxAccount,
      BPItem._OriginDocHeader,
      BPItem._OriglStstclItemCode,
      BPItem._OtherTaxCode,
      BPItem._PartnerCompany,
      BPItem._PaytMethod,
      BPItem._PaytPreNotifCode,
      BPItem._PaytSpecCategory,
      BPItem._PeriodCode,
      BPItem._ProfitCenter,
      BPItem._ProviderContract,
      BPItem._PrtnSettlementStatus,
      BPItem._ReceivingCountry,
      BPItem._ReconAccount,
      BPItem._Segment,
      BPItem._StatisticalItemCode,
      BPItem._SubstitDocCategory,
      BPItem._SubstitDocHeader,
      BPItem._SubTransaction,
      BPItem._TaxAccount,
      BPItem._WhldgTaxSuplmnt,
      BPItem._CAWithholdingTaxCat,
      BPItem._WithholdingTaxCode,
      BPItem._WorkflowCheckProcess,
      BPItem._WorkflowCheckReason
}
where
  (
    (
          CARepetitionItemNumber              = '000'
      and CARepetitionGroup                   = '000'
    )
    or    CARepetitionItemNumber != '000'
  )
  and(
          BPItem.CASubstituteDocumentCategory = ''  // no substitute document

    or    BPItem.CASubstituteDocumentCategory = 'P' // Promise to Pay

  ) // do not select original documents of Installment Plans and Collective Bills


union all select from I_CADocumentBPItemPhysical   as BPItem
  join                I_CADocumentBPRepetitionItem as RepItem on  BPItem.CADocumentNumber  = RepItem.CADocumentNumber
                                                              and BPItem.CARepetitionGroup = RepItem.CARepetitionGroup

association [1..1] to E_CADocumentBPItemPhysical as _Extension on  BPItem.CADocumentNumber        = _Extension.CADocumentNumber
                                                               and RepItem.CARepetitionItemNumber = _Extension.CARepetitionItemNumber
                                                               and BPItem.CABPItemNumber          = _Extension.CABPItemNumber
                                                               and BPItem.CASubItemNumber         = _Extension.CASubItemNumber

{
  key BPItem.CADocumentNumber,
  key RepItem.CARepetitionItemNumber,
  key BPItem.CABPItemNumber,
  key BPItem.CASubItemNumber,
      BPItem.CompanyCode,
      BPItem.BusinessArea,
      BPItem.BusinessPlace,
      BPItem.Segment,
      BPItem.ProfitCenter,
      BPItem.Division,
      BPItem.PersonnelNumber,
      BPItem.PartnerCompany,
      BPItem.BusinessPartner,
      BPItem.CAContract,
      BPItem.CAProviderContractItemNumber,
      BPItem.CAAdditionalContract,
      BPItem.ContractAccount,
      BPItem.CASubApplication,
      BPItem.AltvContractAcctForCollvBills,
      BPItem.CAReconciliationAccount,
      BPItem.CAApplicationArea,
      BPItem.CAMainTransaction,
      BPItem.CASubTransaction,
      BPItem.CAAccountDeterminationCode,
      BPItem.CADoubtfulOrValueAdjmtCode,
      BPItem.CAAccountAssignmentCategory,
      BPItem.CAAccountAssignment,
      BPItem.CADocumentType,
      BPItem.CAIsDownPaymentRequest,
      BPItem.CAItemIsOnlyForSettlement,
      BPItem.CAStatisticalItemCode,
      BPItem.CABPItemText,
      BPItem.CANumberOfRepetitionItems,
      RepItem.CARepetitionGroup,
      BPItem.CAStartDateOfBillingPeriod,
      BPItem.CAEndDateOfBillingPeriod,
      BPItem.CAGroupingCodeForBPItems,
      RepItem.CAPeriodCode,
      RepItem.CAChangeIsForbidden,
      BPItem.CAInterestCode,
      BPItem.CARoundingItemCode,
      BPItem.CAReceivingCountry,
      BPItem.CAInternalPostingReasonCode,
      BPItem.CAWorkflowCheckReason,
      BPItem.CAWorkflowCheckProcess,
      BPItem.CANegativePostingControlCode,
      BPItem.CAPartnerSettlementStatus,
      BPItem.CAIsPartOfJointLiability,
      BPItem.CADocumentOriginCode,
      RepItem.CASubstituteDocumentNumber,
      RepItem.CASubstituteDocumentCategory,
      BPItem.CAStatisticalCodeOfOriginItem,
      BPItem.CADocumentNumberOfOriginItem,
      BPItem.CAReferenceDocument,
      BPItem.DocumentDate,
      RepItem.CAPostingDate,
      RepItem.CANetDueDate,
      BPItem.CADeferralDate,
      BPItem.TransactionCurrency,
      BPItem.CompanyCodeCurrency,
      BPItem.CAExchangeRate,
      BPItem.ExchRateIsIndirectQuotation,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      BPItem.CAAmountInLocalCurrency,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      BPItem.CAAmountInTransactionCurrency,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      BPItem.CAAmountInSecondCurrency,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      BPItem.CAAmountInThirdCurrency,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      BPItem.CADocBPItemTotalAmountInTC,
      RepItem.CACashDiscountDueDate,
      BPItem.CACashDiscountRate,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      BPItem.CAEligibleAmountForCshDiscount,
      @Semantics.amount.currencyCode: 'CAClearingCurrency'
      BPItem.CACashDiscAmountInClearingCrcy,
      BPItem.TaxCode,
      BPItem.CASupplementaryTaxCode,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      BPItem.CATaxAmountInLocalCurrency,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      BPItem.CATaxAmountInTransCurrency,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      BPItem.CATaxAmountInSecondCurrency,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      BPItem.CATaxAmountInThirdCurrency,
      BPItem.CADownPaymentTaxAccount,
      BPItem.CADownPaymentOffsetTaxAccount,
      BPItem.TaxJurisdiction,
      BPItem.CATaxDate,
      BPItem.WithholdingTaxCode,
      BPItem.CAWithholdingTaxSupplement,
      BPItem.CAWithholdingTaxCategory,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      BPItem.CABaseAmountForWithholdingTax,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      BPItem.CAWithholdingTaxAmount,
      BPItem.CAWithholdingTaxPercentage,
      BPItem.WithholdingTaxCertificate,
      BPItem.CAOtherTaxCode,
      BPItem.CAGroupingCodeForTaxItems,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      BPItem.CATaxPortionInLocalCurrency,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      BPItem.CATaxPortionInTransCurrency,
      BPItem.CATaxIsCalculatedExternally,
      BPItem.CAPaymentMethod,
      BPItem.CAPaymentCompanyCode,
      BPItem.CAGroupingForPayment,
      BPItem.CAPaymentSpecificationCategory,
      case
        when RepItem.CAClearingDate <> '00000000'
          then '9'
          else ' '
      end as CAClearingStatus,
      RepItem.CAClearingDate,
      RepItem.CAClearingDocumentNumber,
      RepItem.CAPostingDateOfClearingDoc,
      RepItem.CAClearingReason,
      BPItem.CAClearingCurrency,
      @Semantics.amount.currencyCode: 'CAClearingCurrency'
      BPItem.CAClearingAmountInClearingCrcy,
      @Semantics.amount.currencyCode: 'CAClearingCurrency'
      BPItem.CATaxAmountInClearingCrcy,
      RepItem.CAValueDateForClearing,
      BPItem.CAClearingRestrictionCode,
      RepItem.CAClearingPostingIsReset,
      RepItem.CAItemIsWithdrawn,
      BPItem.CAItemIsExcludedFromDunning,
      BPItem.CADunningProcedure,
      BPItem.CAGrpgCodeForTransfToCollAgcy,
      BPItem.CAIsIncludedInCollectionCase,
      BPItem.CashPlanningGroup,
      BPItem.PlanningLevel,
      BPItem.CAAdditionalDaysForCashMgmt,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      BPItem.PlannedAmtInTransactionCrcy,
      BPItem.CAAltvBPForPayment,
      BPItem.CABankOfAltvBPForPayment,
      BPItem.CAAddressOfAltvBPForPayment,
      BPItem.CACardOfAltvBPForPayment,
      BPItem.CAGLPostingCurrency,
      @Semantics.amount.currencyCode: 'CAGLPostingCurrency'
      BPItem.CAGLPostingAmount,
      @Semantics.amount.currencyCode: 'CAGLPostingCurrency'
      BPItem.CAGLPostingTaxAmount,
      BPItem.CAIsSeparateLineItemInGL,
      BPItem.CAIsCashFlowItem,
      BPItem.CACashFlowAccount,
      BPItem.CACashFlowCompanyCode,
      RepItem.CAPaymentPreNotificationCode,
      RepItem.CASEPAPreNotificationNumber,
      RepItem.CASEPAPreNotifOriginCode,
      RepItem.CASEPAPreNotifExecutionDate,
      BPItem.CASEPAPreNotificationRqmtCode,
      BPItem.CARevenueDistrFinalRecipient,
      BPItem.CARevenueDistrCurrentStatus,
      BPItem.CARevenueDistrLastStatus,
      BPItem.CACurrentFactoringStatusOfRbl,
      BPItem.CAFactoringCheckStsForClrgInfo,
      BPItem.ControllingArea,
      BPItem.ChartOfAccounts,
      BPItem.Country,
      BPItem.TaxCalculationProcedure,
      BPItem.SEPAMandateCAInternalID,

      /* associations from I_CADocumentBPItemPhysical and I_CADocumentBPRepetitionItem */
      BPItem._AcctAssgmtCat,
      BPItem._AcctDetnCode,
      BPItem._AltvBPForPayment,
      BPItem._ApplArea,
      BPItem._BusinessArea,
      BPItem._BusinessPartner,
      BPItem._CAHeader,
      BPItem._CAHeaderCollvBills,
      BPItem._CAHeaderFinalRec,
      BPItem._CAPartner,
      BPItem._CARevnDistrCurSts,
      BPItem._CARevnDistrLastSts,
      BPItem._CARoundingItemCode,
      RepItem._SEPAPreNotifOrignCd,
      BPItem._SEPAPreNotifRqmtCode,
      BPItem._CashFlowAccount,
      BPItem._CASubApplication,
      BPItem._ClearingCurrency,
      RepItem._ClearingDocHeader,
      RepItem._ClearingReason,
      BPItem._ClrgRstrcnCode,
      BPItem._Currency,
      BPItem._CompanyCodeCurrency,
      BPItem._CompCode,
      BPItem._CompCodeCashFlow,
      BPItem._CompCodePayt,
      BPItem._ControllingArea,
      BPItem._ChartOfAccounts,
      BPItem._Country,
      BPItem._DbtflOrValAdjmtCode,
      BPItem._Division,
      BPItem._DocHeader,
      BPItem._DocType,
      BPItem._DunningProcedure,
      BPItem._FactoringRblStatus,
      BPItem._FctrngClrgChkStatus,
      BPItem._GLPostingCurrency,
      BPItem._InterestCode,
      BPItem._IntPostingReasonCode,
      BPItem._MainTransaction,
      BPItem._NgtvPostingCtrlCode,
      BPItem._OffsetTaxAccount,
      BPItem._OriginDocHeader,
      BPItem._OriglStstclItemCode,
      BPItem._OtherTaxCode,
      BPItem._PartnerCompany,
      BPItem._PaytMethod,
      RepItem._PaytPreNotifCode,
      BPItem._PaytSpecCategory,
      RepItem._PeriodCode,
      BPItem._ProfitCenter,
      BPItem._ProviderContract,
      BPItem._PrtnSettlementStatus,
      BPItem._ReceivingCountry,
      BPItem._ReconAccount,
      BPItem._Segment,
      BPItem._StatisticalItemCode,
      RepItem._SubstitDocCategory,
      RepItem._SubstitDocHeader,
      BPItem._SubTransaction,
      BPItem._TaxAccount,
      BPItem._WhldgTaxSuplmnt,
      BPItem._CAWithholdingTaxCat,
      BPItem._WithholdingTaxCode,
      BPItem._WorkflowCheckProcess,
      BPItem._WorkflowCheckReason
}
where
      BPItem.CARepetitionItemNumber      = '000'
  and BPItem.CARepetitionGroup != '000'
  and RepItem.CARepetitionItemIsResolved = ''