I_AdvncdReturnsMgmtProcessItem

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'IARMPROCESSITM'
@AbapCatalog.compiler.compareFilter: true

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
  }
@ObjectModel.representativeKey: 'RetsMgmtProcessItem'
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

@VDM.viewType: #COMPOSITE
@Analytics:{ dataExtraction.enabled:false }
@EndUserText.label: 'Advanced Returns Management Process Item'

define view I_AdvncdReturnsMgmtProcessItem
  as select from           I_AdvncdRetsMgmtProcItemBasic as Item
    inner join             I_AdvncdReturnsMgmtProcBasic  as Head                 on  Item.RetsMgmtProcess     = Head.RetsMgmtProcess
                                                                                 and Head.ReturnsDocumentType = '00'
    left outer to one join I_RetsMgmtProcItmWthProcgSts  as ItemProcessingStatus on  Head.ReturnsDocument     = ItemProcessingStatus.ReturnsDocument
                                                                                 and Item.RetsMgmtProcess     = ItemProcessingStatus.RetsMgmtProcess
                                                                                 and Item.RetsMgmtProcessItem = ItemProcessingStatus.RetsMgmtProcessItem

  association [1..1] to I_AdvncdReturnsMgmtProcess     as _AdvncdRetsMgmtProcess  on  $projection.RetsMgmtProcess = _AdvncdRetsMgmtProcess.RetsMgmtProcess

  association [0..*] to I_AdvncdReturnsMgmtProcessStep as _AdvncdRetsMgmtProcStep on  $projection.RetsMgmtProcess     = _AdvncdRetsMgmtProcStep.RetsMgmtProcess
                                                                                  and $projection.RetsMgmtProcessItem = _AdvncdRetsMgmtProcStep.RetsMgmtProcessItem
{
      //Key

      @ObjectModel.foreignKey.association: '_AdvncdRetsMgmtProcess'
  key Item.RetsMgmtProcess,
  key Item.RetsMgmtProcessItem,
      Head.ReturnsDocument,

      Item.ReturnsRefundRjcnReason,
      Item.CustRetMatlAuthzn,
      Item.CustomerRetMatlInspResultCode,
      Item.NextFllwUpActivityForMatlInsp,

      Item.RetsProdValnIsSuspended,
      Item.RetsInspIsCrtedAutomly,
      Item.RetsProdIsVltdWithRef,

      //Status fields

      ItemProcessingStatus.RetsMgmtItmLogProcgStatus,
      ItemProcessingStatus.RetsMgmtItmCompnProcgStatus,
      ItemProcessingStatus.RetsMgmtItmProcgStatus,

      //CRM Reference

      Item.CRMLogicalSystem,
      Item.CRMObjectUUID,
      Item.CRMObjectID,
      Item.CRMObjectType,

      //Associations

      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT,
                                      #TO_COMPOSITION_ROOT]
      _AdvncdRetsMgmtProcess,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _AdvncdRetsMgmtProcStep,
      Item._ReturnsRefundRjcnReason,
      ItemProcessingStatus._RetsMgmtItmLogProcgStatus,
      ItemProcessingStatus._RetsMgmtItmCompnProcgStatus,
      ItemProcessingStatus._RetsMgmtItmProcgStatus

}