I_AdvncdReturnsMgmtProcessStep

@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Advanced Returns Management Process Step'

@VDM.viewType: #COMPOSITE

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations: [ '_Address', '_DfltAddrRprstn' ]
}

@AbapCatalog: {
  sqlViewName: 'IARMPROCSTEP',
  compiler.compareFilter: true
}

@ObjectModel: {
  representativeKey: 'RetsMgmtProcessStep',
  usageType: {
    dataClass:      #MIXED,
    serviceQuality: #C,
    sizeCategory:   #L
  }
}
@Analytics.dataExtraction.enabled: false

define view I_AdvncdReturnsMgmtProcessStep
  as select from            I_AdvncdRetsMgmtProcExecuted   as Executed

    left outer to one join  I_AdvncdReturnsMgmtProcChain   as Chain             on Executed.CustRetItmChainID = Chain.CustRetItmChainID

    left outer to many join I_AdvncdRetsMgmtProcNextPlants as NextPlants        on  Executed.RetsMgmtProcess         = NextPlants.RetsMgmtProcess
                                                                                and Executed.RetsMgmtProcessItem     = NextPlants.RetsMgmtProcessItem
                                                                                and Executed.RetsMgmtProcItmQtySplit = NextPlants.RetsMgmtProcItmQtySplit
                                                                                and Executed.RetsMgmtProcessStep     = NextPlants.RetsMgmtProcessStep

    left outer to many join I_AdvncdRetsMgmtProcExecStatus as ProcgStatus       on  Executed.RetsMgmtProcess                      = ProcgStatus.RetsMgmtProcess
                                                                                and Executed.ReturnsDocument                      = ProcgStatus.ReturnsDocument
                                                                                and Executed.RetsMgmtProcessItem                  = ProcgStatus.RetsMgmtProcessItem
                                                                                and Executed.RetsMgmtProcItmQtySplit              = ProcgStatus.RetsMgmtProcItmQtySplit
                                                                                and Executed.RetsMgmtProcessStep                  = ProcgStatus.RetsMgmtProcessStep
                                                                                and Executed.ReturnsDocumentStatus                = ''
                                                                                and (
                                                                                   (
                                                                                     ProcgStatus.ReturnsReferenceDocument         = Executed.ReturnsDocument
                                                                                     and ProcgStatus.ReturnsReferenceDocumentItem = Executed.ReturnsDocumentItem
                                                                                   )
                                                                                   or ProcgStatus.ReturnsReferenceDocument        = ''
                                                                                 )
  //Enhance ProductIsInspectedAtCustSite

    left outer to one join  I_InspectionOutcomeBasic       as InspectionOutcome on  Executed.RetsMgmtProcess           = InspectionOutcome.RetsMgmtProcess
                                                                                and Executed.ReturnsDocument           = InspectionOutcome.ReturnsReferenceDocument
                                                                                and Executed.ReturnsDocumentItem       = InspectionOutcome.ReturnsReferenceDocumentItem
                                                                                and Executed.ReturnsDocumentType       = InspectionOutcome.ReturnsReferenceDocumentType
                                                                                and InspectionOutcome.DeliveryDocument = ''
                                                                                and InspectionOutcome.InspectionDocumentIsDeleted = ''
{
      //Key

  key Executed.RetsMgmtProcess,
  key Executed.RetsMgmtProcessItem,

  key Executed.RetsMgmtProcItmQtySplit,
  key Executed.RetsMgmtProcessStep,

  key Executed.ReturnsDocumentType,
  key Executed.ReturnsDocument,
  key Executed.ReturnsDocumentItem,


      //Reference Document

      Executed.ReturnsReferenceDocumentType,
      Executed.ReturnsReferenceDocument,
      Executed.ReturnsReferenceDocumentItem,

      //Returns Document Status

      Executed.ReturnsDocumentStatus,
      Executed.ReturnsDocumentApprovalStatus,

      Executed.RetsMgmtProcItmExectdSequence,
      Executed.CustRetItmChainID,

      Chain.CustRetItmFollowUpActivity,
      Chain.ReturnsMaterialHasBeenReceived,

      NextPlants.NextPlantForFollowUpActivity,
      NextPlants.ReturnsTransshipmentPlant,

      //Refunding

      Executed.ReturnsRefundType,
      Executed.ReturnsRefundProcgMode,
      Executed.PrelimRefundIsDetermined,

      //Replacement

      Executed.ReplacementMaterial,
      Executed.ReplacementMaterialQuantity,
      Executed.ReplacementMaterialQtyUnit,
      Executed.ReplacementMaterialIsRequested,
      Executed.ReplacementMatlSupplyingPlant,

      Executed.Supplier,
      Executed.AddressID,
      Executed.SupplierRetMatlAuthzn,
      Executed.SuplrRetMatlAuthznIsRequired,

      //Inspection

      Executed.RetMatlInspResultCode,

      InspectionOutcome.ProductIsInspectedAtCustSite,
      @Semantics.booleanIndicator:true
      InspectionOutcome.InspectionDocumentIsDeleted,

      //Processing Status

      cast ( case when  ProcgStatus.RetsMgmtProcessStep <> ''
        then
          case when ProcgStatus.RetsMgmtProcStepExecStatus = '2'
            then
              '2' -- ->'with errors'
            else
              '0' -- ->'open'
          end
        else
          '1' -- ->'complete'
      end as msr_exec_step_status) as RetsMgmtProcStepExecStatus,

      //Associations

      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT]
      Executed._AdvncdRetsMgmtProcess,
      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT]
      Executed._AdvncdRetsMgmtProcessItem,
      Executed._ReturnsReferenceDocumentType,
      Executed._ReturnsRefundType,
      Executed._ReturnsRefundProcgMode,
      Executed._ReplacementMaterialQtyUnit,
      Executed._Supplier,
      Executed._Address,
      Executed._DfltAddrRprstn,
      Executed._RetMatlInspResultCode
}