R_ProdStoreToExplctAsstmtMdlTP

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #BLOCKED_DATA_EXCLUDED
}

@EndUserText.label: 'Product-Store Assignment via Assortment Module'

@ObjectModel: {
    usageType: {
        serviceQuality: #C,
        sizeCategory: #L,
        dataClass: #MASTER
   },
   sapObjectNodeType.name: 'AssortmentModule'
}
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle: {
    contract: {
      type: #SAP_INTERNAL_API
    }
  }
}

define root view entity R_ProdStoreToExplctAsstmtMdlTP
  as select distinct from I_ProdToExplicitAsstmtModule
    inner join I_AssMdlUserToExplctAssMdlTP_2 as _UserAssignment on I_ProdToExplicitAsstmtModule.AssortmentModuleUUID = _UserAssignment.AssortmentModuleUUID
    left outer to one join  I_AsstmtMdlUsrProdExclsnTP_2  as _Exclusion      on  I_ProdToExplicitAsstmtModule.AssortmentModuleUUID = _Exclusion.AssortmentModuleUUID
                                                                              and I_ProdToExplicitAsstmtModule.Product              = _Exclusion.Product
                                                                              and _UserAssignment.AssortmentModuleUser              = _Exclusion.AssortmentModuleUser
association [0..1] to I_AssMdlUserToExplctAssMdlTP_2 as _User on $projection.AssortmentModuleUUID = _User.AssortmentModuleUUID
                                                             and $projection.AssortmentModuleUser = _User.AssortmentModuleUser
                                                             and $projection.AssignmentValidityStartDate = _User.ValidityStartDate
{
  key I_ProdToExplicitAsstmtModule.AssortmentModuleUUID,
  key I_ProdToExplicitAsstmtModule.Product,
  key _UserAssignment.AssortmentModuleUser,
  key _UserAssignment.ValidityStartDate as AssignmentValidityStartDate,
      I_ProdToExplicitAsstmtModule.ProductIsMandatoryInAssortment,
      I_ProdToExplicitAsstmtModule.ValidityStartDate,
      I_ProdToExplicitAsstmtModule.ValidityEndDate,
      I_ProdToExplicitAsstmtModule._Text,
      case when coalesce( _Exclusion.AssortmentModuleUser, ' ' ) = ' ' then ' ' else 'X' end as ProductIsExcludedForStore,
      
      _UserAssignment.SalesOrganization,
      _UserAssignment.DistributionChannel,
      
      _User,
      I_ProdToExplicitAsstmtModule._Product as _Product
}