I_AdvncdReturnsMgmtProcess

DDL: I_ADVNCDRETURNSMGMTPROCESS SQL: IARMPROCESS Type: view COMPOSITE Package: VDM_ARM_BASICS

Advanced Returns Management Process

I_AdvncdReturnsMgmtProcess is a Composite CDS View (Dimension) that provides data about "Advanced Returns Management Process" in SAP S/4HANA. It reads from 2 data sources (I_AdvncdReturnsMgmtProcBasic, I_SalesDocumentBasic) and exposes 15 fields with key field RetsMgmtProcess. It has 1 association to related views. Part of development package VDM_ARM_BASICS.

2 data source(s) 15 fields

Data Sources (2)

SourceAliasJoin Type
I_AdvncdReturnsMgmtProcBasic AdvncdReturnsMgmtProcess from
I_SalesDocumentBasic SalesDocument inner

Associations (1)

CardinalityTargetAliasCondition
[0..*] I_AdvncdReturnsMgmtProcessItem _AdvncdRetsMgmtProcessItem $projection.RetsMgmtProcess = _AdvncdRetsMgmtProcessItem.RetsMgmtProcess

Annotations (15)

NameValueLevelField
ClientHandling.algorithm #SESSION_VARIABLE view
AbapCatalog.sqlViewName IARMPROCESS view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #MANDATORY view
ObjectModel.representativeKey RetsMgmtProcess view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.compositionRoot true view
VDM.viewType #COMPOSITE view
Analytics.dataCategory #DIMENSION view
Analytics.dataExtraction.enabled false view
Metadata.ignorePropagatedAnnotations true view
Metadata.allowExtensions true view
EndUserText.label Advanced Returns Management Process view

Fields (15)

KeyFieldSource TableSource FieldDescription
KEY RetsMgmtProcess I_AdvncdReturnsMgmtProcBasic RetsMgmtProcess
ReturnsDocumentType I_AdvncdReturnsMgmtProcBasic ReturnsDocumentType
ReturnsDocument I_AdvncdReturnsMgmtProcBasic ReturnsDocument
RetsMgmtLogProcgStatus ProcessingStatus RetsMgmtLogProcgStatus
RetsMgmtCompnProcgStatus ProcessingStatus RetsMgmtCompnProcgStatus
RetsMgmtProcessingStatus ProcessingStatus RetsMgmtProcessingStatus
SalesOrganization I_SalesDocumentBasic SalesOrganization
DistributionChannel I_SalesDocumentBasic DistributionChannel
SalesDocumentType I_SalesDocumentBasic SalesDocumentType
OrganizationDivision I_SalesDocumentBasic OrganizationDivision
_AdvncdRetsMgmtProcessItem _AdvncdRetsMgmtProcessItem
_ReturnsDocumentType I_AdvncdReturnsMgmtProcBasic _ReturnsDocumentType
_RetsMgmtLogProcgStatus ProcessingStatus _RetsMgmtLogProcgStatus
_RetsMgmtCompnProcgStatus ProcessingStatus _RetsMgmtCompnProcgStatus
_RetsMgmtProcessingStatus ProcessingStatus _RetsMgmtProcessingStatus 
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'IARMPROCESS'
@AbapCatalog.compiler.compareFilter: true
@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
  }
@ObjectModel.representativeKey: 'RetsMgmtProcess'
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.compositionRoot: true
@VDM.viewType: #COMPOSITE
@Analytics:{ dataCategory: #DIMENSION, dataExtraction.enabled: false }
@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions: true
@EndUserText.label: 'Advanced Returns Management Process'

define view I_AdvncdReturnsMgmtProcess
  as select from         I_AdvncdReturnsMgmtProcBasic as AdvncdReturnsMgmtProcess
  inner join             I_SalesDocumentBasic         as SalesDocument    on SalesDocument.SalesDocument = AdvncdReturnsMgmtProcess.ReturnsDocument
  left outer to one join I_RetsMgmtProcessWthProcgSts as ProcessingStatus on AdvncdReturnsMgmtProcess.RetsMgmtProcess = ProcessingStatus.RetsMgmtProcess
                                                                         and AdvncdReturnsMgmtProcess.ReturnsDocument = ProcessingStatus.ReturnsDocument

  association [0..*] to I_AdvncdReturnsMgmtProcessItem as _AdvncdRetsMgmtProcessItem  on $projection.RetsMgmtProcess = _AdvncdRetsMgmtProcessItem.RetsMgmtProcess
{
      //Key

  key AdvncdReturnsMgmtProcess.RetsMgmtProcess,

      AdvncdReturnsMgmtProcess.ReturnsDocumentType,
      AdvncdReturnsMgmtProcess.ReturnsDocument,

      //Processing Status

      ProcessingStatus.RetsMgmtLogProcgStatus,
      ProcessingStatus.RetsMgmtCompnProcgStatus,
      ProcessingStatus.RetsMgmtProcessingStatus,

      //For Access control

      SalesDocument.SalesOrganization,
      SalesDocument.DistributionChannel,
      SalesDocument.SalesDocumentType,
      SalesDocument.OrganizationDivision,

      //Associations

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _AdvncdRetsMgmtProcessItem,
      AdvncdReturnsMgmtProcess._ReturnsDocumentType,
      ProcessingStatus._RetsMgmtLogProcgStatus,
      ProcessingStatus._RetsMgmtCompnProcgStatus,
      ProcessingStatus._RetsMgmtProcessingStatus
}

Learn More