I_AssMdlUserToExplctAssMdlTP_2

@AccessControl.authorizationCheck: #MANDATORY 
@EndUserText.label: 'Asstmt User Assignment to Asstmt Module'

@VDM: {
  viewType: #TRANSACTIONAL,

  lifecycle: {
    contract: {
      type: #SAP_INTERNAL_API
    }
  }
}
@ObjectModel: {
    usageType: {
        serviceQuality: #C,
        sizeCategory: #M,
        dataClass: #MASTER
   },
   sapObjectNodeType.name: 'AssortmentModule'
}
define root view entity I_AssMdlUserToExplctAssMdlTP_2
  as select from            I_UserToExplicitAsstmtModule_2 as AssortmentModuleUser
    inner to one join I_AsstmtMdlMgmtSolnGenSetting on I_AsstmtMdlMgmtSolnGenSetting.AsstmtMdlMgmtSolnIsEnbld = 'X'
  association [1..1] to I_ExplicitAssortmentModuleTP   as _ExplicitAssortmentModule on  _ExplicitAssortmentModule.AssortmentModuleUUID = $projection.AssortmentModuleUUID
  association [0..*] to I_AssortmentModuleText         as _Text                     on  _Text.AssortmentModuleUUID = $projection.AssortmentModuleUUID
  association [1..*] to I_ProdToExplicitAsstmtMdlTP    as _Products                 on  _Products.AssortmentModuleUUID = $projection.AssortmentModuleUUID
  association [1..*] to I_ExplctAssMdlUsrProdExclsnTP  as _Exclusions               on  _Exclusions.AssortmentModuleObjectUUID = $projection.AssortmentModuleUUID
                                                                                    and _Exclusions.AssortmentModuleUser       = $projection.AssortmentModuleUser
  association [1..*] to I_AsstmtMdlUsrProdExclsnTP_2   as _Exclusions_2             on  _Exclusions_2.AssortmentModuleUUID = $projection.AssortmentModuleUUID
                                                                                    and _Exclusions_2.AssortmentModuleUser = $projection.AssortmentModuleUser
  association [0..1] to I_UserContactCard              as _User                     on  _User.ContactCardID = $projection.LastChangedByUserName
  association [0..*] to R_ProdStoreToExplctAsstmtMdlTP as _ProductsWithoutExclusion on  _ProductsWithoutExclusion.AssortmentModuleUUID        = $projection.AssortmentModuleUUID
                                                                                    and _ProductsWithoutExclusion.AssortmentModuleUser        = $projection.AssortmentModuleUser
                                                                                    and _ProductsWithoutExclusion.AssignmentValidityStartDate = $projection.ValidityStartDate


{
  key AssortmentModuleUser.AssortmentModuleUUID,
  key AssortmentModuleUser.AssortmentModuleUser,
  key AssortmentModuleUser.ValidityStartDate,
      AssortmentModuleUser.AssortmentModuleName,
      AssortmentModuleUser.ValidityEndDate,
      AssortmentModuleUser.LastChangeDate,
      AssortmentModuleUser.LastChangeDateTime,
      AssortmentModuleUser.LastChangedByUserName,

      /*For DCL*/
      AssortmentModuleUser.SalesOrganization,
      AssortmentModuleUser.DistributionChannel,


      _ExplicitAssortmentModule,
      _Exclusions,
      _Exclusions_2,
      _ProductsWithoutExclusion,
      AssortmentModuleUser._ExclusionRatio,
      _Text,
      _Products,
      AssortmentModuleUser._Site,
      _User
}