I_ProdToExplicitAsstmtMdlTP

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #BLOCKED_DATA_EXCLUDED
}

@EndUserText.label: 'Product Assignment to Assortment Module'

@ObjectModel: {
    usageType: {
        serviceQuality: #C,
        sizeCategory: #L,
        dataClass: #MASTER
   },
   sapObjectNodeType.name: 'AssortmentModuleProductAssgmt'
}
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle: {
    contract: {
      type: #SAP_INTERNAL_API
    }
  }
}

define root view entity I_ProdToExplicitAsstmtMdlTP
  as select from I_ProdToExplicitAsstmtModule
    inner to one join I_AsstmtMdlMgmtSolnGenSetting on I_AsstmtMdlMgmtSolnGenSetting.AsstmtMdlMgmtSolnIsEnbld = 'X'
  association [1..1] to I_ProdAssgblToExplctModuleTP  as _AssignableProduct on $projection.Product = _AssignableProduct.Product
  composition [1..*] of I_ProdToExplctAsstmtMdlVersTP as _ProdToExplctMdlVers 
{
  key I_ProdToExplicitAsstmtModule.AssortmentModuleUUID,
  key I_ProdToExplicitAsstmtModule.Product,
  key I_ProdToExplicitAsstmtModule.AssortmentModuleName,
      I_ProdToExplicitAsstmtModule.ProductIsMandatoryInAssortment,
      cast ( coalesce ( I_ProdToExplicitAsstmtModule._ExclusionRatio.RatioOfUsersWhoExcludedProdVal, '0%' ) as rfm_asm_usr_prod_excl_percent preserving type ) as RatioOfUsersWhoExcludedProdVal,
      I_ProdToExplicitAsstmtModule.ValidityStartDate,
      I_ProdToExplicitAsstmtModule.ValidityEndDate,
      I_ProdToExplicitAsstmtModule.LastChangeDate,
      I_ProdToExplicitAsstmtModule.LastChangeDateTime,
      I_ProdToExplicitAsstmtModule._ModuleVersion,
      I_ProdToExplicitAsstmtModule._Text,
      I_ProdToExplicitAsstmtModule._Product,
      _AssignableProduct,
      _ProdToExplctMdlVers
}