C_SalesManagerSelection

@AbapCatalog: {
   sqlViewName: 'CSDSLSMGRSEL',
   compiler.compareFilter: true
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L 
@EndUserText.label: 'Sales Manager Selection'
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
define view C_SalesManagerSelection
with parameters
  @Consumption.defaultValue: 'EUR'
  @Consumption.valueHelpDefinition: [{ entity:{ name: 'C_CurrencyValueHelp', element: 'Currency' } }]
  P_DisplayCurrency: vdm_v_display_currency
as select from I_SalesDocumentBasic

//association [0..1] to C_SoldToValueHelp as _SoldToParty

//  on $projection.SoldToParty = _SoldToParty.Customer

association [0..1] to C_Q2CCustomerQuickView    as _SoldToParty             on  $projection.SoldToParty = _SoldToParty.Customer  
 
// C_SalesOrganizationVH is not used since it is not in SD compoent

// association [0..1] to C_SalesOrganizationVH as _SalesOrganization

//  on $projection.SalesOrganization = _SalesOrganization.SalesOrganization


association [0..1] to C_Dischannelvaluehelp as _DistributionChannel
  on $projection.SalesOrganization = _DistributionChannel.SalesOrganization
     and $projection.DistributionChannel = _DistributionChannel.DistributionChannel
     
association [0..1] to C_OrgDivisionValueHelp as _OrganizationDivision
  on $projection.SalesOrganization = _OrganizationDivision.SalesOrganization
     and $projection.DistributionChannel  = _OrganizationDivision.DistributionChannel
     and $projection.OrganizationDivision = _OrganizationDivision.Division
     
association [0..1] to C_SalesOfficeValueHelp as _SalesOffice
  on $projection.SalesOrganization = _SalesOffice.SalesOrganization
     and $projection.DistributionChannel  = _SalesOffice.DistributionChannel
     and $projection.OrganizationDivision = _SalesOffice.OrganizationDivision
     and $projection.SalesOffice = _SalesOffice.SalesOffice
     
association [0..1] to C_SalesGroupValueHelp as _SalesGroup
  on $projection.SalesOffice = _SalesGroup.SalesOffice
     and $projection.SalesGroup = _SalesGroup.SalesGroup
{

  key SalesDocument,

  @UI.hidden: true
  SalesDocumentType,
  
  //@Consumption.valueHelp: '_SoldToParty'

//  @Consumption.valueHelpDefinition: [

//        { entity:  { name:    'C_SoldToValueHelp',

//                     element: 'Customer' }

//        }] 

  @Consumption.valueHelpDefinition: [{ entity: { name: 'D_Q2CCustomerCVH',
                                           element: 'Customer' } }]      
  SoldToParty,
  @Consumption.filter.hidden: true
  _SoldToParty,
  
 // @Consumption.valueHelp: '_SalesOrganization'

  SalesOrganization,
  @Consumption.filter.hidden: true
  _SalesOrganization,
  
  @Consumption.valueHelp: '_DistributionChannel'       
  DistributionChannel,
  @Consumption.filter.hidden: true
  _DistributionChannel,
  
  @Consumption.valueHelp: '_OrganizationDivision'       
  OrganizationDivision,
  @Consumption.filter.hidden: true
  _OrganizationDivision,
    
  @Consumption.valueHelp: '_SalesOffice'  
  SalesOffice,
  @Consumption.filter.hidden: true
  _SalesOffice,
  
  @Consumption.valueHelp: '_SalesGroup'
  SalesGroup,
  @Consumption.filter.hidden: true
  _SalesGroup,
  
  @Semantics.currencyCode: true
  TransactionCurrency,
  
  @UI.hidden: true
  @DefaultAggregation: #SUM
  @Semantics.amount.currencyCode: 'TransactionCurrency'
  TotalNetAmount
}